[FarHaN_ShaiKh]

Guys i want a plugin, when a player will enter/join the server if his steamid is not registered he will kick and we will decide their teams by their steam id, here you can check a code which i got from a friend but it is not working anyone plz help.

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <reapi>

#define PLUGIN  "New Plug-In"
#define VERSION "1.0"
#define AUTHOR  "Author"

new n_steamid[ MAX_PLAYERS + 1 ];
new n_connectid[ MAX_PLAYERS + 1 ];
new filename[ 256 ];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    get_configsdir(filename,255);
    format(filename,255,"%s/matchplayers.ini",filename);
}

public client_authorized( id )
{
    get_user_authid(id, n_connectid, charsmax( n_connectid ));
}

public client_putinserver(id)
{
    new line, len, Data[ 128 ];
    new team[ 8 ];

    while((line = read_file( filename , line , Data , 127 , len) ) != 0 ) 
    {
          parse(Data, team,7, n_steamid,7);

        if( n_connectid[id] != n_steamid[id] )
        {
            server_cmd("amx_kick #%s You Have No Entry To The Server^n", n_steamid);
        }

          if( equal( team, "CT") )
          {
              rg_set_user_team(id, TEAM_CT, MODEL_AUTO, true);

        }

        if( equal( team, "TT") )
          {
              rg_set_user_team(id, TEAM_TERRORIST, MODEL_AUTO, true);

        }
    }

} 


[r0ma]

I'm not use reapi, test:

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <reapi>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "r0ma'"

#define FILE "steamid.ini"

new Trie:g_Steam;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_concmd("amx_reload_steamid", "concmd_reload");
}

public plugin_cfg() {
    g_Steam = TrieCreate();
    
    load_configfile();
}

public concmd_reload(id) {
    if(!(get_user_flags(id) & ADMIN_BAN)) {
        return PLUGIN_HANDLED;
    }
    
    load_configfile();
    
    return PLUGIN_HANDLED;
}

public load_configfile() {
    TrieClear(g_Steam);
    
    new szConfigDir[64], szBuffer[128], szTeam[6], szSteam[33];

    get_configsdir(szConfigDir, charsmax(szConfigDir));
    formatex(szBuffer, charsmax(szBuffer), "%s/%s", szConfigDir, FILE);
    
    if(!file_exists(szBuffer))
        set_fail_state("File '%s' not found.", szBuffer);
    
    new file = fopen(szBuffer, "rt");
    
    if(!file)
        set_fail_state("Failed to open file.");

    while(!feof(file)) {
        fgets(file, szBuffer, charsmax(szBuffer));
        trim(szBuffer);

        if(!szBuffer[0] || szBuffer[0] == ';')
            continue;

        strtok(szBuffer, szSteam, charsmax(szSteam), szTeam, charsmax(szTeam), '=');

        trim(szSteam);
        trim(szTeam);
        
        if(!szTeam[0])
            continue;
        
        if(szTeam[0] == 'T' || szTeam[0] == 't')
            TrieSetCell(g_Steam, szSteam, 1);
        else
            TrieSetCell(g_Steam, szSteam, 2);
    }
    
    fclose(file);
    
    console_print(0, "[AMXX] Loaded %d steams from file.", TrieGetSize(g_Steam));
}

public client_putinserver(id) {
    new szSteam[33], iTeam;
    
    get_user_authid(id, szSteam, charsmax(szSteam));
    
    if(TrieKeyExists(g_Steam, szSteam)) {
        TrieGetCell(g_Steam, szSteam, iTeam);
        
        if(iTeam == 1)
            rg_set_user_team(id, TEAM_TERRORIST, MODEL_AUTO, true);
        else
            rg_set_user_team(id, TEAM_CT, MODEL_AUTO, true);
    }
    else
        server_cmd("kick #%d ^"You Have No Entry To The Server^"", get_user_userid(id));
} 


in steamid.ini:
STEAM_ID = CT
STEAM_ID = TT