[SilentBr]

Hello everyone.

I'm pretty sure that there are some wallhackers in my 20vs server, and they are ruinning the gameplay. So I was wondering if there is a plugin that helps admins to identify those players.

I have an idea:

A plugin that will spawn the admin (root) as a zombie:
- will be 100% invisible
- will not make any noise

So, you can walk in the opposite way staing away from the survivors. If someone kills you, once, twice, you can investigate. The is no reason for that player killing you since you are far away and invisible.

+ maybe is possible to be also invisible for teammates;
+ maybe show for this admin who killed him, damage, etc..
+ maybe you can choose the zombie that you want (boomer and smoker are the best)

So thats it.

Thank you in advance.

[cravenge]

Hey, I remember now! You were the one who requested something from me and I'm deeply sorry for not fulfilling it due to some... stuff.

About your problem, SMAC does the job for it completely. It comes with all the anti-cheats that every server needs --► wallhacks, spinhacks, aimbots, speedhacks, etc. and I'm pretty sure that I've read somewhere that it is prohibited to share links to it though.

[dustinandband]

The wallhack plugin sometimes causes issues in L4D2 with sound. I had to remove it from my servers 1-2 years back and I was using the latest version of smac.
https://forums.alliedmods.net/archiv.../t-181642.html

[cravenge]

Originally Posted by dustinandband [...]

From the link, it was stated that it was already fixed and

... if there's another sound issue, I recommend filing a bug report (link removed) so it doesn't get lost.

[dustinandband]

Yeah, but I still had sound issues myself and I installed it just 1-2 years back (those fixes posted where from 2012). Maybe someone else can play test it for a while - I don’t have any test servers (all being used in production) but I definitely remember that being an issue.
Also it’s unlikely the author would update anything seeing as he’s banned so I didn’t want to post there...

[SilentBr]

Originally Posted by cravenge Hey, I remember now! You were...

Yes thats me! Hehe no problem, when you have time please send the files.

Originally Posted by dustinandband The wallhack plugin sometimes causes issues in L4D2 with sound. I had to remove it from my servers 1-2 years back and I was using the latest version of smac. https://forums.alliedmods.net/archiv.../t-181642.html

I have tested the latest SMAC Wallhack version and got those sound issues. I was running the plugin for about 1 week and I'm pretty sure it should get at least one wallhacker that plays on my server. We got no bans.

This plugin that I've suggest I think it would be perfect. I could check by myself if the players will shoot me as a invisible-nosound-boomer far away.

[cravenge]

Like this?

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdkhooks>
#include <sdktools>

ConVar hPlayToSelf;
bool bPlayToSelf, bCloaked[MAXPLAYERS+1];

public Plugin myinfo =
{
    name = "Cheater Detector",
    author = "cravenge (requested by SilentBr)",
    description = "Lets root admins be able to detect cheaters.",
    version = "1.2",
    url = "https://forums.alliedmods.net/forumdisplay.php?f=108"
};

public void OnPluginStart()
{
    CreateConVar("cheater_detector_version", "1.2", "Cheater Detector Version", FCVAR_SPONLY|FCVAR_NOTIFY|FCVAR_DONTRECORD);
    
    hPlayToSelf = CreateConVar("cd_play_to_self", "0", "Play own sounds to yourself?", FCVAR_SPONLY|FCVAR_NOTIFY);
    bPlayToSelf = hPlayToSelf.BoolValue;
    hPlayToSelf.AddChangeHook(OnCDCVarChanged);
    
    HookEvent("player_death", OnPlayerDeath, EventHookMode_Pre);
    
    AddAmbientSoundHook(OnAdminASCheck);
    AddNormalSoundHook(OnAdminNSCheck);
    
    RegAdminCmd("sm_cdetect", OnCDCmd, ADMFLAG_ROOT, "Apply cloaking function");
}

public void OnCDCvarChanged(ConVar cvar, const char[] sOldValue, const char[] sNewValue)
{
    bPlayToSelf = hPlayToSelf.BoolValue;
}

