Alive/Death Chat

matiaslp · **Author**

Hi

I'm looking some kind of plugin that allow dead and alive players to chat.

The only restrinction to this "all chat" it's that the other team CAN'T see other team messages.

It's something similar to move all chatting to say_team and make alive/dead indistinc

I know that there it's a plugin named "All chat" but this doesn't restrict that the other team see your team messages...

thanks in advance

xPaw · 03-31-2010 , 15:08 Re: Alive/Death Chat

Code:

#include < amxmodx >
#include < cstrike >

new g_iMsgSayText;

public plugin_init( ) {
    register_plugin( "Ghost Chat", "1.0", "xPaw" );
    
    g_iMsgSayText = get_user_msgid( "SayText" );
    
    register_event( "SayText", "EventSayText", "b", "2&#Cstrike_Chat_All" );
}

public EventSayText( const id ) {
    if( id != read_data( 1 ) )
        return;
    
    new szChannel[ 22 ], iPlayers[ 32 ], iNum;
    read_data( 2, szChannel, 21 );
    
    get_players( iPlayers, iNum, szChannel[ 17 ] ? "ach" : "bch" );
    
    if( !iNum )
        return;
    
    new szMessage[ 192 ], iPlayer, CsTeams:iTeam = cs_get_user_team( id );
    read_data( 4, szMessage, 191 );
    
    for( new i; i < iNum; i++ ) {
        iPlayer = iPlayers[ i ];
        
        if( iTeam != cs_get_user_team( iPlayer ) )
            continue;
        
        message_begin( MSG_ONE_UNRELIABLE, g_iMsgSayText, _, iPlayer );
        write_byte( id );
        write_string( szChannel );
        write_string( "" );
        write_string( szMessage );
        message_end( );
    }
}