[LazyKeviin]

Hey!

I'm trying to make a AWP only server but the thing is i don't find any good awp + knife only plugins?

All i need is:
* all players spawn with AWP + Knife every round
* block the buytime
* A good Ranking/Points system

Thats all i need

[Pilo]

Message me in discord Pilo#8253

[Kolapsicle]

Feel free to give this a whirl.

[Pilo]

Originally Posted by Kolapsicle Feel free to give this a whirl.

Nice plugin..

[Kolapsicle]

Originally Posted by Pilo Nice plugin..

Thanks. Sorry for hijacking your sale. I had prepared to make the plugin for OP when I first came across his/her post, but I didn't have time. The plugin I posted doesn't correctly loop the grenade slot, and it will only remove the first grenade. You could probably work out a deal with OP to address it, and maybe add additional features if either you, or OP are interested.

[Pilo]

Originally Posted by Kolapsicle Thanks. Sorry for hijacking your sale. I had prepared to make the plugin for OP when I first came across his/her post, but I didn't have time. The plugin I posted doesn't correctly loop the grenade slot, and it will only remove the first grenade. You could probably work out a deal with OP to address it, and maybe add additional features if either you, or OP are interested.

That's alright, good job about the plugin, I learned some.

[B3none]

Originally Posted by Kolapsicle Feel free to give this a whirl.

Made some small edits:

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

#define WEAPON_KNIFE 2
#define WEAPON_C4 4

public Plugin myinfo = 
{
    name = "AWPs Only", 
    author = "Kolapsicle", 
    description = "Spawns players with AWPs, and disables buy zones.", 
    version = "1.0"
};

ConVar cvBuyZones, cvRemoveKnives, cvRemoveC4, cvWeaponOverride;
ArrayList alBuyZones;

public void OnPluginStart()
{
    cvBuyZones = CreateConVar("sm_awpsonly_enable_buyzones", "0", "Should we enables buy zones?", _, true, 0.0, true, 1.0);
    if (cvBuyZones != null)
    {
        cvBuyZones.AddChangeHook(onBuyZonesChanged);
    }
    
    cvRemoveKnives = CreateConVar("sm_awpsonly_remove_knives", "0", "Should we remove knives from players on spawn?", _, true, 0.0, true, 1.0);
    cvRemoveC4 = CreateConVar("sm_awpsonly_remove_c4", "1", "Should we remove the bomb from players on spawn?", _, true, 0.0, true, 1.0);
    cvWeaponOverride = CreateConVar("sm_awpsonly_weapon_override", "weapon_awp", "Overrides players' primary weapons. (Note: Invalid weapon names may cause server issues!)");
    
    HookEvent("player_spawn", Event_PlayerSpawn);
    AutoExecConfig(true, "awpsonly");
}

public void onBuyZonesChanged(ConVar convar, const char[] oldValue, const char[] newValue)
{
    SetBuyZones(view_as<bool>(StringToInt(newValue, 2)));
}

public void OnMapStart()
{
    if (alBuyZones != null)
    {
        delete alBuyZones;
    }
    
    alBuyZones = new ArrayList(1);
    
    GetBuyZones();
    SetBuyZones(GetConVarBool(cvBuyZones));
}

public Action Event_PlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));
    if (!IsValidClient(client))
    {
        return Plugin_Continue;
    }
    
    // Delay strip function in order to catch C4
    RequestFrame(StripNextTick, client);
    return Plugin_Continue;
}

void StripNextTick(int client)
{
    if (!IsValidClient(client))
    {
        return;
    }
    
    StripWeapons(client, GetConVarBool(cvRemoveKnives), GetConVarBool(cvRemoveC4));
    
    char classname[32];
    cvWeaponOverride.GetString(classname, sizeof(classname));
    if (StrContains(classname, "weapon_", false) != -1)
    {
        GivePlayerItem(client, classname);
        
        return;
    }
    
    GivePlayerItem(client, "weapon_awp");
}

void StripWeapons(int client, bool removeKnife = false, bool removeC4 = true)
{
    for (int i = 0; i < 5; i++)
    {
        if (!removeKnife && i == WEAPON_KNIFE)
        {
            continue;
        }
        
        if (!removeC4 && i == WEAPON_C4)
        {
            continue;
        }
        
        int weapon = GetPlayerWeaponSlot(client, i);
        if (!IsValidEntity(weapon))
        {
            continue;
        }
        
        RemovePlayerItem(client, weapon);
        AcceptEntityInput(weapon, "Kill");
    }
}

void GetBuyZones()
{
    char classname[32];
    
    for (int i = MaxClients; i < GetMaxEntities(); i++)
    {
        if (!IsValidEntity(i))
        {
            continue;
        }
        
        GetEntityClassname(i, classname, sizeof(classname));
        if (StrEqual("func_buyzone", classname, false))
        {
            alBuyZones.Push(i);
        }
    }
}

void SetBuyZones(bool enabled = true)
{
    for (int i = 0; i < alBuyZones.Length; i++)
    {
        int zone = alBuyZones.Get(i);
        if (!IsValidEntity(zone))
        {
            continue;
        }
        
        AcceptEntityInput(zone, enabled ? "Enable" : "Disable");
    }
}

bool IsValidClient(int client)
{
    return 0 < client <= MaxClients && IsClientInGame(client) && 2 <= GetClientTeam(client) <= 3;
}