[AlejandroSk]

Nice plugin!

[Racoon]

xPaw, wtf? Can't you just write the translations in russian, using Rusiian alphabet and then save the text in UTF-8 format (without BOM)?? Транслит напрягает, честно))

[fantasist]

In my knife mode modified on CSDM everyone is set to 35hp at spawn, it is very funny with only one stab

[SnoW]

PHP Code:

[fin]
HUD_FK = Puukko tappelu !!!
HUD_ENABLE = %s on aktivoinut puukko tappelun
ALREADY_ENABLE = Puukko tappelu on aktivoitu
CMD_NOT = Sinulla ei ole valtuuksia tuohon komentoon 


[Arkshine]

Hi. Some suggestions you could/should do :

- register_clcmd("say /kf", "cmdkf") <= you forget to define a level for the command. I don't think you want all players able to use this command.
- cmdkf() : in cmd_access(), it should be 1. You define "CMD_NOT" but there is already a key in common.txt : "NO_ACC_COM" . Use new, not static ; for such function which won't called often no need.
- event_round_start() : returning PLUGIN_HANDLED does nothing. You should avoid to return something it will generate less code, you could do the same thing like the cvar in cmdkf().
- fm_strip_user_weapons, fm_give_item : Use strip_user_weapons() and give_item() from fun ; it will be more efficient.
- fw_TouchWeapon() : is_user_connected is useless here, remove it. Check instead if id is between 1 and maxplayer. Cache the value of is_user_bot.

[alan_el_more]

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <hamsandwich>

#define VERSION "1.1"

new g_enable, kf_enable, g_maxplayers, g_IsBot[33], g_IsConnected[33]

public plugin_init()
{
    register_plugin("Knife Fight", "VERSION", "alan_el_more")
    register_cvar("kf_version", VERSION, FCVAR_SERVER)
    register_dictionary("Knife_Fight.txt")
    g_enable = register_cvar("kf_enable", "1")
    register_clcmd("say /kf", "cmdkf", ADMIN_KICK)
    register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
    RegisterHam(Ham_Touch, "weaponbox", "fw_TouchWeapon")
    RegisterHam(Ham_Touch, "armoury_entity", "fw_TouchWeapon")
    RegisterHam(Ham_Touch, "weapon_shield", "fw_TouchWeapon")
    g_maxplayers = get_maxplayers()
}

public cmdkf(id, level, cid)
{
    if(get_pcvar_num(g_enable))
    {
        if (!cmd_access(id, level, cid, 1))
            return PLUGIN_HANDLED;
        
        if(kf_enable)
        {
            client_print(id, print_chat, "[KF] %L", id, "ALREADY_ENABLE")
            return PLUGIN_HANDLED;
        }
        
        new name[32]
        get_user_name(id, name, 31)
        set_hudmessage(255, 0, 0, 0.3, 0.0, 1, 0.0, 5.0, 1.0, 1.0, -1)
        show_hudmessage(0, "[KF] %L", id, "HUD_ENABLE", name)
        kf_enable = true
    }
    else
        client_print(id, print_chat, "[KF] %L", id, "KF_DISABLE")
    
    return PLUGIN_CONTINUE
}

public event_round_start()
{
    if(!kf_enable) return;
    
    set_hudmessage(255, 0, 0, 0.3, 0.0, 1, 0.0, 5.0, 1.0, 1.0, -1)
    show_hudmessage(0, "[KF] %L", LANG_PLAYER, "HUD_KF")
    
    for(new id = 1; id <= g_maxplayers; id++)
    {
        if(is_user_alive(id))
        {
            strip_user_weapons(id)
            give_item(id, "weapon_knife")
        }
    }
    
    kf_enable = false
}

public fw_TouchWeapon(weapon, id)
{
    if (kf_enable && !g_IsBot[id] && (1 <= id <= g_maxplayers))
        return HAM_SUPERCEDE;
    
    return HAM_IGNORED;
}

public client_putinserver( id )
{
    g_IsConnected[id] = true;
    
    if(is_user_bot(id))
        g_IsBot[id] = true;
}

public client_disconnect(id)
    g_IsBot[id] = g_IsConnected[id] = false; 


Does this well so?

[Arkshine]

cmdkf() : 0 -> id
fw_TouchWeapon() : do the player check before the bot.
client_putinserver() : Should be g_IsBot[id] = bool:is_user_bot(id);

[alan_el_more]

Originally Posted by arkshine cmdkf() : 0 -> id fw_TouchWeapon() : do the player check before the bot. client_putinserver() : Should be g_IsBot[id] = bool:is_user_bot(id);

sorry but i don't understand

[Exolent[jNr]]

Originally Posted by arkshine client_putinserver() : Should be g_IsBot[id] = bool:is_user_bot(id);

Why? It is defaulted to false and when the player that was a bot leaves, it's set to false again.
Therefore, it will always be false in client_putinserver().

[Arkshine]

You're right, you're right. I did not read really the code below. Though I would prefer what i've said and removing it in disconnect(). Both is fine, whatever.

sorry but i don't understand

show_hudmessage(0, "[KF] %L", id, "HUD_ENABLE", name) : Either you replace 0 by id ( depending if you want to show for all players ) either you keep 0 but you have to change id by LANG_PLAYER.

fw_TouchWeapon() : You check for bots before the check if the id is between 1 and maxplayers. But id in this foward can be > 32 and it will generate an error if so. That's why, do the last check before the bot check.