[Shzzzzz]

https://forums.alliedmods.net/showthread.php?p=221246
This plugin gives 16k dollarss since 1 round(like mp_startmoney). If possible, can someone make that it starts after first(pistol) round?
Been looking whole day for it and couldn't find it, so sorry if it already exists. Should be simple edit if i am not mistaken, as i myself have no clue about pawning.(Sorry if English sucks, not my first language)

[@LeX]

simple, count the rounds

Spoiler

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

new MONEY;
new szRoundCount; // Variable for Rounds Count

public plugin_init()
{
    register_plugin("round_money","0.7","SweatyBanana")
    
    MONEY = register_cvar("round_money","16000")
    
    /* Register LANG file */
    register_dictionary("rmlang.txt")
    
    register_logevent("new_round", 2, "1=Round_Start")
}
public new_round()
{
    szRoundCount++; // If register event new round it will increase
    // Check if N Round is 2 or whatever number you want
    // 2 because when a single player joins the server it counts 0, when the second player joins, an restart it will be called and is an new round then, will count +1 ( after first round will count +1 again, then will equal with 2 )
    if(szRoundCount == 2)
    {
        new players[32], playerCount, i, player, pMoney;
        pMoney = get_pcvar_num(MONEY)
        
        get_players(players,playerCount);
        
        for(i=0;i<playerCount;i++)
        {
            player = players[i];
            if(cs_get_user_money(player) < pMoney)
            {
                cs_set_user_money(player, pMoney);
                client_print(player,print_chat,"%L",LANG_PLAYER,"MONEY_AMOUNT",pMoney)
            }
        } 
    }
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/ 


but it depends on how you use this plugin together with the others
if you have problems, you can send me a message (then you can tell me exactly how you use it)

if you want not to count endlessly, you can make a statement that checks the number and skips it

Spoiler

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

new MONEY;
new szRoundCount; // Variable for Rounds Count

public plugin_init()
{
    register_plugin("round_money","0.7","SweatyBanana")
    
    MONEY = register_cvar("round_money","16000")
    
    /* Register LANG file */
    register_dictionary("rmlang.txt")
    
    register_logevent("new_round", 2, "1=Round_Start")
}
public new_round()
{

    // If 'szroundcount' is greater than 2 then pass
    if(szRoundCount > 2)
        return 0;

    szRoundCount++; // If register event new round it will increase
    // Check if N Round is 2 or whatever number you want
    // 2 because when a single player joins the server it counts 0, when the second player joins, an restart it will be called and is an new round then, will count +1 ( after first round will count +1 again, then will equal with 2 )
    if(szRoundCount == 2)
    {
        new players[32], playerCount, i, player, pMoney;
        pMoney = get_pcvar_num(MONEY)
        
        get_players(players,playerCount);
        
        for(i=0;i<playerCount;i++)
        {
            player = players[i];
            if(cs_get_user_money(player) < pMoney)
            {
                cs_set_user_money(player, pMoney);
                client_print(player,print_chat,"%L",LANG_PLAYER,"MONEY_AMOUNT",pMoney)
            }
        } 
    }

    return 0;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/ 


with a few debug messages it would look something like this: https://termbin.com/z50a

[Shzzzzz]

Thank you, Alex! I will try both tonight.

[@LeX]

no problem, theoretically they do the same thing
but if you are skeptical about the "memory load", in the second version the count stops after it exceeds 2 ( ie, it will go through the hook without doing anything else )

[Shzzzzz]

So, there is few problems and idk if warmup is the cause of them. People get 16k while in warmup and after sv_restart they get no money from plugin.
P.S. i will try to use 1 of them again later

[@LeX]

Originally Posted by Shzzzzz So, there is few problems and idk if warmup is the cause of them. People get 16k while in warmup and after sv_restart they get no money from plugin. P.S. i will try to use 1 of them again later

that's why i said it depends on how you use it
so i understand that you have a warmup system/plugin that lasts one round, then after the restart there is another round where you want pistols to be played, then after that round offer them $16k

we can reset the count when the round is restarted

I'm going to make everything simple, I'm going to add a boolean variable that detects whether or not a restart has been made in the round

Try This:

PHP Code:


#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <engine>

new MONEY;
new szRoundCount;
new bool:IsRestarting

public plugin_init()
{
    register_plugin("round_money","0.7","SweatyBanana")
    
    MONEY = register_cvar("round_money","16000")
    
    register_dictionary("rmlang.txt")
    
    register_logevent("new_round", 2, "1=Round_Start")
    register_event("TextMsg", "Event_TextMsg_Restart", "a", "2&#Game_C", "2&#Game_w")
}

public Event_TextMsg_Restart()
{
    IsRestarting = true;
}

public new_round()
{
    if( IsRestarting )
    {
        IsRestarting = false;
        szRoundCount = 0;
    }

    if(szRoundCount > 2)
        return 0;

    szRoundCount++;

    if(szRoundCount == 2)
    {
        new players[32], playerCount, i, player, pMoney;
        pMoney = get_pcvar_num(MONEY)
        
        get_players(players,playerCount);
        
        for(i=0;i<playerCount;i++)
        {
            player = players[i];
            if(cs_get_user_money(player) < pMoney)
            {
                cs_set_user_money(player, pMoney);
                client_print(player,print_chat,"%L",LANG_PLAYER,"MONEY_AMOUNT",pMoney)
            }
        } 
    }
    return 0;
} 


[Shzzzzz]

Thank you again! I will try it later this night when players are gone!

[Shzzzzz]

Tested on friends server and that's it. If i see some problems can i type you privately if you have no problem with it?

[@LeX]

Originally Posted by Shzzzzz Tested on friends server and that's it. If i see some problems can i type you privately if you have no problem with it?

sure. no problem