[Ark_Procession]

is it possible to add a .ini file and put the skynames available for random there?

#include < amxmodx >

new gPluginMode;

new const gSkies[ ][ ] =
{
	"2desert", "alien1", "alien2", "alien3",
	"black", "city", "cliffe", "desert",
	"dusk", "morning","neb1", "neb6",
	"neb7", "space", "xen10", "xen8",
	"xen9", "night", "black","green",
	"blue", "backalley", "city1", "morningdew",
	"hav", "cliff", "office", "grnplsnt",
	"tornsky", "doom1", "cx", "de_storm",
	"snowlake_", "tornsky", "trainyard", "tsccity_",
	"snow", "2desert", "des"
};

public plugin_init( )
{
	register_plugin( "Random Skies", "2.0.0", "tuty" );
	
	gPluginMode = register_cvar( "sv_skies_mode", "1" );  // 0 - disabled, 1 - random skies
}

public plugin_end( )
{
	if( get_pcvar_num( gPluginMode ) == 1 )
	{
		server_cmd( "sv_skyname %s", gSkies[ random_num( 0, charsmax( gSkies ) ) ] );
	}
}

[DJEarthQuake]

Custom Sky - Add a cool new sky to dull maps has an INI file already for each map. There's also a working maintained weather plugin to change sky depending on weather feed and time of day or night. Weather rain or snow is random. Whatever city it is set to it will mimic the weather there along with matching skies.

[Ark_Procession]

Originally Posted by DJEarthQuake Custom Sky - Add a cool new sky to dull maps has an INI file already for each map. There's also a working maintained weather plugin to change sky depending on weather feed and time of day or night. Weather rain or snow is random. Whatever city it is set to it will mimic the weather there along with matching skies.

1 - Option can't randomize skies, that is the main thing i wanted.

2 - not looking for weather plugin tho it seems to be an impressive plugin!

Thanks for answering

[CryWolf]

Use this: https://forums.alliedmods.net/showthread.php?t=243202 in your plugin is verry simple, you can use at ZP5.0 mod to see more info and how skyes are applied from a .ini file, done this a lot of times.

[Ark_Procession]

Originally Posted by CryWolf Use this: https://forums.alliedmods.net/showthread.php?t=243202 in your plugin is verry simple, you can use at ZP5.0 mod to see more info and how skyes are applied from a .ini file, done this a lot of times.

Thanks Cry! that seems really useful.

Not entirely related question:

https://wiki.alliedmods.net/Configur...p_Config_Files

why using amxx method of configs, they are not applied immediatly? they require a round restart after a few seconds to apply. it's annoying.
also, if the skybox is changed like with the plugin i posted, the skymap won't change at first changelevel, but it requires two changelevels. i think its related.

[CryWolf]

Yes it is releated! look

PHP Code:

#include <amxmodx>
#include <amx_settings_api>

new const ZP_SETTINGS_FILE[] = "skyes.ini"

new const sky_names[][] = { "space, sky2, sky3, etc" }

new g_sky_custom_enable = 1
new Array:g_sky_names
new g_SkyArrayIndex

#define SKYNAME_MAX_LENGTH 32

public plugin_init()
{
    register_plugin("[ZP] Effects: Lighting", "0.0.1", "ZP Dev Team")
    
    // Set a random skybox?
    if (g_sky_custom_enable)
    {
        new skyname[SKYNAME_MAX_LENGTH]
        ArrayGetString(g_sky_names, g_SkyArrayIndex, skyname, charsmax(skyname))
        set_cvar_string("sv_skyname", skyname)
    }
    
    // Disable sky lighting so it doesn't mess with our custom lighting
    set_cvar_num("sv_skycolor_r", 0)
    set_cvar_num("sv_skycolor_g", 0)
    set_cvar_num("sv_skycolor_b", 0)
}