public Action OnCDCmd(int client, int args)
{
    if (client == 0 || !IsClientInGame(client) || GetClientTeam(client) != 3 || !IsPlayerAlive(client))
    {
        return Plugin_Handled;
    }
    
    if (bCloaked[client])
    {
        SDKUnhook(client, SDKHook_SetTransmit, OnSetTransmit);
        
        SetEntityRenderMode(client, RENDER_NORMAL);
        SetEntityRenderColor(client, _, _, _, 255);
        
        bCloaked[client] = false;
    }
    else
    {
        bCloaked[client] = true;
        
        SetEntityRenderMode(client, RENDER_TRANSALPHA);
        SetEntityRenderColor(client, _, _, _, 0);
        
        SDKHook(client, SDKHook_SetTransmit, OnSetTransmit);
    }
    
    return Plugin_Handled;
}

public Action OnSetTransmit(int entity, int other)
{
    if (IsRootAdmin(other))
    {
        return Plugin_Continue;
    }
    
    return Plugin_Handled;
}

public Action OnAdminASCheck(char sample[PLATFORM_MAX_PATH], int &entity, float &volume, int &level, int &pitch, float pos[3], int &flags, float &delay)
{
    if (!IsInfected(entity) || !IsRootAdmin(entity) || !bCloaked[entity])
    {
        return Plugin_Continue;
    }
    
    return Plugin_Stop;
}

public Action OnAdminNSCheck(int clients[MAXPLAYERS], int &numClients, char sample[PLATFORM_MAX_PATH], int &entity, int &channel, float &volume, int &level, int &pitch, int &flags, char soundEntry[PLATFORM_MAX_PATH], int &seed)
{
    if (!IsInfected(entity) || !IsRootAdmin(entity) || !bCloaked[entity])
    {
        return Plugin_Continue;
    }
    
    if (!bPlayToSelf)
    {
        return Plugin_Stop;
    }
    
    numClients = 0;
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && GetClientTeam(i) == 3 && IsRootAdmin(i) && i == entity)
        {
            clients[numClients] = i;
            numClients++;
        }
    }
    return Plugin_Changed;
}

public void OnPluginEnd()
{
    hPlayToSelf.RemoveChangeHook(OnCDCVarChanged);
    delete hPlayToSelf;
    
    UnhookEvent("player_death", OnPlayerDeath, EventHookMode_Pre);
    
    RemoveAmbientSoundHook(OnAdminASCheck);
    RemoveNormalSoundHook(OnAdminNSCheck);
}

public void OnClientDisconnect(int client)
{
    if (!IsRootAdmin(client) || !bCloaked[client])
    {
        return;
    }
    
    bCloaked[client] = false;
    SDKUnhook(client, SDKHook_SetTransmit, OnSetTransmit);
}

public Action OnPlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int died = GetClientOfUserId(event.GetInt("userid")),
         killer = GetClientOfUserId(event.GetInt("attacker"));
    
    if (IsInfected(died) && IsRootAdmin(died) && bCloaked[died] && IsSurvivor(killer))
    {
        bCloaked[died] = false;
        SDKUnhook(died, SDKHook_SetTransmit, OnSetTransmit);
        
        SetEntityRenderMode(died, RENDER_NORMAL);
        SetEntityRenderColor(died, _, _, _, 255);
        
        PrintToChat(died, "\x05[\x03CD\x05]\x04 %N\x01 killed you while cloaked!", killer);
    }
    
    return Plugin_Continue;
}

public void OnMapEnd()
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && bCloaked[i])
        {
            bCloaked[i] = false;
            SDKUnhook(i, SDKHook_SetTransmit, OnSetTransmit);
        }
    }
}

stock bool IsSurvivor(int client)
{
    return (client > 0 && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 2);
}

stock bool IsInfected(int client)
{
    return (client > 0 && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 3);
}

stock bool IsRootAdmin(int client)
{
    if (IsFakeClient(client))
    {
        return false;
    }
    
    AdminId aiValidity = GetUserAdmin(client);
    if (aiValidity == INVALID_ADMIN_ID)
    {
        return false;
    }
    
    return (GetUserFlagBits(client) & ADMFLAG_ROOT);
} 


[SilentBr]

Wow you were fast. Thank you.

How do I become an invisible-nosound-infected? Is there a command for that?

[Psyk0tik]

Originally Posted by SilentBr Wow you were fast. Thank you. How do I become an invisible-nosound-infected? Is there a command for that?

According to the code, the command is sm_cd_team. Only users with the z or root flag can use it.

[cravenge]

Originally Posted by Crasher_3637 According to the code, the command is sm_cd_team. Only users with the z or root flag can use it.

That command is for turning his teammates invisible, one of his requests.

Btw, I updated the code to include those teammates to have no sounds emitted.