[g0oDnIgHt]

Description:
Players can force nearby Bots to drop C4 with E [use button, +use] like CS:GO

Changelog:

1.0
First release!

[doctawaald]

Hi,

Plugin sounds great!
But it does not work for me

Here is my log :

L 05/13/2021 - 078:26: [SM] Blaming: c4drop.smx
L 05/13/2021 - 078:26: [SM] Call stack trace:
L 05/13/2021 - 078:26: [SM] [0] SDKCall
L 05/13/2021 - 078:26: [SM] [1] Line 69, /home/forums/content/files/3/0/5/0/4/6/185131.attach:ropC4
L 05/13/2021 - 078:26: [SM] [2] Line 42, /home/forums/content/files/3/0/5/0/4/6/185131.attach::OnPlayerRunCmd

If i compile it from my PC i get the following :
L 05/13/2021 - 07:26:25: [SM] Blaming: c4drop.smx
L 05/13/2021 - 07:26:25: [SM] Call stack trace:
L 05/13/2021 - 07:26:25: [SM] [0] SDKCall
L 05/13/2021 - 07:26:25: [SM] [1] Line 69, C:\Users\**USER**\Downloads\c4drop.sp:ropC4
L 05/13/2021 - 07:26:25: [SM] [2] Line 42, C:\Users\**USER**\Downloads\c4drop.sp::OnPlay erRunCmd

Any help ?

[L4D2Noob]

L 05/14/2021 - 00:35:01: [SM] Blaming: c4drop.smx
L 05/14/2021 - 00:35:01: [SM] Call stack trace:
L 05/14/2021 - 00:35:01: [SM]   [0] SDKCall
L 05/14/2021 - 00:35:01: [SM]   [1] Line 69, /home/forums/content/files/3/0/5/0/4/6/185131.attach::DropC4
L 05/14/2021 - 00:35:01: [SM]   [2] Line 42, /home/forums/content/files/3/0/5/0/4/6/185131.attach::OnPlayerRunCmd

Bots don't drop bombs.

[g0oDnIgHt]

Originally Posted by doctawaald If i compile it from my PC i get the following : L 05/13/2021 - 07:26:25: [SM] Blaming: c4drop.smx L 05/13/2021 - 07:26:25: [SM] Call stack trace: L 05/13/2021 - 07:26:25: [SM] [0] SDKCall L 05/13/2021 - 07:26:25: [SM] [1] Line 69, C:\Users\**USER**\Downloads\c4drop.sp:ropC4 L 05/13/2021 - 07:26:25: [SM] [2] Line 42, C:\Users\**USER**\Downloads\c4drop.sp::OnPlay erRunCmd

Sourcemod version?

[doctawaald]

That would be version 1.10.0.6497 running on Linux.

Thanks!

[Ilusion9]

PHP Code:


#include <sourcemod>
#include <sdktools>
#include <cstrike>

public Plugin myinfo =
{
    name = "Bots drop C4",
    author = "gOoDnIgHt",
    description = "Players can force nearby Bots to drop C4 with E",
    version = "1.0",
    url = "ExaGame.ir"
};

int g_LastButtons[MAXPLAYERS + 1];

public void OnClientConnected(int client)
{
    g_LastButtons[client] = 0;
}

public void OnPlayerRunCmdPost(int client, int buttons, int impulse, const float vel[3], const float angles[3], int weapon, int subtype, int cmdnum, int tickcount, int seed, const int mouse[2])
{
    if (!IsClientInGame(client) 
        || IsFakeClient(client)
        || !IsPlayerAlive(client)
        || GetClientTeam(client) != CS_TEAM_T)
    {
        return;
    }
    
    int botTarget = GetClientAimTarget(client, true);
    if (botTarget == -1
        || !IsEntityClient(botTarget)
        || !IsFakeClient(botTarget))
    {
        return;
    }
    
    int c4 = GetPlayerWeaponSlot(botTarget, CS_SLOT_C4);
    if (c4 == -1)
    {
        return;
    }
    
    float origin[3];
    float botOrigin[3];
    
    GetClientAbsOrigin(client, origin);
    GetClientAbsOrigin(botTarget, botOrigin);
    
    if (GetVectorDistance(origin, botOrigin) > 200.0)
    {
        return;
    }
    
    PrintHintText(client, "Press E to take the bomb!");
    
    if (view_as<bool>(buttons & IN_USE) 
        && !view_as<bool>(g_LastButtons[client] & IN_USE))
    {
        CS_DropWeapon(botTarget, c4, false);
        EquipPlayerWeapon(client, c4);
    }
    
    g_LastButtons[client] = buttons;
}

bool IsEntityClient(int client)
{
    return (client > 0 && client <= MaxClients);
} 


[doctawaald]

Originally Posted by Ilusion9 PHP Code: #include <sourcemod> #include <sdktools> #include <cstrike> public Plugin myinfo = {     name = "Bots drop C4",     author = "gOoDnIgHt",     description = "Players can force nearby Bots to drop C4 with E",     version = "1.0",     url = "ExaGame.ir" }; int g_LastButtons[MAXPLAYERS + 1]; public void OnClientConnected(int client) {     g_LastButtons[client] = 0; } public void OnPlayerRunCmdPost(int client, int buttons, int impulse, const float vel[3], const float angles[3], int weapon, int subtype, int cmdnum, int tickcount, int seed, const int mouse[2]) {     if (!IsClientInGame(client)          || IsFakeClient(client)         || !IsPlayerAlive(client)         || GetClientTeam(client) != CS_TEAM_T)     {         return;     }          int botTarget = GetClientAimTarget(client, true);     if (botTarget == -1         || !IsEntityClient(botTarget)         || !IsFakeClient(botTarget))     {         return;     }          int c4 = GetPlayerWeaponSlot(botTarget, CS_SLOT_C4);     if (!c4)     {         return;     }          float origin[3];     float botOrigin[3];          GetClientAbsOrigin(client, origin);     GetClientAbsOrigin(botTarget, botOrigin);          if (GetVectorDistance(origin, botOrigin) > 200.0)     {         return;     }          PrintHintText(client, "Press E to take the bomb!");          if (view_as<bool>(buttons & IN_USE)          && !view_as<bool>(g_LastButtons[client] & IN_USE))     {         FakeClientCommand(botTarget, "say_team I dropped the bomb!");         CS_DropWeapon(botTarget, c4, false);         EquipPlayerWeapon(client, c4);     }          g_LastButtons[client] = buttons; } bool IsEntityClient(int client) {     return (client > 0 && client <= MaxClients); }

This code works.
But it keeps spamming the HintText when you look at any bot in range, T or CT
Then when you press use on the selected bot (with or without bomb it execs the say message)

[Ilusion9]

Originally Posted by doctawaald This code works. But it keeps spamming the HintText when you look at any bot in range, T or CT Then when you press use on the selected bot (with or without bomb it execs the say message)

I fixed those, check the post again

[doctawaald]

Originally Posted by Ilusion9 I fixed those, check the post again

Works like a charm!

Thanks