[hyeNa]

Hiya.
I've got a question/request:

Is it possible to implement an automatic unhide function into this hide plugin?

PHP Code:

#include <sourcemod> 
#include <sdktools> 
#include <sdkhooks> 

#define PLUGIN_VERSION "1.0.0" 

public Plugin:myinfo =  
{ 
    name = "Simple Hide Command", 
    author = "exvel", 
    description = "Hides all players on the server for only one user who typed !hide", 
    version = PLUGIN_VERSION, 
    url = "www.sourcemod.net" 
} 

new bool:g_bHide[MAXPLAYERS+1] = {false,...}; 

public OnPluginStart() 
{ 
    RegConsoleCmd("hide", Command_Hide); 
    RegConsoleCmd("unhide", Command_Unhide); 
} 

public Action:Command_Hide(client, args) 
{ 
    g_bHide[client] = true; 
    return Plugin_Handled; 
} 

public Action:Command_Unhide(client, args) 
{ 
    g_bHide[client] = false; 
    return Plugin_Handled; 
} 

public OnClientPutInServer(client) 
{ 
    g_bHide[client] = false; 
    SDKHook(client, SDKHook_SetTransmit, Hook_SetTransmit); 
} 

public Action:Hook_SetTransmit(entity, client) 
{ 
    if (client != entity && (0 < entity <= MaxClients) && g_bHide[client]) 
        return Plugin_Handled; 
     
    return Plugin_Continue; 
} 


Because when you have !hide enabled and switch to spectator, it gets really buggy until you !unhide.
Thank you in advance

[Glite]

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <sdkhooks>

new bool:g_hide[MAXPLAYERS+1];
new g_iWeaponOwner[2048];
new g_bLateLoad;

public Plugin:myinfo =
{
    name = "Hide Players",
    author = "0wn3r",
    description = "Adds commands to show/hide other players.",
    version = "1.0",
    url = ""
};

public OnPluginStart()
{  
    RegConsoleCmd("sm_hide", HideCommand);

    if (g_bLateLoad)
    {
        for (new i = 1; i <= MaxClients; i++)
        {
            if (IsClientConnected(i) && IsClientInGame(i))
            {
                OnClientPutInServer(i);
            }
        }
    }
}

public APLRes:AskPluginLoad2(Handle:myself, bool:late, String:error[], err_max)
{
    g_bLateLoad = late;
    return APLRes_Success;
}


public OnClientPutInServer(client)
{ 
    g_hide[client] = false; 
    SDKHook(client, SDKHook_SetTransmit, Hook_SetTransmit);
    SDKHook(client, SDKHook_WeaponEquip, Hook_WeaponEquip);
    SDKHook(client, SDKHook_WeaponDrop, Hook_WeaponDrop);
}

public OnClientDisconnect_Post(client)
{
    g_hide[client] = false;
    SDKUnhook(client, SDKHook_SetTransmit, Hook_SetTransmit);
    SDKUnhook(client, SDKHook_WeaponEquip, Hook_WeaponEquip);
    SDKUnhook(client, SDKHook_WeaponDrop, Hook_WeaponDrop);

}

public OnEntityCreated(entity, const String:classname[])
{
    if (entity > MaxClients && entity < 2048)
    {
        g_iWeaponOwner[entity] = 0;
    }
}

public OnEntityDestroyed(entity)
{
    if (entity > MaxClients && entity < 2048)
    {
        g_iWeaponOwner[entity] = 0;
    }
}

public Hook_WeaponEquip(client, weapon)
{
    if (weapon > MaxClients && weapon < 2048)
    {
        g_iWeaponOwner[weapon] = client;
        SDKHook(weapon, SDKHook_SetTransmit, Hook_SetTransmitWeapon);
    }
}

public Hook_WeaponDrop(client, weapon)
{
    if (weapon > MaxClients && weapon < 2048)
    {
        g_iWeaponOwner[weapon] = 0;
        SDKUnhook(weapon, SDKHook_SetTransmit, Hook_SetTransmitWeapon);
    }
}

public Action:Hook_SetTransmit(entity, client) 
{ 
    return (g_hide[client] && IsPlayerAlive(client) && client != entity && (0 < entity <= MaxClients)) ? Plugin_Handled : Plugin_Continue;
}

public Action:Hook_SetTransmitWeapon(entity, client) 
{ 
    return (g_hide[client] && IsPlayerAlive(client) && g_iWeaponOwner[entity] && g_iWeaponOwner[entity] != client) ? Plugin_Handled : Plugin_Continue;
}

public Action:HideCommand(client, args)
{
    g_hide[client] = !g_hide[client];
    
    return Plugin_Handled;
} 


Alive check and weapons hide.

[hyeNa]

Thank you very much. It works like a charm. Is it possible to add a echo/message that says that players are now hidden?

Quick edit: Is there a server cvar or plugin that disables the annoying 'Only 1 team change allowed'? I tried mp_teamoverride and other team limiting stuff, but it's not working. :/

[Glite]

PHP Code:

public Action:HideCommand(client, args)
{
    g_hide[client] = !g_hide[client];
    if(g_hide[client])
    {
        PrintToChat(client, "People are now hidden.");
    }
    else
    {
        PrintToChat(client, "People are now visible.");
    }
    
    return Plugin_Handled;
} 


[hyeNa]

Thank you very much again. Works perfectly.