[speedykiller2012]

Hello AlliedModders,

I Need a Plugin that Creates Logs whenever an admin Connect to the server and when ever he leaves
+ His Time spend at the server today

Like this:
Nick : abc
Connect time :- 12:00
Disconnect Time :- 2:00

Thats Little Too Hard for u Guys i Guess!!

But please this plugin means lot to me !!

[OciXCrom]

That's pretty easy actually. I'll try and make it on my phone, so go easy on me if it doesn't work.

PHP Code:

#include <amxmodx>

#define PLUGIN_VERSION "1.0"
#define FLAG_ADMIN ADMIN_SLAY

enum _:Info
{
    eName[32],
    eJoinTime[9],
    eLeaveTime[9]
}

new const g_szLogFile[] = "AdminInfo.log"
new g_szInfo[33][Info]

public plugin_init()
    register_plugin("Admin Information", PLUGIN_VERSION, "OciXCrom")

public client_putinserver(id)
{
    if(!(get_user_flags(id) & FLAG_ADMIN))
        return

    get_user_name(id, g_szInfo[id][eName], charsmax(g_szInfo[][eName]))
    get_time("%X", g_szInfo[id][eJoinTime], charsmax(g_szInfo[][eJoinTime]))
}

public client_disconnect(id)
{
    if(!(get_user_flags(id) & FLAG_ADMIN))
        return

    get_time("%X", g_szInfo[id][eLeaveTime], charsmax(g_szInfo[][eLeaveTime]))
    log_to_file(g_szLogFile, "Nick: %s | Connect Time: %s | Disconnect Time: %s",
    g_szInfo[id][eName], g_szInfo[id][eJoinTime], g_szInfo[id][eLeaveTime])
} 


[speedykiller2012]

Originally Posted by OciXCrom That's pretty easy actually. I'll try and make it on my phone, so go easy on me if it doesn't work. PHP Code: #include <amxmodx> #define PLUGIN_VERSION "1.0" #define FLAG_ADMIN ADMIN_SLAY enum _:Info {     eName[32],     eJoinTime[9],     eLeaveTime[9] } new const g_szLogFile[] = "AdminInfo.log" new g_szInfo[33][Info] public plugin_init()     register_plugin("Admin Information", PLUGIN_VERSION, "OciXCrom") public client_putinserver(id) {     if(!(get_user_flags(id) & FLAG_ADMIN))         return     get_user_name(id, g_szInfo[id][eName], charsmax(g_szInfo[id][eName]))     get_time("%X", g_szInfo[id][eJoinTime], charsmax(g_szInfo[id][eJoinTime])) } public client_disconnect(id) {     if(!(get_user_flags(id) & FLAG_ADMIN))         return     get_time("%X", g_szInfo[id][eLeaveTime], charsmax(g_szInfo[id][eLeaveTime]))     log_to_file(g_szLogFile, "Nick: %s | Connect Time: %s | Disconnect Time: %s",     g_szInfo[id][eName], g_szInfo[id][eJoinTime], g_szInfo[id][eLeaveTime]) }

Error: Expected token: "]", but found "-identifier-" on line 24
Error: Invalid expression, assumed zero on line 24
Error: Invalid expression, assumed zero on line 24
Error: Too many error messages on one line on line 24

Compilation aborted.
4 Errors.

[OciXCrom]

Try now.

[SomewhereLost]

If admin connects and disconnects from server several times in a day, how will it look like?
Isn't it better just to count the hours of spending in a server in one day?

[fysiks]

It depends on the purpose of the request. Since he requested logging of connections and disconnections, he got what he asked for.

[xxxperts]

This will create a folder named "admin_log_files" in "/addons/amxmodx/data"
and logs folder will have text file named with date of entries
example: 09-03-2016.txt

Output

[ NAME ]: ZOF 'X | Maxime
[ AUTHID ]: STEAM_0:0:7358907
[ LOGIN ]: 09/03/2016 - 12:52:27
[ LOGOUT ]: 09/03/2016 - 12:53:44
[ PLAYED TIME ]: 1 Minute

Code

PHP Code:

#include < amxmodx >
#include < amxmisc >

#pragma semicolon    1
#define MAX_PLAYERS    32

new const PLUGIN[ ] = "ADMIN_LOG";
new const VERSION[ ]= "0.3";
new const AUTHOR[ ] = "ZOF 'X";

enum _:_ADMIN_DATA {
    
    NAME[ 32 ],
    AUTHID[ 35 ],
    LOGIN[ 32 ],
    LOGOUT[ 32 ]
};

new gLogFilePath[ 64 ];
new gAdminInfo[ MAX_PLAYERS + 1 ][ _ADMIN_DATA ];

public plugin_init( ) {
    
    register_plugin( PLUGIN, VERSION, AUTHOR );
    register_cvar( "zofx_admin_log", AUTHOR, FCVAR_SERVER );
    
    get_datadir( gLogFilePath, sizeof( gLogFilePath ) - 1 );
    add( gLogFilePath, sizeof( gLogFilePath ) - 1, "/admin_log_files" );

    if( !dir_exists( gLogFilePath ) ) mkdir( gLogFilePath );
    
}

public client_putinserver( index ) {
    
    if( is_user_admin( index ) ) {
        
        get_user_info( index, "name", gAdminInfo[ index ][ NAME ], sizeof( gAdminInfo[ ][ NAME ] ) - 1 );
        get_user_authid( index, gAdminInfo[ index ][ AUTHID ], sizeof( gAdminInfo[ ][ AUTHID ] ) - 1 );
        get_time( "%d/%m/%Y - %H:%M:%S", gAdminInfo[ index ][ LOGIN ], sizeof( gAdminInfo[ ][ LOGIN ] ) - 1 );
    }
    
}

public client_disconnect( index ) {
    
    
    if( is_user_admin( index ) ) {
        
        new tPlayedTime = ( get_user_time( index, 1) / 60 );
        get_time( "%d/%m/%Y - %H:%M:%S", gAdminInfo[ index ][ LOGOUT ], sizeof( gAdminInfo[ ][ LOGOUT ] ) - 1 );
        
        new iDate[ 64 ], gLogFile[ 64 ];
        
        get_time( "%d-%m-%Y", iDate, sizeof( iDate ) - 1 );
        formatex( gLogFile, sizeof( gLogFile ) - 1, "%s/%s.txt", gLogFilePath, iDate );
        
        static tFile[ 255 ];
        formatex( tFile, sizeof( tFile ) - 1, "[ NAME ]: %s ^n[ AUTHID ]: %s ^n[ LOGIN ]: %s ^n[ LOGOUT ]: %s ^n[ PLAYED TIME ]: %d Minute%s ^n^n", gAdminInfo[ index ][ NAME ], gAdminInfo[ index ][ AUTHID ], gAdminInfo[ index ][ LOGIN ], gAdminInfo[ index ][ LOGOUT ], tPlayedTime, tPlayedTime == 1 ? "" : "s" );
        
        write_file( gLogFile, tFile );
    }
} 


EDIT: Sorry. I forgot to mention that you have to create folder named "admin_log_files" in "/addons/amxmodx/data"

Update. You dont need to create folder manually.

Thanks to OciXCrom

[SomewhereLost]

Sounds just like what I've said. I'll test it out.

[speedykiller2012]

Originally Posted by OciXCrom Try now.

Thankyou Bro <3

[OciXCrom]

Originally Posted by xxxperts EDIT: Sorry. I forgot to mention that you have to create folder named "admin_log_files" in "/addons/amxmodx/data"

You can use mkdir(const dirname[]) to create a folder after checking whether it exists or not with dir_exists(const dirname[]).