[noodleboy347]

How could I use PrintToChat and have it show up to all of the admins?

[bl4nk]

Simple version:

PHP Code:

stock PrintToAdmins(const String:sMessage[])
{
    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            new flags = GetUserFlagBits(i);
            if (flags & ADMFLAG_GENERIC || flags & ADMFLAG_ROOT)
            {
                PrintToChat(i, sMessage);
            }
        }
    }
} 


Using a stock I wrote:

PHP Code:

stock PrintToAdmins(const String:sMessage[])
{
    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            new flags = GetUserFlagBits(i);
            if (CheckAdminFlags(i, ADMFLAG_GENERIC))
            {
                PrintToChat(i, sMessage);
            }
        }
    }
}

/**
 * Checks to see if a client has all of the specified admin flags
 *
 * @param client        Player's index.
 * @param flags            Flags to check for.
 * @return                True on admin having all flags, false otherwise.
 */
stock bool:CheckAdminFlags(client, flags)
{
    new AdminId:admin = GetUserAdmin(client);
    if (admin != INVALID_ADMIN_ID)
    {
        new count, found;
        for (new i = 0; i <= 20; i++)
        {
            if (flags & (1<<i))
            {
                count++;

                if (GetAdminFlag(admin, AdminFlag:i))
                {
                    found++;
                }
            }
        }

        if (count == found)
        {
            return true;
        }
    }

    return false;
} 


[meng]

oops, nvm, listen to that guy ^^^

[FaTony]

I'm using this:

PHP Code:

public InformAdmin (const String:rawmessage[], any:...)
{
    new String:message[MESSAGE_LENGTH];
    VFormat(message, MESSAGE_LENGTH, rawmessage, 2);
    new AdminId:id=INVALID_ADMIN_ID;
    PrintToServer(message);
    new clients=GetClientCount();
    for (new i=1;i<=clients;i++) {
        if (IsClientConnected(i)) {
            id=GetUserAdmin(i);
            if (id!=INVALID_ADMIN_ID) {
                PrintToConsole(i, message);
                PrintToChat(i, message);
                }
            }
        }
} 


[DJ Tsunami]

That's wrong FaTony, using GetClientCount() in a for-loop might leave out clients. Use MaxClients instead. Also a little more spacing to make it more readable wouldn't hurt

[exvel]

Originally Posted by FaTony I'm using this: PHP Code: public InformAdmin (const String:rawmessage[], any:...) {     new String:message[MESSAGE_LENGTH];     VFormat(message, MESSAGE_LENGTH, rawmessage, 2);     new AdminId:id=INVALID_ADMIN_ID;     PrintToServer(message);     new clients=GetClientCount();     for (new i=1;i<=clients;i++) {         if (IsClientConnected(i)) {             id=GetUserAdmin(i);             if (id!=INVALID_ADMIN_ID) {                 PrintToConsole(i, message);                 PrintToChat(i, message);                 }             }         } }

Use IsClientInGame instead of IsClientConnected. Or there may be erros.

[BrutalGoerge]

well i this it's better to look at people with root or ban, since i have admins with just a flag for reservation, or s flag for reskick immunity.

[bl4nk]

Originally Posted by BrutalGoerge well i this it's better to look at people with root or ban, since i have admins with just a flag for reservation, or s flag for reskick immunity.

That's why in my version I specified the b/z flags. Also with the second example I provided you could specify multiple flags and it would only fire if the clients had all of the flags. For example:

PHP Code:

if (CheckAdminFlags(client, ADMFLAG_GENERIC|ADMFLAG_BAN|ADMFLAG_SLAY))
{
    // do stuff
} 


I also have a slightly modified version that makes it so if any of the specified admin flags are found on the client it will trigger, if you would like that.

[p3tsin]

Originally Posted by bl4nk Also with the second example I provided you could specify multiple flags and it would only fire if the clients had all of the flags. For example: PHP Code: if (CheckAdminFlags(client, ADMFLAG_GENERIC|ADMFLAG_BAN|ADMFLAG_SLAY)) {     // do stuff }

... isnt that the same as this?

PHP Code:

if((GetUserFlagBits(client) & ADMFLAG_GENERIC|ADMFLAG_BAN|ADMFLAG_SLAY) == ADMFLAG_GENERIC|ADMFLAG_BAN|ADMFLAG_SLAY) {
    //do stuff
} 


[FaTony]

Well my code was written in early 2008 when I was a complete noob in scripting. I'll fix it.

EDIT: Fixed.

PHP Code:

public InformAdmin (const String:rawmessage[], any:...)
{
    decl String:message[MESSAGE_LENGTH];
    VFormat(message, MESSAGE_LENGTH, rawmessage, 2);
    new AdminId:id=INVALID_ADMIN_ID;
    PrintToServer(message);
    for (new i=1;i<=MaxClients;i++) {
        if (IsClientInGame(i)) {
            id=GetUserAdmin(i);
            if (id!=INVALID_ADMIN_ID) {
                PrintToConsole(i, message);
                PrintToChat(i, message);
                }
            }
        }
}