PHP Code:
#include < amxmodx >
#pragma semicolon 1
#define PLUGIN "kzh cvars detector"
#define VERSION "0.0.1"
const CVAR_MAX_LENGTH = 32;
new Trie:g_tNextCvar = Invalid_Trie;
new gmsgSayText;
new g_szLogBanFile[128];
new g_szInitCvar[CVAR_MAX_LENGTH];
public plugin_init()
{
register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );
gmsgSayText = get_user_msgid("SayText");
new szPrefixesFiles[128], szOldPrefix[CVAR_MAX_LENGTH], szNewPrefix[CVAR_MAX_LENGTH], c;
get_localinfo("amxx_configsdir", szPrefixesFiles, charsmax(szPrefixesFiles));
add(szPrefixesFiles, charsmax(szPrefixesFiles), "/hacks_prefixes.ini");
new fp = fopen(szPrefixesFiles, "rt");
if( fp && file_size(szPrefixesFiles, 1) >= 2 )
{
g_tNextCvar = TrieCreate();
while( !feof(fp) )
{
fgets(fp, szNewPrefix, charsmax(szNewPrefix));
trim( szNewPrefix );
c = szNewPrefix[0];
if( !c || c == '#' || c == '/' || c == ';' )
{
continue;
}
remove_quotes( szNewPrefix );
// strtolower( szNewPrefix ); // WTF was that ?!
if( TrieKeyExists(g_tNextCvar, szNewPrefix) ) // already this entry
{
continue;
}
if( !szOldPrefix[0] ) // first line
{
copy(g_szInitCvar, charsmax(g_szInitCvar), szNewPrefix);
}
else // if( !TrieKeyExists(g_tNextCvar, szOldPrefix) ) // should be useless, must be
{
TrieSetString(g_tNextCvar, szOldPrefix, szNewPrefix);
}
copy(szOldPrefix, charsmax(szOldPrefix), szNewPrefix);
}
fclose( fp );
}
get_localinfo("amxx_logs", g_szLogBanFile, charsmax(g_szLogBanFile));
add(g_szLogBanFile, charsmax(g_szLogBanFile), "/BhopHackChecker");
if( !dir_exists(g_szLogBanFile) )
{
mkdir(g_szLogBanFile);
}
new szDate[16];
get_time("%b%Y", szDate, charsmax(szDate));
format(g_szLogBanFile, charsmax(g_szLogBanFile), "%s/Banned_%s.log", g_szLogBanFile, szDate);
if( g_tNextCvar != Invalid_Trie )
{
register_logevent("LogEvent_EnteredTheGame", 2, "1=entered the game");
}
}
public LogEvent_EnteredTheGame()
{
new id = get_loguser_index();
if( id && !is_user_bot(id) && !is_user_hltv(id) )
{
query_client_cvar(id, g_szInitCvar, "ClientCvarResult");
}
}
get_loguser_index()
{
new szLog[80], szName[32];
read_logargv(0, szLog, charsmax(szLog));
parse_loguser(szLog, szName, charsmax(szName));
return get_user_index(szName);
}
public ClientCvarResult(id, const szCvar[], const szValue[])
{
if( is_user_connected(id) )
{
if( szValue[0] != 'B' )
{
new szName[32], szAuthid[32], szReason[14];
if( equal(szCvar, "kzh", 3) )
{
szReason = "KZHack";
}
else
{
szReason = "KZHack Custom";
}
get_user_name(id, szName, charsmax(szName));
get_user_authid(id, szAuthid, charsmax(szAuthid));
LogBan("%s %s (%s) cvar<%s>", szName, szAuthid, szReason, szCvar);
server_cmd("banid 0 %s;wait;writeid;kick #%d ^"%s^"", szAuthid, get_user_userid(id), szReason);
ColorChat(0, "^3%s ^4has been banned for ^3%s ^4!!", szName, szReason);
}
new szNextCvar[9];
if( TrieGetString(g_tNextCvar, szCvar, szNextCvar, charsmax(szNextCvar)) )
{
query_client_cvar(id, szNextCvar, "ClientCvarResult");
}
}
}
ColorChat(id, fmt[], any:...)
{
new szMsg[192];
szMsg[0] = 0x04;
vformat(szMsg[1], charsmax(szMsg)-1, fmt, 3);
message_begin(id ? MSG_ONE : MSG_ALL, gmsgSayText, _, id);
write_byte(id);
write_string(szMsg);
message_end();
}
LogBan(const fmt[], any:...)
{
new szLog[224], szDate[32];
static szMapName[32];
vformat(szLog, charsmax(szLog), fmt, 2);
get_time("%c", szDate, charsmax(szDate));
if( !szMapName[0] )
{
get_mapname(szMapName, charsmax(szMapName));
}
new fp = fopen(g_szLogBanFile, "at");
fprintf(fp, "%s : %s^n%s^n^n", szDate, szMapName, szLog);
fclose(fp);
}
Linear Mode
