[Meelo]

Hi, i have plugin what detect value of fps_max client cvar.

It's detecting fps_max 99.5 and if someone type fps_max 99.5. or 99.5.1 he automatically gain 100.5 fps.

I'm using this:

public fps(id,const cvar[],const value[])
{
if(str_to_num(value) <= 99.5) {
		        return;

		}else{

                user_kill(id,1)
      }
}

The solution would be if we can detect if there are more than 4 chars in fps_max command but i dont know how to make it

[Bugsy]

Check if strlen( value ) > 4?

[Meelo]

okay, it works but i found another problem:

str_to_num see only if values are 100,99,98. If i type 99.9 fps are increases to 100.1 - 100.4 even if i'm checking if fps_max is 99.5

[Napoleon_be]

have u tried this?

PHP Code:

public fps(id, const cvar[], Float:value)
{
    if(value <= 99.5)
    {
        return;

    }
    else
    {
        user_kill(id,1)
    }
} 


[Meelo]

i tried different way, now yours and nothing happens

[Napoleon_be]

Perhaps you should share your whole code then.

[Bugsy]

Napoleon_be, the query_client_cvar() callback function passes the cvar and value as a string, you cannot convert it to a Float: like you have.

Meelo, you should convert to a float instead of integer when doing the validation.

PHP Code:

if ( str_to_float( value ) > 99.5 )
{
    user_kill( id , 1 );
} 


If this doesn't solve your problem, you can validate that their fps_max value is in the appropriate float format (only 1 decimal point). The below will kill a player if they have something like 99.5.1 or 90.3.2 (invalid float) or if their value is formatted correctly, but over 99.5.

PHP Code:

public fps( id , const cvar[] , const value[] )
{
    new iCount , bool:bInvalid;
    new iLen = strlen( value );
    
    for ( new i = 0 ; i < iLen ; i++ )
    {
        if ( value[ i ] == '.' )
        {
            if ( ++iCount > 1 )
            {
                bInvalid = true;
                break;
            }
        }
    }
    
    if ( bInvalid || ( str_to_float( value ) > 99.5 ) )
    {
        if ( bInvalid )
            client_print( id , print_chat , "* Please fix your fps_max value, %s is formatted incorrectly." , value );

        user_kill( id , 1 );
    }    
} 


[Meelo]

It works perfecly, thanks. One more question is why you check two times bInvalid?

PHP Code:

if ( bInvalid || ( str_to_float( value ) > 99.5 ) )
    {
        if ( bInvalid )
            client_print( id , print_chat , "* Please fix your fps_max value, %s is formatted incorrectly." , value );

        user_kill( id , 1 );
    }    
} 


[fysiks]

Originally Posted by Meelo It works perfecly, thanks. One more question is why you check two times bInvalid? PHP Code: if ( bInvalid || ( str_to_float( value ) > 99.5 ) )     {         if ( bInvalid )             client_print( id , print_chat , "* Please fix your fps_max value, %s is formatted incorrectly." , value );         user_kill( id , 1 );     }     }

Because there are two ways to get into that first if statement. If the value is greater than 99.5 then you will kill the player but it will only print the message if bInvalid is true.

[Bugsy]

I added that so it can notify the player why he is getting slayed each time. You may also want to advise that he needs to lower his FPS.

PHP Code:

if ( bInvalid || ( str_to_float( value ) > 99.5 ) )
{
    if ( bInvalid )
        client_print( id , print_chat , "* Please fix your fps_max value, %s is formatted incorrectly." , value );
    else
        client_print( id , print_chat , "* Please lower your fps_max value less than or equal to 95.5" );
        
    user_kill( id , 1 );    
}