[purple_pixie]

So the amount of damage you do depends on the money you had *before you bought weapons* ??

Fair enough, I suppose ... but it seems a little wrong.

Also, if someone disables this plugin in-game all it will do is freeze the players' levels at their current state.
(If you don't want to check the cvar value in the damage event, which I fully understand, then the spawn event should set PlayerLevel back to 0 before checking the flag)

And do you really need to query "is_user_alive" at player_spawn? (You may well - been a while since I played with the glorious HamSandwich)

[ConnorMcLeod]

Originally Posted by purple_pixie And do you really need to query "is_user_alive" at player_spawn? (You may well - been a while since I played with the glorious HamSandwich)

Yes, because Spawn is called 1 time when a player enter the server.

[SnoW]

Hmmm... Interesting plugin. Armor basically does the same thing, but what a hey.

[Nextra]

Originally Posted by purple_pixie So the amount of damage you do depends on the money you had *before you bought weapons* ??

Yeah, I think it would be better to hook Money message so you set levels depending on the actual money.

You could even do both things and make a cvar for switching between the two.

And I think you should implement cvars for both the required money and the multi for each level.

[alan_el_more]

Originally Posted by Nextra Yeah, I think it would be better to hook Money message so you set levels depending on the actual money.

How do I do that?

[joaquimandrade]

Originally Posted by alan_el_more How do I do that?

Check this:

http://forums.alliedmods.net/showthread.php?t=84761

Originally Posted by ConnorMcLeod Yes, because Spawn is called 1 time when a player enter the server.

I just learned that yesterday. Since this plugin uses a cstrike function on spawn, everytime someone joined the server (without the user_is_alive check), it gave me an error. Everybody should be aware of that.

A hamsandwich hook to the spawn event gets called everytime a player joins the server.

[alan_el_more]

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

enum Level
{
    Level0,
    Level1,
    Level2,
    Level3
}

new Level:PlayerLevels[33]
new Float:LevelDamageMultiplier[Level] = {_:1.0,_:1.5,_:2.0,_:2.5}

new g_enabled, money

public plugin_init()
{
    register_plugin("Damage by the amount of money", "1.1.2", "alan_el_more")
    
    RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
    RegisterHam(Ham_Spawn,"player","playerSpawn",1)
    
    money = get_user_msgid("Money")
    register_message(money,"hook_money")
    
    g_enabled = register_cvar("amx_dmg_money", "1", FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_UNLOGGED|FCVAR_SPONLY)
}

public playerSpawn(id)
{
    if(get_pcvar_num(g_enabled))
    {
        check_level(id)
    }
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage, damage_type)
{
    if(get_pcvar_num(g_enabled))
        SetHamParamFloat(4, damage * LevelDamageMultiplier[PlayerLevels[attacker]])
}

public hook_money(msg_id,msg_dest,id)
{
    if(!get_pcvar_num(g_enabled)) return PLUGIN_CONTINUE
        
    check_level(id)
    
    return PLUGIN_CONTINUE
}

public check_level(id)
{
    if(get_pcvar_num(g_enabled))
    {
        new money = cs_get_user_money(id);
        if(money < 5000)
        {
            PlayerLevels[id] = Level0;
        }
        else if(money <= 10000)
        {
            PlayerLevels[id] = Level1;
        }
        else if(money <= 14000)
        {
            PlayerLevels[id] = Level2;
        }
        else
        {
            PlayerLevels[id] = Level3;
        }
    }
} 


It is well so?

[Nextra]

Originally Posted by alan_el_more It is well so?

Yeah, that should be ok. But you can leave out the enabled check in both spawn and the money hook because you already do it in check_level.


You should change check_level to:

PHP Code:

public check_level(id)
{
    if(get_pcvar_num(g_enabled))
    {
        new money = cs_get_user_money(id);
        if(money < 5000)
        {
            PlayerLevels[id] = Level0;
        }
        else if(money <= 10000)
        {
            PlayerLevels[id] = Level1;
        }
        else if(money <= 14000)
        {
            PlayerLevels[id] = Level2;
        }
        else
        {
            PlayerLevels[id] = Level3;
        }
    }
    else
    {
        PlayerLevels[id] = Level0;
    }
} 


Then you can leave out the cvar check on Ham_TakeDamage as the players level will be reset on the next round at the latest.

[purple_pixie]

Also, PlayerSpawn will have to be:

public playerSpawn(id)
{
        check_level(id)
}

Otherwise it won't reset the level to 0 because check_level is never called ;-)

[Nextra]

As I said, he should remove the cvar check in Spawn and Money hook.