public plugin_precache()
{
    // Initialize arrays
    g_sky_names = ArrayCreate(SKYNAME_MAX_LENGTH, 1)
    
    // Load from external file
    if (!amx_load_setting_int(ZP_SETTINGS_FILE, "Custom Skies", "ENABLE", g_sky_custom_enable))
        amx_save_setting_int(ZP_SETTINGS_FILE, "Custom Skies", "ENABLE", g_sky_custom_enable)
    amx_load_setting_string_arr(ZP_SETTINGS_FILE, "Custom Skies", "SKY NAMES", g_sky_names)

    // If we couldn't load from file, use and save default ones
    new index
    if (ArraySize(g_sky_names) == 0)
    {
        for (index = 0; index < sizeof sky_names; index++)
            ArrayPushString(g_sky_names, sky_names[index])
        
        // Save to external file
        amx_save_setting_string_arr(ZP_SETTINGS_FILE, "Custom Skies", "SKY NAMES", g_sky_names)
    }

    if (g_sky_custom_enable)
    {
        // Choose random sky and precache sky files
        new path[128], skyname[SKYNAME_MAX_LENGTH]
        g_SkyArrayIndex = random_num(0, ArraySize(g_sky_names) - 1)
        ArrayGetString(g_sky_names, g_SkyArrayIndex, skyname, charsmax(skyname))
        formatex(path, charsmax(path), "gfx/env/%sbk.tga", skyname)
        precache_generic(path)
        formatex(path, charsmax(path), "gfx/env/%sdn.tga", skyname)
        precache_generic(path)
        formatex(path, charsmax(path), "gfx/env/%sft.tga", skyname)
        precache_generic(path)
        formatex(path, charsmax(path), "gfx/env/%slf.tga", skyname)
        precache_generic(path)
        formatex(path, charsmax(path), "gfx/env/%srt.tga", skyname)
        precache_generic(path)
        formatex(path, charsmax(path), "gfx/env/%sup.tga", skyname)
        precache_generic(path)
    }
} 


Credits goes to MeRcyLeZZ for his awesome Zombie Plague Mod (respect man).
It's applied round by round, im using it on Biohazard Mod.

[Ark_Procession]

Originally Posted by CryWolf Yes it is releated! look PHP Code: #include <amxmodx> #include <amx_settings_api> new const ZP_SETTINGS_FILE[] = "skyes.ini" new const sky_names[][] = { "space, sky2, sky3, etc" } new g_sky_custom_enable = 1 new Array:g_sky_names new g_SkyArrayIndex #define SKYNAME_MAX_LENGTH 32 public plugin_init() {     register_plugin("[ZP] Effects: Lighting", "0.0.1", "ZP Dev Team")          // Set a random skybox?     if (g_sky_custom_enable)     {         new skyname[SKYNAME_MAX_LENGTH]         ArrayGetString(g_sky_names, g_SkyArrayIndex, skyname, charsmax(skyname))         set_cvar_string("sv_skyname", skyname)     }          // Disable sky lighting so it doesn't mess with our custom lighting     set_cvar_num("sv_skycolor_r", 0)     set_cvar_num("sv_skycolor_g", 0)     set_cvar_num("sv_skycolor_b", 0) } public plugin_precache() {     // Initialize arrays     g_sky_names = ArrayCreate(SKYNAME_MAX_LENGTH, 1)          // Load from external file     if (!amx_load_setting_int(ZP_SETTINGS_FILE, "Custom Skies", "ENABLE", g_sky_custom_enable))         amx_save_setting_int(ZP_SETTINGS_FILE, "Custom Skies", "ENABLE", g_sky_custom_enable)     amx_load_setting_string_arr(ZP_SETTINGS_FILE, "Custom Skies", "SKY NAMES", g_sky_names)     // If we couldn't load from file, use and save default ones     new index     if (ArraySize(g_sky_names) == 0)     {         for (index = 0; index < sizeof sky_names; index++)             ArrayPushString(g_sky_names, sky_names[index])                  // Save to external file         amx_save_setting_string_arr(ZP_SETTINGS_FILE, "Custom Skies", "SKY NAMES", g_sky_names)     }     if (g_sky_custom_enable)     {         // Choose random sky and precache sky files         new path[128], skyname[SKYNAME_MAX_LENGTH]         g_SkyArrayIndex = random_num(0, ArraySize(g_sky_names) - 1)         ArrayGetString(g_sky_names, g_SkyArrayIndex, skyname, charsmax(skyname))         formatex(path, charsmax(path), "gfx/env/%sbk.tga", skyname)         precache_generic(path)         formatex(path, charsmax(path), "gfx/env/%sdn.tga", skyname)         precache_generic(path)         formatex(path, charsmax(path), "gfx/env/%sft.tga", skyname)         precache_generic(path)         formatex(path, charsmax(path), "gfx/env/%slf.tga", skyname)         precache_generic(path)         formatex(path, charsmax(path), "gfx/env/%srt.tga", skyname)         precache_generic(path)         formatex(path, charsmax(path), "gfx/env/%sup.tga", skyname)         precache_generic(path)     } }  Credits goes to MeRcyLeZZ for his awesome Zombie Plague Mod (respect man). It's applied round by round, im using it on Biohazard Mod.

awesome! thanks!