[raizo11]

I want to detect if 2 or more players from terrorsits is close to 1 from Ct... Any ideea?

I can't think of other ways

public client_PreThink()
{ 
    static X[32], Y[32], XNum, YNum, Float:XOrigin[ 3 ], Float:YOrigin[ 3 ], Float:fDistance

    get_players(X, XNum, "ae", "TERRORIST") 
    get_players(Y, YNum, "ae", "CT") 

    pev(XNum, pev_origin, XOrigin)
    pev(YNum, pev_origin, YOrigin)

    fDistance = get_distance_f( XOrigin, YOrigin)

    if( fDistance <= 100.0)
    {
        if (XNum == 2 && YNum == 1) 
        { 
            // something
        } 
    }
}

[E1_531G]

XNum and YNum aren't indexes, they hold the amount of players.

[Natsheh]

Don't use client think use a 1.0 loop task or entity think 1.0 sec length for such purpose.

Then use find entity in sphere natives.

Also your "way" doesn't work. As e1531G stated.

[raizo11]

already not working

#include <amxmodx>
#include <fakemeta>
#include <cstrike>
 
public plugin_init() 
{     
	register_forward(FM_TraceHull,"fm_tracehull",1);
}


public fm_tracehull(Float:start[3],Float:end[3],noMonsters,hull,id,trace)
{
	if(!is_user_connected(id) || !is_user_alive(id))
		return FMRES_IGNORED;
	
	new hit = get_tr2(trace,TR_pHit);

	if(!is_user_alive(hit))
		return FMRES_IGNORED;

	new CsTeams:team = cs_get_user_team(id)

	new Origin[3]
	get_user_origin(id, Origin);
	
	new enemycount=0
	
	new ent = -1
	while((ent = engfunc(EngFunc_FindEntityInSphere, ent, Origin, 150.0)) != 0)
	{
		if(!pev_valid(ent) || !is_user_alive(ent))
			continue
		
		if (team==cs_get_user_team(ent))
			continue
		
		enemycount++
		
		if (enemycount>1)
		{
			set_tr2(trace,TR_flFraction,1.0);
			client_print(0, print_chat, "[TEST]");
		}
	}

	return FMRES_IGNORED;
}

[JocAnis]

First time seeing client prethink without index...so its serverframe() ? Go with id there and loop

[Bugsy]

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <cstrike>
 
public plugin_init() 
{     
    set_task( 0.1 , "FindPlayers" , .flags="b" );
}


public FindPlayers()
{
    new iPlayers[ 32 ] , iNum , iPlayer , Float:fOrigin[ 3 ] , iEntity , iEnemyCount , szName[ 32 ];
    
    get_players( iPlayers , iNum , "ae" , "CT" );

    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        pev( iPlayer , pev_origin , fOrigin );
        
        iEntity = -1;
        iEnemyCount = 0;
        
        while( ( iEntity = engfunc( EngFunc_FindEntityInSphere , iEntity , fOrigin , 150.0 ) ) != 0 )
        {
            if ( is_user_alive( iEntity ) && ( cs_get_user_team( iEntity ) == CS_TEAM_T ) )
                iEnemyCount++;
        }
        
        if ( iEnemyCount >= 2 )
        {
            get_user_name( iPlayer , szName , charsmax( szName ) );
            client_print( 0 , print_chat , "%d enemies near %s" , iEnemyCount , szName );
        }
    }
} 


[raizo11]

Thanks !

[edon1337]

Originally Posted by Bugsy PHP Code: #include <amxmodx> #include <fakemeta> #include <cstrike>   public plugin_init()  {          set_task( 0.1 , "FindPlayers" , .flags="b" ); } public FindPlayers() {     new iPlayers[ 32 ] , iNum , iPlayer , Float:fOrigin[ 3 ] , iEntity , iEnemyCount , szName[ 32 ];          get_players( iPlayers , iNum , "ae" , "CT" );     for ( new i = 0 ; i < iNum ; i++ )     {         iPlayer = iPlayers[ i ];                  pev( iPlayer , pev_origin , fOrigin );                  iEntity = -1;         iEnemyCount = 0;                  while( ( iEntity = engfunc( EngFunc_FindEntityInSphere , iEntity , fOrigin , 150.0 ) ) != 0 )         {             if ( is_user_alive( iEntity ) && ( cs_get_user_team( iEntity ) == CS_TEAM_T ) )                 iEnemyCount++;         }                  if ( iEnemyCount >= 2 )         {             get_user_name( iPlayer , szName , charsmax( szName ) );             client_print( 0 , print_chat , "%d enemies near %s" , iEnemyCount , szName );         }     } }

The variables could be created globally to avoid creating every 10th of a second.

[JocAnis]

- was drunk enough to ask whoops-