[-=STN=- MaGe]

okay used this plugin since you made it, but today i upgraded to 1.75a and redownloaded the plugin.

everytime anyone throws a nade they get this

"MuLLen * (RADIO): Fire in the hole!
You have exceeded the maximum number of HE Grenades that you can throw.
You are only allowed 0 HE Grenades per round."

my config files is below

mp_grenspampunish 1 // enable/disable plugin 
mp_grenspampunish_maxflash 2 // number of FB's allowed per round 
mp_grenspampunish_maxhe 1 // number of HE's allowed per round 
mp_grenspampunish_maxsmoke 1 // number of SG's allowed per round 
mp_grenspampunish_damage 99 // Slap them for x damage 

using

Grenade Spam Punish  1.1      [gOf]-Soul        grenspampunish.amxx  debug

[EDIT]
Tried it again with my old version and it works fine.

Grenade Spam Punish  1.0      [gOf]-Soul        grenspampunish.amxx  running

In case anyone else has this problem here is the old version.

#include <amxmodx>
#include <amxmisc>
#include <engine>
#include <csx>
#include <cstrike>

#define PLUGIN "Grenade Spam Punish"
#define VERSION "1.0"
#define AUTHOR "[gOf]-Soul"

new grencount[33]

public plugin_init(){
  register_plugin(PLUGIN  , VERSION , AUTHOR )
  register_event("ResetHUD", "funcNewRound", "b")

  register_cvar("mp_grenspampunish",          "1"  )    // enable/disable plugin
  register_cvar("mp_grenspampunish_maxflash", "2"  )    // number of FB's allowed per round
  register_cvar("mp_grenspampunish_maxhe",    "1"  )    // number of HE's allowed per round
  register_cvar("mp_grenspampunish_maxsmoke", "0"  )    // number of SG's allowed per round
  register_cvar("mp_grenspampunish_damage",   "99")    // health to remove upon punishment

  new szConfigFile[64]
  get_configsdir( szConfigFile, 63 )
  format( szConfigFile, 63, "%s/grenspampunish.cfg", szConfigFile )
  server_cmd( "exec %s", szConfigFile )
}


public funcNewRound(id) {

  if ( !get_cvar_num("mp_grenspampunish") )
    return PLUGIN_CONTINUE

  set_task(1.0, "funcResetStats", id)
  return PLUGIN_CONTINUE
}

public funcResetStats(id){
  //Get Auth ID
  new authid[32]
  new vaultkey[64],vaultdata[64]
  get_user_authid(id,authid,31)

  //reset he grenades
  format(vaultkey,63,"%s-%s", "HE Grenades", authid)
  format(vaultdata,63,"%d",0)
  set_vaultdata(vaultkey,vaultdata)

  //reset smoke grenades
  format(vaultkey,63,"%s-%s", "Smoke Grenades", authid)
  format(vaultdata,63,"%d",0)
  set_vaultdata(vaultkey,vaultdata)

  //reset flash grenades
  format(vaultkey,63,"%s-%s", "Flash Grenades", authid)
  format(vaultdata,63,"%d",0)
  set_vaultdata(vaultkey,vaultdata)

  return PLUGIN_CONTINUE
}



public grenade_throw( index , greindex , wId ){
  //Get Auth ID
  new authid[32]
  new playername[32]

  new vaultkey[64],vaultdata[64]
  get_user_authid(index ,authid,31)
  get_user_name(index, playername, 31)
  new punishlevel

  new greName[32] 
  if ( wId==CSW_HEGRENADE ){ 
    copy(greName,31,"HE Grenades")
    punishlevel = get_cvar_num("mp_grenspampunish_maxhe")
  }
  else if ( wId==CSW_SMOKEGRENADE ){
    copy(greName,31,"Smoke Grenades")
    punishlevel = get_cvar_num("mp_grenspampunish_maxsmoke")
  }
  else if ( wId==CSW_FLASHBANG ){
    copy(greName,31,"Flash Grenades")
    punishlevel = get_cvar_num("mp_grenspampunish_maxflash")
  }

  //get grenade count
  format(vaultkey,63,"%s-%s", greName, authid)
  get_vaultdata(vaultkey,vaultdata,63)
  grencount[index]=str_to_num(vaultdata)

  grencount[index]=grencount[index]+1

  //set grenade count
  format(vaultkey,63,"%s-%s", greName, authid)
  format(vaultdata,63,"%d",grencount[index])
  set_vaultdata(vaultkey,vaultdata)

  if (punishlevel < grencount[index]){
    client_print(index ,print_chat,"You have exceeded the maximum number of %s that you can throw.",greName)
    client_print(index ,print_chat,"You are only allowed %d %s per round.",punishlevel,greName)
    user_slap(index, get_cvar_num("mp_grenspampunish_damage"))
    remove_entity(greindex)

    set_hudmessage(255 ,0 ,0 ,-1.0 ,0.32 ,0 ,6.0 ,10.0 )
    show_hudmessage(0," %s was slayed because they were grenade spamming", playername)
  }
}

