[Carrion]

Hello...

here is Nice OFF Spec by sector

sma

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <cstrike>
#include <colorchat>

new nNumplayers, nMaxplayers

public plugin_init() {
    register_plugin("Nice OFF Spec", "1.0", "sector")
    register_logevent("nice_off_spec", 2, "1=Round_Start")
    nMaxplayers = get_maxplayers()
}

public nice_off_spec() {
    nNumplayers = get_playersnum()
    if(nNumplayers == nMaxplayers) {
        for(new s = 1; s <= nMaxplayers; s++)
        {
            new players[32], pnum, tempid;
            get_players(players, pnum, "h");
            for (new x ; x<pnum ; x++)
            {
                tempid = players[x];
                switch( cs_get_user_team(tempid) ) {
                    case CS_TEAM_CT: continue;
                    case CS_TEAM_T: continue;
                    case CS_TEAM_UNASSIGNED: { 
                        if (!(get_user_flags(tempid) & ADMIN_IMMUNITY)) {
                            server_cmd("kick # %d ^"[AMXX] Spectating Not Allowed when SERVER is FULL!^"", get_user_userid(tempid));
                        }
                    }
                    case CS_TEAM_SPECTATOR: {
                        if (!(get_user_flags(tempid) & ADMIN_IMMUNITY)) {
                            server_cmd("kick # %d ^"[AMXX] Spectating Not Allowed when SERVER is FULL!^"", get_user_userid(tempid));
                            ColorChat(0, NORMAL, "^1[^4AMXX^1] ^3All Spectators Kicked!")
                        }
                    }
                    
                }
            }
        }
    }
}

/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1049\\ f0\\ fs16 \n\\ par }
*/ 


i did lil changes and my server crashed

PHP Code:

public plugin_init() {
    register_plugin("Spectator Kicker", "1.0", "sector")
    register_logevent("nice_off_spec", 2, "1=Round_Start")
    register_logevent("nice_off_spec", 2, "1&Restart_Round_", "1=Game_Commencing")
    register_event("TextMsg", "nice_off_spec", "a", "2=#Game_will_restart_in");
    nMaxplayers = register_cvar("max_players", "2")
}



public nice_off_spec() {
    nNumplayers = get_playersnum()
    if(nNumplayers >= get_pcvar_num(nMaxplayers)) { 


kick all spectators when there is >= 2 users on server

[+ARUKARI-]

try this?

PHP Code:

public nice_off_spec() 
{
    // Now Playing Players num.
    new nNumPlayers = get_playersnum();

    // there is >= 2 users?
    if (nNumPlayers < get_pcvar_num(nMaxplayers))
        return PLUGIN_CONTINUE;

    new players[MAX_PLAYERS], pnum, uid;
    get_players(players, pnum, "h");

    // for loop playing players.
    for (new i = 0; i < nNumPlayers; i++)
    {
        uid = players[i];
        switch (cs_get_user_team(uid))
        {
            case CS_TEAM_UNASSIGNED, CS_TEAM_SPECTATOR: 
            {
                if (!(get_user_flags(uid) & ADMIN_IMMUNITY)) 
                    server_cmd("kick # %d ^"[AMXX] Spectating Not Allowed when SERVER is FULL!^"", get_user_userid(uid));
            }
            case CS_TEAM_CT: 
                continue;
            case CS_TEAM_T: 
                continue;
        }
    }
    ColorChat(0, NORMAL, "^1[^4AMXX^1] ^3All Spectators Kicked!");
    return PLUGIN_CONTINUE;
} 


[Carrion]

Originally Posted by +ARUKARI- try this?

at the end i got this

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <cstrike>
#include <colorchat>

#define MAX_PLAYERS 32

new nMaxplayers

public plugin_init() {
    register_plugin("Nice OFF Spec", "1.0", "sector")
    register_logevent("nice_off_spec", 2, "1=Round_Start")
    register_logevent("nice_off_spec", 2, "1&Restart_Round_", "1=Game_Commencing")
    register_event("TextMsg", "nice_off_spec", "a", "2=#Game_will_restart_in");
    nMaxplayers = register_cvar("nos_max_players", "25")
}

public nice_off_spec() {
    
    // Now Playing Players num.
    new nNumPlayers = get_playersnum();
    
    // there is >= 2 users?
    if (nNumPlayers < get_pcvar_num(nMaxplayers))
        return PLUGIN_CONTINUE;
    
    new players[MAX_PLAYERS], pnum, uid;
    get_players(players, pnum, "h");
    
    // for loop playing players.
    for (new i = 0; i < nNumPlayers; i++)
    {
        uid = players[i];
        switch (cs_get_user_team(uid))
        {
            case CS_TEAM_UNASSIGNED, CS_TEAM_SPECTATOR: 
            {
                if (get_user_flags(uid) & ADMIN_IMMUNITY)  return PLUGIN_HANDLED;
                server_cmd("kick #%d ^"[AMXX] Spectating Not Allowed when SERVER is FULL!^"", get_user_userid(uid));
                ColorChat(0, NORMAL, "^1[^4AMXX^1] ^3All Spectators Kicked!");
            }
            case CS_TEAM_CT: 
                continue;
            case CS_TEAM_T: 
                continue;
        }
    }
    return PLUGIN_CONTINUE;
} 

/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1049\\ f0\\ fs16 \n\\ par }
*/ 


[Bugsy]

Try this

PHP Code:


#include <amxmodx>
#include <cstrike>
#include <colorchat>

#define MAX_PLAYERS 32

const KickTeams = ( ( 1 << _:CS_TEAM_UNASSIGNED ) | ( 1 << _:CS_TEAM_SPECTATOR ) );

new nMaxplayers

public plugin_init() 
{
    register_plugin( "Nice OFF Spec" , "1.0" , "sector" );
    
    register_logevent( "nice_off_spec" , 2 , "1=Round_Start" );
    register_logevent( "nice_off_spec" , 2 , "1&Restart_Round_", "1=Game_Commencing" );
    register_event( "TextMsg" , "nice_off_spec" , "a" , "2=#Game_will_restart_in" );
    
    nMaxplayers = register_cvar( "nos_max_players" , "25" );
}

public nice_off_spec() 
{
    new players[ MAX_PLAYERS ] , pnum , uid , bool:bSpecsKicked;
    
    get_players( players , pnum , "h" );
    
    if ( pnum >= get_pcvar_num( nMaxplayers ) )
    {
        for ( new i = 0 ; i < pnum ; i++ )
        {
            uid = players[ i ];
            
            if ( !( get_user_flags( uid ) & ADMIN_IMMUNITY ) && ( KickTeams & ( 1 << _:cs_get_user_team( uid ) ) ) )  
            {
                server_cmd( "kick #%d ^"[AMXX] Spectating Not Allowed when SERVER is FULL!^"" , get_user_userid( uid ) );
                bSpecsKicked = true;
            }
        }
        
        if ( bSpecsKicked )
            ColorChat( 0 , NORMAL , "^1[^4AMXX^1] ^3All Spectators Kicked!" );
    }
}