[Natsheh]

i recently wrote a goombastomp plugin, its a plugin which if a player fell on another player's head with a high fall velocity, player that got jumped on will be killed (die's,goombastomp), wondering if is there another better method can be achieve.

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN "goomba stomp"
#define VERSION "1.0"
#define AUTHOR "Natsheh"

new g_cvar1, g_cvar2, g_cvar3;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    g_cvar1 = register_cvar("goombastomp_min_fallspeed", "500");
    g_cvar2 = register_cvar("goombastomp_damage", "50");
    g_cvar3 = register_cvar("goombastomp_silent_dmg", "0");
    
    RegisterHam(Ham_Touch, "player", "fw_player_touch_pre");
}

public fw_player_touch_pre(id, other)
{
    if(is_user_alive(id))
    {
        if(is_user_alive(other))
        {
            if(pev(other, pev_groundentity) == id)
            {
                static Float:fVelocity[3], Float:fMinFallSpeed;
                pev(other, pev_velocity, fVelocity)
                if(fVelocity[2] <= (fMinFallSpeed=-get_pcvar_float(g_cvar1)))
                {
                    static Float:fHealth, Float:fDamage;
                    pev(id, pev_health, fHealth);
                    
                    fDamage = (fVelocity[2]/floatmax(floatabs(fMinFallSpeed), 0.1)) * -get_pcvar_float(g_cvar2);
                    if(fDamage >= fHealth)
                        ExecuteHamB(Ham_Killed, id, other, 2);
                    else
                    {
                        if(get_pcvar_num(g_cvar3))
                            set_pev(id, pev_health, (fHealth-fDamage));
                        else ExecuteHamB(Ham_TakeDamage, id, other, other, fDamage, DMG_BLAST);
                    }
                    
                    fVelocity[2] = 0.0;
                    set_pev(other, pev_velocity, fVelocity);
                    set_pev(other, pev_flFallVelocity, 0.0);
                    set_pev(other, pev_flags, (pev(other, pev_flags)&~FL_ONGROUND));
                }
            }
        }
    }
} 


[OciXCrom]

You don't need the "touch" event. Since the damage should be dealt only with a high velocity, such velocity will probably be enough to cause default fall damage from the game. Thus, you can simply hook the "damage" event and check the player below you. I wrote such a plugin a while ago. Guess there's no point in keeping it private anymore:

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <engine>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

#define PLUGIN_VERSION "1.1"
#define STOMP_SOUND "iplay/stomp.wav"
#define FLAG_VIP ADMIN_RESERVATION

new g_pFriendlyFire,
    g_pFrags,
    g_pNormalBonus,
    g_pVipBonus

public plugin_init()
{
    register_plugin("Goomba Stomp", PLUGIN_VERSION, "OciXCrom")
    RegisterHam(Ham_TakeDamage, "player", "OnTakeDamagePre", 0)
    g_pFriendlyFire = get_cvar_pointer("mp_friendlyfire")
    g_pFrags = register_cvar("goomba_frags", "2")
    g_pNormalBonus = register_cvar("goomba_normal_bonus", "30.0")
    g_pVipBonus = register_cvar("goomba_vip_bonus", "15.0")
}

public plugin_precache()
    precache_sound(STOMP_SOUND)

public OnTakeDamagePre(iVictim, iInflictor, iAttacker, Float:fDamage, iBits)
{
    if(iBits & DMG_FALL)
    {
        new iEnt = pev(iVictim, pev_groundentity)
        
        if(!is_ent_breakable(iEnt))
            return HAM_IGNORED
            
        fDamage += get_pcvar_float(g_pNormalBonus)
            
        if(get_user_flags(iVictim) & FLAG_VIP)
            fDamage += get_pcvar_float(g_pVipBonus)
            
        ExecuteHamB(Ham_TakeDamage, iEnt, 0, iVictim, fDamage, DMG_FALL)
        
        if(is_user_connected(iEnt))
        {
            if(get_pcvar_num(g_pFriendlyFire) || get_user_team(iVictim) != get_user_team(iEnt))
                GoombaStomp(iVictim, iEnt, fDamage)
        }
        
        return HAM_SUPERCEDE
    }
    
    return HAM_IGNORED
}

GoombaStomp(id, iEnt, Float:fDamage)
{
    new szName[2][32]
    get_user_name(id, szName[0], charsmax(szName[]))
    get_user_name(iEnt, szName[1], charsmax(szName[]))
        
    if(is_user_alive(iEnt))
    {
        client_print(id, print_center, "You dealt %.0f damage to %s. He has %i HP left!", fDamage, szName[1], pev(iEnt, pev_health))
        client_print(iEnt, print_center, "%s fell on top of you dealing %.0f damage!", szName[0], fDamage)
    }
    else
    {
        set_user_frags(id, get_user_frags(id) + get_pcvar_num(g_pFrags))
        cs_set_user_deaths(id, cs_get_user_deaths(id))
        client_print(0, print_center, "%s Goomba Stomped %s with %.0f damage!", szName[0], szName[1], fDamage)
        emit_sound(id, CHAN_AUTO, STOMP_SOUND, 1.0, ATTN_NORM, 0, PITCH_NORM)
    }
}

bool:is_ent_breakable(iEnt)
{
    if(iEnt)
    {        
        new szName[32]
        entity_get_string(iEnt, EV_SZ_classname, szName, charsmax(szName))
    
        if(equal(szName, "hostage_entity"))
            return false
    
        if((entity_get_float(iEnt, EV_FL_health) > 0.0) && (entity_get_float(iEnt, EV_FL_takedamage) > 0.0) && !(entity_get_int(iEnt, EV_INT_spawnflags) & SF_BREAK_TRIGGER_ONLY))
            return true
    }
    
    return false
} 


[Natsheh]

PHP Code:

  set_pev(other, pev_flFallVelocity, 0.0);
                    set_pev(other, pev_flags, (pev(other, pev_flags)&~FL_ONGROUND)); 


The weird part is this managed to block the fall damage.

[HamletEagle]

Why do you think it's weird? flFallVelocity is used to determine if fall damage should be applied and you set it to 0.

[Natsheh]

I'm just not familiar when the fall damage is happening after or before the touch nor fall velocity behaviour, i am more certain about it happening after the touch, I have some doubts.

[OciXCrom]

Like I said, you don't need to check any touches. You can check if the damage is fall damage in the damage event and easily locate the player you fell on.

[Natsheh]

Originally Posted by Natsheh when the fall damage is happening after or before the touch nor fall velocity behaviour, i am more certain about it happening after the touch, I have some doubts.

[OciXCrom]

Why does that matter if you don't need to use it? If you're curious, you can simply hook both events and print a message when they happen to see which message will get printed first.

[Natsheh]

Because I didn't find any explanation on pev_flFallvelocity and this entity variable don't make sense anyway it's solved.

And it's doesn't matter if I don't use it an explanation will be helpful for future planning.

[Black Rose]

Originally Posted by Natsheh I'll stick into my method since its more efficient.

Touch is called every frame and for each player.