[Jezis]

Hello,

I would like to request a plugin, that will let CT when the round starts mark a specific player by aiming on him and pressing a specific color in menu to a green, red or netural(none) color.


Example: I write !mark, a menu pops up and i can mark a player in front of me green, because he is innocent, or red if he is suspicious. Also no color would be great, if missclick...


Thank you in advance <3

[Papero]

Try this:

PHP Code:

#include <sourcemod>
#include <cstrike>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

#define PLUGIN_AUTHOR "Hexah"
#define PLUGIN_VERSION "1.00"


public Plugin myinfo = 
{
    name = "Mark Players", 
    author = PLUGIN_AUTHOR, 
    description = "", 
    version = PLUGIN_VERSION, 
    url = "https://forums.alliedmods.net/showthread.php?t=301424"
};

public void OnPluginStart()
{
    RegConsoleCmd("sm_mark", Cmd_Mark);
}

public Action Cmd_Mark(int client, int args)
{
    if (!IsPlayerAlive(client))
    {
        ReplyToCommand(client, "[SM] You must be alive to do this!");
        return Plugin_Handled;
    }
    if (GetClientTeam(client) != CS_TEAM_CT)
    {
        ReplyToCommand(client, "[SM] You must be CT to do this command!");
        return Plugin_Handled;
    }
    
    Menu menu = new Menu(ColorMenuHandler);
    
    menu.SetTitle("Aim and Mark!");
    
    menu.AddItem("Red", "Red");
    menu.AddItem("Green", "Green");
    menu.AddItem("NoColor", "No Color");
    
    menu.Display(client, MENU_TIME_FOREVER);
    return Plugin_Handled;
}

public int ColorMenuHandler(Menu menu, MenuAction action, int param1, int param2)
{
    if (action == MenuAction_Select)
    {
        
        if (!IsPlayerAlive(param1))
        {
            PrintToChat(param1, "[SM] You must be alive to do this!");
            return;
        }
        if (GetClientTeam(param1) != CS_TEAM_CT)
        {
            PrintToChat(param1, "[SM] You must be CT to mark someone!");
            return;
        }
        
        char info[32];
        menu.GetItem(param2, info, sizeof(info));
        
        int target = GetClientAimTarget(param1);
        
        if (target == -1)
            return;
        
        if (StrEqual(info, "Red"))
        {
            SetEntityRenderColor(target, 255, 0, 0, 255);
        }
        else if (StrEqual(info, "Green"))
        {
            SetEntityRenderColor(target, 0, 255, 0, 255);
        }
        else
        {
            SetEntityRenderColor(target);
        }
    }
    else if (action == MenuAction_End)
    {
        delete menu;
    }
} 


All CTs Can do !mark to mark someone.

Not tested.

[nhnkl159]

Originally Posted by Papero Try this: PHP Code: #include <sourcemod> #include <cstrike> #include <sdktools> #pragma semicolon 1 #pragma newdecls required #define PLUGIN_AUTHOR "Hexah" #define PLUGIN_VERSION "1.00" public Plugin myinfo =  {     name = "Mark Players",      author = PLUGIN_AUTHOR,      description = "",      version = PLUGIN_VERSION,      url = "https://forums.alliedmods.net/showthread.php?t=301424" }; public void OnPluginStart() {     RegConsoleCmd("sm_mark", Cmd_Mark); } public Action Cmd_Mark(int client, int args) {     if (!IsPlayerAlive(client))     {         ReplyToCommand(client, "[SM] You must be alive to do this!");         return Plugin_Handled;     }     if (GetClientTeam(client) != CS_TEAM_CT)     {         ReplyToCommand(client, "[SM] You must be CT to do this command!");         return Plugin_Handled;     }          Menu menu = new Menu(ColorMenuHandler);          menu.SetTitle("Aim and Mark!");          menu.AddItem("Red", "Red");     menu.AddItem("Green", "Green");     menu.AddItem("NoColor", "No Color");          return Plugin_Handled; } public int ColorMenuHandler(Menu menu, MenuAction action, int param1, int param2) {     if (action == MenuAction_Select)     {         char info[32];         menu.GetItem(param2, info, sizeof(info));                  int target = GetClientAimTarget(param1);                  if (target == -1)             return;                  if (StrEqual(info, "Red"))         {             SetEntityRenderColor(target, 255, 0, 0, 255);         }         else if (StrEqual(info, "Green"))         {             SetEntityRenderColor(target, 0, 255, 0, 255);         }         else         {             SetEntityRenderColor(target);         }     }     else if (action == MenuAction_End)     {         delete menu;     } }  All CTs Can do !mark to mark someone. Not tested.

You aren't displaying the menu to anyone, plus always check if the player is in the correct team even inside the handler.

[Papero]

Originally Posted by nhnkl159 You aren't displaying the menu to anyone, plus always check if the player is in the correct team even inside the handler.

I forgot completely about displaying. I will add a check also for the team in the handler also.

EDIT: Updated the first post.

[Mitchell]

I think he wants something like in the Gmod TTT where you could 'mark' players as being suspicious or dead or friendly. Some player could use this to determine that a player is considered innocent instead of remembering it all round.

[Jezis]

Works great! Thank you