[Ardonicek]

dHUD Round | Timeleft

Hello! I made another plugin. It's calleed DHUD Round | Timeleft, as you can see.

INFO:
The name tells everything, it shows round timeleft and current round in dHUD.
For this plugin you don't need the dhud include.

REQUIRED:
AMXX



I hope you will like it! It's pretty simple.
I've provided also some screens.

[Kia]

There is no need to create a task each time a player joins since you are showing the HUD to everyone.
Just use 0 as index and create the Task at plugin_init / when first player joins.

[Ardonicek]

Is it better now?

[PyPKjE20]

Wow nice, good sistem ;)

[yokomo]

Create an entity and set it think, since it call every 1 second and it global task. See:

Now use entity and think

PHP Code:

#include <amxmodx>
//#include <amxmisc>
#include <engine>

/* Special thanks to Blizzard for dhudmessae stock. */

new round;
new timestring[31]
new const ClassHudInfo[] = "ent_hudinfo"

public plugin_init()
{
    register_plugin("dHUD Top message", "1.0", "Noobish")
    register_event("HLTV", "roundstart", "a", "1=0", "2=0");
    register_event("TextMsg", "restartround", "a", "2=#Game_will_restart_in");
    //set_task(1.0, "hudclient", 0, _, _, "b") 
    register_cvar( "sv_hudmsgver", "1.0" ); 
    
    new ent = create_entity("info_target")
    entity_set_string(ent, EV_SZ_classname, ClassHudInfo)
    entity_set_float(ent, EV_FL_nextthink, get_gametime()+10.0)
    
    register_think(ClassHudInfo, "OnHudInfoThink")
}

//public hudclient()
public OnHudInfoThink(ent)
{    
    static timeleft; timeleft = get_timeleft() 
    get_time("%H:%M",timestring,8)
        
    set_dhudmessage(128, 128, 128, -1.0, 0.02, 0, 0.1, 0.9, 0.1, 0.1)
    show_dhudmessage(0, "[Round: %d | %d:%02d]", round, timeleft / 60, timeleft % 60);
    
    entity_set_float(ent, EV_FL_nextthink, get_gametime()+1.0)
}
public restartround()
{
    round = 0;    
}
public roundstart()
{
    round += 1;    
}

////////////////////////////////////////////////////////////
/*      DHUD MESSAGE STOCKS - BY BLIZZARD                 */
////////////////////////////////////////////////////////////
stock __dhud_color;
stock __dhud_x;
stock __dhud_y;
stock __dhud_effect;
stock __dhud_fxtime;
stock __dhud_holdtime;
stock __dhud_fadeintime;
stock __dhud_fadeouttime;
stock __dhud_reliable;
 
stock set_dhudmessage( red = 0, green = 160, blue = 0, Float:x = -1.0, Float:y = 0.65, effects = 2, Float:fxtime = 6.0, Float:holdtime = 3.0, Float:fadeintime = 0.1, Float:fadeouttime = 1.5, bool:reliable = false )
{
    #define clamp_byte(%1)       ( clamp( %1, 0, 255 ) )
    #define pack_color(%1,%2,%3) ( %3 + ( %2 << 8 ) + ( %1 << 16 ) )
 
    __dhud_color       = pack_color( clamp_byte( red ), clamp_byte( green ), clamp_byte( blue ) );
    __dhud_x           = _:x;
    __dhud_y           = _:y;
    __dhud_effect      = effects;
    __dhud_fxtime      = _:fxtime;
    __dhud_holdtime    = _:holdtime;
    __dhud_fadeintime  = _:fadeintime;
    __dhud_fadeouttime = _:fadeouttime;
    __dhud_reliable    = _:reliable;
 
    return 1;
}
 
stock show_dhudmessage( index, const message[], any:... )
{
    new buffer[ 128 ];
    new numArguments = numargs();
 
    if( numArguments == 2 )
    {
        send_dhudMessage( index, message );
    }
    else if( index || numArguments == 3 )
    {
        vformat( buffer, charsmax( buffer ), message, 3 );
        send_dhudMessage( index, buffer );
    }
    else
    {
        new playersList[ 32 ], numPlayers;
        get_players( playersList, numPlayers, "ch" );
 
        if( !numPlayers )
        {
            return 0;
        }
 
        new Array:handleArrayML = ArrayCreate();
 
        for( new i = 2, j; i < numArguments; i++ )
        {
            if( getarg( i ) == LANG_PLAYER )
            {
                while( ( buffer[ j ] = getarg( i + 1, j++ ) ) ) {}
                j = 0;
 
                if( GetLangTransKey( buffer ) != TransKey_Bad )
                {
                    ArrayPushCell( handleArrayML, i++ );
                }
            }
        }
 
        new size = ArraySize( handleArrayML );
 
        if( !size )
        {
            vformat( buffer, charsmax( buffer ), message, 3 );
            send_dhudMessage( index, buffer );
        }
        else
        {
            for( new i = 0, j; i < numPlayers; i++ )
            {
                index = playersList[ i ];
 
                for( j = 0; j < size; j++ )
                {
                    setarg( ArrayGetCell( handleArrayML, j ), 0, index );
                }
 
                vformat( buffer, charsmax( buffer ), message, 3 );
                send_dhudMessage( index, buffer );
            }
        }
 
        ArrayDestroy( handleArrayML );
    }
 
    return 1;
}
 
stock send_dhudMessage( const index, const message[] )
{
    message_begin( __dhud_reliable ? ( index ? MSG_ONE : MSG_ALL ) : ( index ? MSG_ONE_UNRELIABLE : MSG_BROADCAST ), SVC_DIRECTOR, _, index );
    {
        write_byte( strlen( message ) + 31 );
        write_byte( DRC_CMD_MESSAGE );
        write_byte( __dhud_effect );
        write_long( __dhud_color );
        write_long( __dhud_x );
        write_long( __dhud_y );
        write_long( __dhud_fadeintime );
        write_long( __dhud_fadeouttime );
        write_long( __dhud_holdtime );
        write_long( __dhud_fxtime );
        write_string( message );
    }
    message_end();
} 


[Going Dutch]

Simple yet useful.

Well done.

[Groven]

Thanks! Will use it.

[ConnorMcLeod]

Originally Posted by yokomo Create an entity and set it think, since it call every 1 second and it global task.

Task is ok for this.



dhud is from Arkshine, not from BLIZZARD.

[Ardonicek]

Blizzard added it to one my plugin and inserted the 3 lines that it's by him.

[Blizzard_87]

Originally Posted by ConnorMcLeod dhud is from Arkshine, not from BLIZZARD.

Originally Posted by Ardonicek Blizzard added it to one my plugin and inserted the 3 lines that it's by him.

i just used the code from the include file Arkshine made so i didnt need to include files for compiling from webcompiler.. to make it easy for people... i did not make the stock... just to clarify.