[Alka]

Oh well, just opened again my server that was unused a very long time, and guess what? The plugin works fine... -.-

[zombieplague]

Originally Posted by Alka Oh well, just opened again my server that was unused a very long time, and guess what? The plugin works fine... -.-

My mistake, but, can you fix the the max heath ?

Yea, it stopped at 200+ but, can make it stop it 200 instead of 200 + ??

[Alka]

Ok. Code updated, take a look...

[joropito]

Maye this can help

PHP Code:

#include <amxmodx>
#include <engine>
#include <hamsandwich>

#define DELAY   3.0
#define MAXHEALTH       100.0

new Float:g_origin[33][3]
new Float:g_nextheal[33]

public plugin_init()
{
        RegisterHam(Ham_TakeDamage, "player", "ham_TakeDamagePost", 1)
}

public ham_TakeDamagePost(victim, inflictor, attacker, Float:damage, damagebits)
{
        if(is_user_alive(victim))
        {
                g_nextheal[victim] = halflife_time() + DELAY
                entity_get_vector(victim, EV_VEC_origin, g_origin[victim])
        }
}

public client_PreThink(id)
{
        new Float:health
        health = entity_get_float(id, EV_FL_health)
        if(is_user_alive(id) && (health < MAXHEALTH) && (halflife_time() > g_nextheal[id]))
        {
                new Float:origin[3]
                entity_get_vector(id, EV_VEC_origin, origin)
                if(origin[0] != g_origin[id][0] || origin[1] != g_origin[id][1] || origin[2] != g_origin[id][2])
                {
                        g_nextheal[id] = halflife_time() + DELAY
                        entity_get_vector(id, EV_VEC_origin, g_origin[id])
                }
                else
                {
                        server_print("Heal the man!!!");
                }
        }
} 


[5c0r-|3i0]

@zombieplague: Show your code zombieplague .And we'll try to look at it !
@joropito:

PHP Code:

stock bool:CheckMovement(id)    // xero's :)
{
    if(get_user_button(id)&(IN_JUMP|IN_FORWARD|IN_BACK|IN_MOVELEFT|IN_MOVERIGHT))
        return true
    return false
} 


To check player's movement , there are lots of methods , I think..
1) Check player speed ?
2) Check if player press any button involve to movement ?
3) Check user origin is the same with the previous origin ??
....
I wonder if there is a good way for this, >"<

[Alka]

Originally Posted by Hawk552 stop. using. static. for. everything.

Eh? do you like s?

I prefer mine anyway

[Hawk552]

Originally Posted by Alka I see useful only the posts about my code that you made above, others are useless talk. EDIT:After reading all your comments, just to feel better i rewrited the mess (err... plugin), let's see now.

This is still completely wrong...

I laid out exactly how to do it, too. Well, here's my implementation:

PHP Code:

#include <amxmodx>
#include <engine>
#include <xs>

#define PLUGIN "Health Regen"
#define VERSION "1.0"
#define AUTHOR "Alka"

#define HEAL_WAIT_TIME 3.0
#define HEAL_AMOUNT 10.0
#define MAX_HEAL 200.0

new g_iMaxPlayers;

new Float:g_vOldOrigin[33][3];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    g_iMaxPlayers = get_maxplayers();
    
    set_task(HEAL_WAIT_TIME, "task_CheckHeal", .flags="b");
}

public task_CheckHeal()
{
    for(new id = 1 ; id <= g_iMaxPlayers ; id++)
    {
        if(!is_user_alive(id))
        {
            continue;
        }
        
        new Float:vOrigin[3];
        entity_get_vector(id, EV_VEC_origin, vOrigin);
        
        if(xs_vec_equal(vOrigin, g_vOldOrigin[id]))
        {            
            new Float:fHealth = entity_get_float(id, EV_FL_health);
            
            if(fHealth < MAX_HEAL)
            {
                //fHealth = floatmin(fHealth + HEAL_AMOUNT, MAX_HEAL);
                // Following expression has better performance, but not as consistent.
                // In general, it would be better to compare before
                // setting, but the case where this happens is relatively
                // infrequent compared to the player's health being
                // either lower ten units lower or right on the max heal.
                if ( ( fHealth += HEAL_AMOUNT ) > MAX_HEAL )
                    fHealth = MAX_HEAL

                entity_set_float(id, EV_FL_health, fHealth);
                
                set_hudmessage(0, 255, 0, -1.0, 0.9, 0, 6.0, 1.0, .channel=1);
                show_hudmessage(id, "Regeneration in progress...");
            }
        }
        xs_vec_copy(vOrigin, g_vOldOrigin[id]);
    }
} 


Again: fast, robust, effective. Another tip: stop using HN. Also, you should probably use fun for the health setting stuff. I only objected to your use of fakemeta over engine, not to your use of both fakemeta and fun.

[Alka]

Ah, i see, just 2 things. He wanted to start the heal after 3 seconds since when he stopped. And what means HN :-)

[Hawk552]

Originally Posted by Alka Ah, i see, just 2 things. He wanted to start the heal after 3 seconds since when he stopped.

Yeah, it'll do that.

Originally Posted by Alka And what means HN :-)

Hungarian Notation. It's when you include tags in variable names, such as g_fLastTime as opposed to g_LastTime (although the g_ tag is also HN, it's somewhat useful).

[Alka]

Ah yea, i like to keep the track of variables type, i just don't like random names in plugin "health, VectorLength, last_time", anyway that depends on user coding style and anyone can understand it as long as it has a descriptive name, no matter of prefixes/tags.