[PartialCloning]

Try this, reconstructed from your code:

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <engine>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

#pragma semicolon 1

#define m_bHasPrimary 116
#define CBasePlayer 5

new g_PlayersSpeed;

public plugin_init()
{
    register_plugin("Armes/MrGarfield", "1.1a-Reconstructed", "Jailbreak Shop");

    RegisterHam(Ham_Spawn, "player", "PlayerSpawn", 1);
    g_PlayersSpeed = register_cvar("players_speed", "700");
}

public PlayerSpawn(id)
{
    if(!is_user_alive(id))
        return HAM_IGNORED;

    strip_user_weapons(id);
    set_pdata_int(id, m_bHasPrimary, 0, CBasePlayer);
    give_item(id, "weapon_knife");

    ShopMenu(id, cs_get_user_team(id));
    return HAM_IGNORED;
}

ShopMenu(id, CsTeams:Team)
{
    switch(Team)
    {
        case CS_TEAM_T:
        {
            new Menu = menu_create("[Alias#`KraZy] Choisis ta classe de Prisonnier", "ShopMenuPrisoner_Handler");

            menu_additem(Menu, "\wAssassin \y- \w[ \rGravite \w]");
            menu_additem(Menu, "\wDealer \y- \w[ \r130Hp \w]");
            menu_additem(Menu, "\wPedobear \y- \w[ \rVitesse \w]");
            menu_additem(Menu, "\wTerroriste \y- \w[ \rHe \w+ \rFlash \w+ \rSmoke \w]");
            menu_additem(Menu, "\wProtecteur \y- \w[ \rArmure \w+ \rSmoke \w] *NEW*");

            menu_setprop(Menu, MPROP_EXITNAME, "Quitter");
            menu_setprop(Menu, MPROP_EXIT, MEXIT_ALL);
            menu_display(id, Menu, 0);
        }
        case CS_TEAM_CT:
        {
            new Menu = menu_create("[Alias#`KraZy] Choisis ta classe de Garde", "ShopMenuGuard_Handler");

            menu_additem(Menu, "\wMilitaire \y- \w[ \rM4 \w+ \rDeagle \w]");
            menu_additem(Menu, "\wSniper \y- \w[ \rAwp \w+ \rDeagle \w]");
            menu_additem(Menu, "\wRambo \y- \w[ \rMitrailleuse \w+ \rUsp \w+ \r30HP \w]");
            menu_additem(Menu, "\wGarde \y- \w[ \rAk47 \w+ \rDeagle \w]");
            menu_additem(Menu, "\wPyro \y- \w[ \rAug \w+ \rDeagle \w] *NEW*");

            menu_setprop(Menu, MPROP_EXITNAME, "Quitter");
            menu_setprop(Menu, MPROP_EXIT, MEXIT_ALL);
            menu_display(id, Menu, 0);
        }
    }
}

public ShopMenuPrisoner_Handler(id, Menu, Item)
{
    if(Item == MENU_EXIT || !is_user_alive(id) || cs_get_user_team(id) != CS_TEAM_T)
    {
        menu_destroy(Menu);
        return PLUGIN_HANDLED;
    }

    switch(Item)
    {
        case 0: set_user_gravity(id, 0.40);
        case 1: set_user_health(id, get_user_health(id) + 30);
        case 2: set_user_maxspeed(id, get_pcvar_float(g_PlayersSpeed));
        case 3:
        {
            give_item(id, "weapon_hegrenade");
            give_item(id, "weapon_flashbang");
            give_item(id, "weapon_smokegrenade");
        }
        case 4:
        {
            give_item(id, "weapon_smokegrenade");
            cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM);
        }
    }

    menu_destroy(Menu);
    return PLUGIN_CONTINUE;
}

public ShopMenuGuard_Handler(id, Menu, Item)
{
    if(Item == MENU_EXIT || !is_user_alive(id) || cs_get_user_team(id) != CS_TEAM_CT)
    {
        menu_destroy(Menu);
        return PLUGIN_HANDLED;
    }

    strip_user_weapons(id);
    give_item(id, "weapon_knife");

    switch(Item)
    {
        case 0:
        {
            give_item(id, "weapon_m4a1");
            cs_set_user_bpammo(id, CSW_M4A1, 9000);

            give_item(id, "weapon_deagle");
            cs_set_user_bpammo(id, CSW_DEAGLE, 3500);

            cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM);
        }
        case 1:
        {
            give_item(id, "weapon_awp");
            cs_set_user_bpammo(id, CSW_AWP, 9000);

            give_item(id, "weapon_deagle");
            cs_set_user_bpammo(id, CSW_DEAGLE, 3500);

            cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM);
        }
        case 2:
        {
            give_item(id, "weapon_m249");
            cs_set_user_bpammo(id, CSW_M249, 9000);

            give_item(id, "weapon_usp");
            cs_set_user_bpammo(id, CSW_USP, 3500);

            set_user_health(id, get_user_health(id) + 30);
        }
        case 3:
        {
            give_item(id, "weapon_ak47");
            cs_set_user_bpammo(id, CSW_AK47, 9000);

            give_item(id, "weapon_deagle");
            cs_set_user_bpammo(id, CSW_DEAGLE, 3500);

            cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM);
        }
        case 4:
        {
            give_item(id, "weapon_aug");
            cs_set_user_bpammo(id, CSW_AUG, 9000);

            give_item(id, "weapon_deagle");
            cs_set_user_bpammo(id, CSW_DEAGLE, 3500);

            cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM);
        }
    }

    menu_destroy(Menu);
    return PLUGIN_CONTINUE;
} 


[MrGarfield]

thank you for the advice, I would like to know how to recognize an amxx decompiler of a code sma so that this action does not renew thanks again

[OciXCrom]

This part of the code should never be there:

PHP Code:

public __fatal_ham_error(Ham:id, HamError:err, String:reason[])
{
    !!! Removed Phi
    if (func != -1 && callfunc_begin_i(func, -1) == 1)
    {
        callfunc_push_int(id);
        callfunc_push_int(err);
        callfunc_push_str(reason, false);
        if (callfunc_end() == 1)
        {
            fail = 0;
        }
    }
    if (fail)
    {
        set_fail_state(reason);
    }
    return 0;
} 


Especailly the "!!! Removed Phi" thing - there's no such thing in Pawn scripting.

[MrGarfield]

super thank you very much PartialCloning, the plugin works well, as I told you this plugin was really given to me I would be careful now thanks to all