[joeyeyey]

Hey! I am new to plugincoding. This plugin does its work, in the chat atleast. The actual damage is not reducted. I know there are plugins done for this already. But I am trying to learn. What am I doing wrong? Since the compiling works fine. Thanks in advance!
(It is for CS:GO)

PHP Code:

#include <sourcemod>
#include <sdkhooks>
#include <sdktools>

public OnPluginStart() {
    HookEvent("player_falldamage", Event_PlayerFallDamage, EventHookMode_Pre);
}

public Action:Event_PlayerFallDamage(Handle:hEvent, const String:sName[], bool:bDontBroadcast) {
    new damage = GetEventInt(hEvent, "damage");
    PrintToChatAll("Damage taken from fall BEFORE reduction: %i", damage);
    damage -= 10;
    SetEventInt(hEvent, "damage", damage); // Should not be neccesary right?
    PrintToChatAll("Damage taken from fall: %i", damage);
    return Plugin_Changed;
} 


[Darkness_]

You need to use SDKHook_OnTakeDamage. If the damagetype is DMG_FALL (1 << 5) then get the damage and reduce it by 10 like you did above and return Plugin_Changed.

[WildCard65]

PHP Code:

#include <sourcemod>
#include <sdkhooks>

public void OnMapStart()
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
            SDKHook(i, SDKHook_OnTakeDamage, OnTakeDamage);
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3], int damagecustom)
{
    if (damagetype & DMG_FALL)
    {
        damage -= 10.0;
        return Plugin_Changed;
    }
    return Plugin_Continue;
} 


[Impact123]

@joeyeyey
The reason you need to use SDKHooks is because an event hook is usually called after something happens. You can block the event, but not what triggered it.

@WildCard65
You should hook clients that join during the game.

[WildCard65]

Originally Posted by Impact123 @WildCard65 You should hook clients that join during the game.

Forgot.

[joeyeyey]

Originally Posted by Impact123 @joeyeyey The reason you need to use SDKHooks is because an event hook is usually called after something happens. You can block the event, but not what triggered it. @WildCard65 You should hook clients that join during the game.

Thanks man!