[CliptonHeist]

Is it possible to pass a DataPack to a native and use it with something like DataPack pack = view_as<DataPack>(GetNativeCell(1));

[Kailo]

Yes, It is. All as you described. If you want to know why it works so, read more about Handles concept.

[CliptonHeist]

Hmm I'm not sure that I'm doing it right then.

Here's the native declaration:

PHP Code:

native void SBPP_BanPlayer(int iAdmin, int iTarget, int iTime, const char[] sReason, Handle pack = null); 


Implementation:

PHP Code:

public Native_SBBanPlayer(Handle plugin, int numParams)
{
    int client = GetNativeCell(1);
    int target = GetNativeCell(2);
    int time = GetNativeCell(3);
    DataPack pack = view_as<DataPack>(GetNativeCell(5));
    pack.Reset();
    char reason[128];
    GetNativeString(4, reason, 128);

    if (reason[0] == '\0')
        strcopy(reason, sizeof(reason), "Banned by SourceBans");

    if (client && IsClientInGame(client))
    {
        AdminId aid = GetUserAdmin(client);
        if (aid == INVALID_ADMIN_ID)
        {
            ThrowNativeError(SP_ERROR_NATIVE, "Ban Error: Player is not an admin.");
            return 0;
        }

        if (!GetAdminFlag(aid, Admin_Ban))
        {
            ThrowNativeError(SP_ERROR_NATIVE, "Ban Error: Player does not have BAN flag.");
            return 0;
        }
    }

    PrepareBan(client, target, time, reason, sizeof(reason), pack);
    return true;
} 


When pack.Reset() is called I get this error:

L 02/06/2019 - 10:52:35: [SM] Exception reported: Invalid data pack handle 12f00f4 (error 5) L 02/06/2019 - 10:52:35: [SM] Blaming: sbpp_main.smx L 02/06/2019 - 10:52:35: [SM] Call stack trace: L 02/06/2019 - 10:52:35: [SM] [0] DataPack.Reset L 02/06/2019 - 10:52:35: [SM] [1] Line 2291, sbpp_main.sp::Native_SBBanPlayer L 02/06/2019 - 10:52:35: [SM] [3] SBPP_BanPlayer L 02/06/2019 - 10:52:35: [SM] [4] Line 168, disconnect_ban.sp::SQL_SelectSeconds

And this is the function that calls the native:

Spoiler

PHP Code:

public void SQL_SelectSeconds(Database db, DBResultSet results, const char[] sError, any data)
{
    if(results == null)
    {
        PrintToServer("MySQL Query Failed: %s", sError);
        LogError("MySQL Query Failed: %s", sError);
        return;
    }

    if(!results.FetchRow()) return;

    int secCol, steamCol, nameCol, ipCol;
    char sSteam[64], sName[64], sIp[64];
    results.FieldNameToNum("seconds", secCol);
    results.FieldNameToNum("steamid", steamCol);
    results.FieldNameToNum("name", nameCol);
    results.FieldNameToNum("ip", ipCol);

    int seconds = results.FetchInt(secCol);
    results.FetchString(steamCol, sSteam, sizeof(sSteam));
    results.FetchString(nameCol, sName, sizeof(sName));
    results.FetchString(ipCol, sIp, sizeof(sIp));

    if(RoundFloat(seconds / 60.0) >= g_hCVDisconnectWindow.IntValue)
    {
        char sReason[128];
        g_hCVBanReason.GetString(sReason, sizeof(sReason));

        int Client = -1;
        for(int i = 1; i <= MaxClients; i++)
        {
            if(!IsValidClient(i)) continue;
            char steam[64];
            GetClientAuthId(i, AuthId_Steam2, steam, sizeof(steam));
            if(StrEqual(steam, sSteam, false))
            {
                Client = i;
                break;
            }
        }
        if(Client != -1)
            SBPP_BanPlayer(0, Client, g_hCVBanTime.IntValue, sReason);
        else
        {
            DataPack pack = new DataPack();
            pack.WriteString(sSteam);
            pack.WriteString(sName);
            pack.WriteString(sIp);
            pack.Reset();
            SBPP_BanPlayer(0, 0, g_hCVBanTime.IntValue, sReason, pack);
        }
    }

    char sQuery[1024];
    Format(sQuery, sizeof(sQuery), "DELETE FROM dc_ban WHERE steamid='%s';", sSteam);
    g_Database.Query(SQL_GenericQuery, sQuery);
} 


Is there anything wrong with what I'm doing here?

[Powerlord]

Not sure if this is causing the issue, but I would change this:

PHP Code:

DataPack pack = view_as<DataPack>(GetNativeCell(5)); 


to this

PHP Code:

DataPack pack = null;
if (numParams >= 5) {
    pack = view_as<DataPack>(GetNativeCell(5));
    pack.Reset();
} 


[Kailo]

Powerlord, optional argument not assume change of params count. I think these changes will be overkill.

CliptonHeist, Here is only one thing that i see for now, you don't have check for null handle.
And in this case you definitely pass null. You don't set param -> you default param value -> pass null.

[Mitchell]

https://sm.alliedmods.net/new-api/handles/CloneHandle