[tousif]

I've read this https://forums.alliedmods.net/showthread.php?t=123445 tutorial regarding dynamic items . How can we show shop for different team ? T and CT ? .
Any help didnt find anything like that in that tutorial .

[addons_zz]

On the 'public _item_add( iPlugin, iParams )' function declaration, you need to receive 4 paramenters instead of 3. Note, '( iPlugin, iParams )' are not the parameters. The parameters I am talking about are those you get with 'get_param(1)'.

The new parameter will the the CS_TEAM's constants on which you are adding the item. Them you can add different itens for CT and T, handling on the this function to which team you are adding items.
On that function, when you add a item, it goes to the global Array 'g_aItems'. Now you will have to create more 1 global Array, for the other team items, and add the items for that team to it.

Next step is to change the function 'ShowShopMenu( iPlayer, iPage )'. On it, you will the get user team by their id using 'cs_get_user_team(1)' function. And create the menu with the CT items, or with the TR items. Remember, the items are on the arrays you created on the last step.

Cs team use example:

    new CsTeams:currentTeam = cs_get_user_team( playerId );
    
    if( currentTeam == CS_TEAM_CT )
    {
        ...
    } 
    else if( currentTeam == CS_TEAM_T )
    {
        ...
    }

Update:

Using a switch for the team selection seens to be more appropriate.

    switch( cs_get_user_team( playerId ) )
    {
        case CS_TEAM_CT:
        {
            ...
        }
        case CS_TEAM_T:
        {
            ...
        }
    }

[KiLLeR.]

Try this:

PHP Code:

enum _:ItemData
{
    ItemName[ 32 ],
    ItemCost
}; 


>

PHP Code:

enum _:ItemData
{
    ItemName[ 32 ],
    ItemCost,
    ItemTeam
}; 


------------------------------

PHP Code:

public _item_add( iPlugin, iParams )
{
    // create an array to hold our item data
    new eItemData[ ItemData ];
    
    // get item name from function
    get_string( 1, eItemData[ ItemName ], charsmax( eItemData[ ItemName ] ) );
    
    // get item cost from function
    eItemData[ ItemCost ] = get_param( 2 );
    
    // add item to array and increase size
    ArrayPushArray( g_aItems, eItemData );
    g_iTotalItems++;
    
    // return the index of this item in the array
    // this creates the unique item index
    return ( g_iTotalItems - 1 );
} 


>

PHP Code:

public _item_add( iPlugin, iParams )
{
    // create an array to hold our item data
    new eItemData[ ItemData ];
    
    // get item name from function
    get_string( 1, eItemData[ ItemName ], charsmax( eItemData[ ItemName ] ) );
    
    // get item cost from function
    eItemData[ ItemCost ] = get_param( 2 );

    // get item team from function
    eItemData[ ItemTeam ] = clamp( get_param( 3 ), 0, 2 );
    
    // add item to array and increase size
    ArrayPushArray( g_aItems, eItemData );
    g_iTotalItems++;
    
    // return the index of this item in the array
    // this creates the unique item index
    return ( g_iTotalItems - 1 );
} 


------------------------------

PHP Code:

  for( new i = 0; i < g_iTotalItems; i++ )
    {
        // get item data from array
        ArrayGetArray( g_aItems, i, eItemData );
        
        // format item for menu
        formatex( szItem, charsmax( szItem ), "%s\R\y%i", eItemData[ ItemName ], eItemData[ ItemCost ] );
        
        // pass array index to menu to find information about it later
        num_to_str( i, szNum, charsmax( szNum ) );
        
        // add item to menu
        menu_additem( hMenu, szItem, szNum );
    } 


>

PHP Code:

  for( new i = 0; i < g_iTotalItems; i++ )
    {
        // get item data from array
        ArrayGetArray( g_aItems, i, eItemData );
       
        if(eItemData[ ItemTeam ] && (eItemData[ ItemTeam ] != cs_get_user_team(iPlayer)))
            continue;

        // format item for menu
        formatex( szItem, charsmax( szItem ), "%s\R\y%i", eItemData[ ItemName ], eItemData[ ItemCost ] );
        
        // pass array index to menu to find information about it later
        num_to_str( i, szNum, charsmax( szNum ) );
        
        // add item to menu
        menu_additem( hMenu, szItem, szNum );
    } 


In .inc file:

PHP Code:

shop_item_add( const szName[ ], const iCost ); 


>

PHP Code:

shop_item_add( const szName[ ], const iCost, const iTeam ); // 0 = Both teams, 1 = Terrorist, 2 = Counter-Terrorist 


[tousif]

Thanks for the help . Will try it .

[KiLLeR.]

The above code is updated, because i forgot to add options for both teams.