[Psyfire]

Like mage said, the newer Version doesnt work correct. I have the same problem but I set the 3 cvars for my map and so it worked good

Edit: It crashs the server :/

[DaSoul]

Sorry I will post a new version. Very very soon. Glad to see people actually using it. I made some quick hack changes to get it working again. But its not clean. I will work on cleaning it up a bit tonight.

EDIT: I will have to get a 1.75 environment up to test it on. Should be able to get it done tonight though.

[Xanimos]

dunno why this was just sitting in the new section.
I like the customization.

Only thing that I would like to see done to it is use pcvar's over cvars.

[DaSoul]

Originally Posted by Suicid3 dunno why this was just sitting in the new section. I like the customization. Only thing that I would like to see done to it is use pcvar's over cvars.

What is the pcvar? I will go check it out.

EDIT: I found them

EDIT: Added a beta version. I am unable to test it here at work though. So I don't even know if it will load or if I did the map specific configs correctly. I will test and update the post tonight with a fully tested version. But this should allow someone to actually use it on 1.70 and above.

cvars go into the amxx.cfg or into map specific config files.

[slurpycof]

Great plugin, hope your fixes work. +karma

[DaSoul]

I think I just fixed it. I tested it. There were some bugs in that beta. But this version I am uploading now will fix it. I think I also fixed the "punished for first nade bug" that we had seen happen on our servers.

[-=STN=- MaGe]

still slays for me

[DaSoul]

Im using this fine on our servers... do you have the proper cvars in your amxx.cfg file? Also is your "log on"? Because thats how it resets the grenade throw count.

[vittu]

Couple of things,

What broke your plugin was:

• You removed the csx include which is needed for the grenade_throw forward. You're not even using cstike so you can remove the need to include it.
• When you changed from the ResetHUD event to using the Round_Start logevent. Round start doesn't pass an id. So the nade counts never get reset to 0 for any of the clients. (resethud was fine, doesn't even really need the delay)
  

  register_logevent("funcNewRound", 2, "1=Round_Start")
  
  public funcNewRound(id) {

This should not be in the code, those will be run by amxmodx itself at the appropriate times (then you can remove the need to include amxmisc):

  new configsdir[128]
  get_configsdir(configsdir, 127)
  server_cmd("exec %s/amxx.cfg", configsdir)
  
  new currmap[128]
  get_mapname(currmap,127)
  server_cmd("exec %s/maps/%s.cfg",configsdir, currmap)

When using pcvars you don't need to set them to global varibles like below. That is almost basically what you are already doing by using pcvars.

  limitFlash = get_pcvar_num(p_grenspampunish_maxflash)
  limitHE = get_pcvar_num(p_grenspampunish_maxhe)
  limitSmoke = get_pcvar_num(p_grenspampunish_maxsmoke)

And it would be better to use a switch statement for this instead:

  if ( wId==CSW_HEGRENADE ){ 
    copy(greName,31,"HE Grenades")
    punishlevel = limitHE
    grencountindex = 0
  }
  else if ( wId==CSW_SMOKEGRENADE ){
    copy(greName,31,"Smoke Grenades")
    punishlevel = limitSmoke
    grencountindex = 1
  }
  else if ( wId==CSW_FLASHBANG ){
    copy(greName,31,"Flash Grenades")
    punishlevel = limitFlash
    grencountindex = 2
  }

Also, you don't have enough parameters for your set_hudmessage:

set_hudmessage(255 ,0 ,0 ,-1.0 ,0.32 ,0 ,6.0 ,10.0 )

I'm gonna try using this with the fixes until Brad fixes the issues with the Grenade Control plugin and rebuy.