[LiveAndLetDie]

I would need a little nifty function to detect whenever a player is looking/aiming at the ground but couldn't figure it out. I guess it could be done with vectors or tracerays. Any help?

[LiveAndLetDie]

Originally Posted by 000 Hi. What do you want to do?

I want clients to be able to spawn props on ground or floor only.

[LiveAndLetDie]

Originally Posted by 000 https://forums.alliedmods.net/showthread.php?p=1893141

I know this plugin and how it works but unfortunately it doesn't help me to solve my problem.

[backwards]

This should work how you wanted by checking the normals of the end point from the traceray and the players viewangles.x direction.

PHP Code:

#include <sourcemod>
#include <sdktools>

public void OnPluginStart()
{
    RegConsoleCmd("place", Command_Place);
}

public Action Command_Place(int client, int args)
{
    TryPlaceObject(client);
    return Plugin_Handled;
}

public bool Filter_LocalPlayer(int entity, int contentsMask, any client)
{
    return !(entity == client)
}

void TryPlaceObject(int client)
{
    float EyePos[3], ViewAngles[3], Normals[3];
    
    GetClientEyePosition(client, EyePos);
    GetClientEyeAngles(client, ViewAngles);

    //simple exit early if not looking downward based on viewangles
    if(ViewAngles[0] < 0.0)
        return;

    TR_TraceRayFilter(EyePos, ViewAngles, MASK_PLAYERSOLID, RayType_Infinite, Filter_LocalPlayer, client);

    //Traceray hit nothing
    if(!TR_DidHit(INVALID_HANDLE))
        return;
    
    TR_GetPlaneNormal(INVALID_HANDLE, Normals);
    
    //check angle of the surface hit by raytrace to prevent spawning on slanted edges/walls
    //can be inverted depending on map (I think?)
    if(Normals[2] < 0.9 && Normals[2] > -0.9)
        return;
    
    //Find the raytrace end point location
    float HitEndPoint[3];
    TR_GetEndPosition(HitEndPoint);
    
    //Create item and teleport it to HitEndPos
    int ent = CreateEntityByName("weapon_ak47");
    DispatchSpawn(ent);
    
    TeleportEntity(ent, HitEndPoint, NULL_VECTOR, NULL_VECTOR);
    
    PrintToChat(client, "Spawned Item at (%.2f, %.2f, %.2f)", HitEndPoint[0], HitEndPoint[1], HitEndPoint[2]);
}