Average damage per round.

kramesa · **Author**

How I can get the "ADR" of the player?

Thanks.

Exolent[jNr] · 03-21-2012 , 14:20 Re: Average damage per round.

Code:

#include <amxmodx>
#include <engine>
#include <hamsandwich>

#define MAX_PLAYERS 32

new bool:gSpawned[MAX_PLAYERS + 1];
new Float:gRoundDamage[MAX_PLAYERS + 1];
new Float:gTotalDamage[MAX_PLAYERS + 1];
new gRoundsPlayed[MAX_PLAYERS + 1];

new gMaxPlayers;

#define GetADR(%1) (gTotalDamage[%1] / gRoundsPlayed[%1])

public plugin_init() {
    register_clcmd("say /adr", "CmdShowAverage");
    
    register_event("HLTV", "EventNewRound", "a", "1=0", "2=0");
    
    RegisterHam(Ham_Spawn, "player", "FwdPlayerSpawnPost", 1);
    RegisterHam(Ham_TakeDamage, "player", "FwdPlayerDamagePost", 1);
    
    gMaxPlayers = get_maxplayers();
}

public client_disconnect(id) {
    gSpawned[id] = false;
    gRoundDamage[id] = 0.0;
    gTotalDamage[id] = 0.0;
    gRoundsPlayed[id] = 0;
}

public CmdShowAverage(id) {
    client_print(id, print_chat, "* Your average damage per round is %.1f", GetADR(id));
}

public EventNewRound() {
    for(new id = 1; id <= gMaxPlayers; id++) {
        if(gRoundDamage[id] > 0.0) {
            gTotalDamage[id] += gRoundDamage[id];
            gRoundDamage[id] = 0.0;
            
            gRoundsPlayed[id]++;
        }
        else if(gSpawned[id]) {
            gRoundsPlayed[id]++;
        }
        
        gSpawned[id] = false;
    }
}

public FwdPlayerSpawnPost(id) {
    if(is_user_alive(id)) {
        gSpawned[id] = true;
    }
}

public FwdPlayerDamagePost(victim, inflictor, attacker, Float:damage, damageBits) {
    if(1 <= attacker <= gMaxPlayers && attacker != victim) {
        gRoundDamage[attacker] += entity_get_float(victim, EV_FL_dmg_take);
    }
}

kramesa · 03-21-2012 , 14:56 Re: Average damage per round.

Thanks.

Can you add in this plugin the ADR? With mysql.

Code:

#include <amxmodx>
#include <cstrike>
#include <csx>
#include <sqlx>

const MaxSlots = 32;
const MaxSteamIdChars = 35;

const SecondsInHour = 3600;

enum _:DataTypes
{
    _Data_Kills,
    _Data_Deaths,
    _Data_Headshots,
    _Data_Wins,
    _Data_Losses,
    _Data_Points,
};

new PlayerData[MaxSlots + 1][DataTypes];

new SteamId[MaxSlots + 1][MaxSteamIdChars];

new ExistsInDB[MaxSlots + 1];

new MaxPlayers;

new Handle:SQLTuple;

new CvarPointsKill;
new CvarPointsHeadshot;
new CvarPointsWins;

new szName[32], szSteamID[32];

public plugin_init()
{
    CvarPointsKill = register_cvar("pug_points_kill", "1");
    CvarPointsHeadshot = register_cvar("pug_points_headshot", "2");
    CvarPointsWins = register_cvar("pug_points_win", "1");
    MaxPlayers = get_maxplayers();
    
    register_event("DeathMsg", "Event_DeathMsg", "a");
    
    register_event("SendAudio", "Event_SendAudio_TWin", "a", "2&%!MRAD_terwin");
    register_event("SendAudio", "Event_SendAudio_CTWin", "a", "2&%!MRAD_ctwin");
    
    set_cvar_string("amx_sql_host","");
    set_cvar_string("amx_sql_user","");
    set_cvar_string("amx_sql_pass","");
    set_cvar_string("amx_sql_db","");
    set_cvar_string("amx_sql_table","");
    set_cvar_string("amx_sql_type","mysql");
    
    PrepareDatabase();
}

PrepareDatabase()
{
    SQLTuple = SQL_MakeStdTuple();
    
    new Query[512];
    formatex(Query, 
    charsmax(Query), 
    "CREATE TABLE IF NOT EXISTS sb_ranking (kills int(10), deaths int(10), headshots int(10), wins int(10), losses int(10), points int(10), steamid varchar(35), name varchar(32), PRIMARY KEY(steamid))");
    
    SQL_ThreadQuery(SQLTuple, "QueryDefaultHandle", Query);
}

SaveData(const Client)
{
    new Query[512];
    new ClientName[MaxSlots];
    new ClientNameSafe[MaxSlots];
    get_user_name(Client, ClientName, charsmax(ClientName));
    MakeStringSQLSafe(ClientName, ClientNameSafe, charsmax(ClientName));
    
    if(ExistsInDB[Client] == -1)
    {
        formatex(Query, charsmax(Query), 
        "INSERT INTO sb_ranking (kills, deaths, headshots, wins, losses, points, steamid, name) VALUES (%i, %i, %i, %i, %i, %i, '%s', '%s')",
        PlayerData[Client][_Data_Kills],
        PlayerData[Client][_Data_Deaths],
        PlayerData[Client][_Data_Headshots],
        PlayerData[Client][_Data_Wins],
        PlayerData[Client][_Data_Losses],
        PlayerData[Client][_Data_Points],
        SteamId[Client],
        ClientNameSafe
        );
        
        ExistsInDB[Client] = 1;
    }
    else
    {
        formatex(Query, charsmax(Query),
        "UPDATE sb_ranking SET kills = %i, deaths = %i, headshots = %i, wins = %i, losses = %i, points = %i, name = '%s' WHERE steamid = '%s'",
        PlayerData[Client][_Data_Kills],
        PlayerData[Client][_Data_Deaths],
        PlayerData[Client][_Data_Headshots],
        PlayerData[Client][_Data_Wins],
        PlayerData[Client][_Data_Losses],
        PlayerData[Client][_Data_Points],
        ClientNameSafe,
        SteamId[Client]
        );
    }
    
    SQL_ThreadQuery(SQLTuple, "QueryDefaultHandle", Query);
}

MakeStringSQLSafe(const Input[], Output[], Len)
{
    copy(Output, Len, Input );
    replace_all(Output, Len, "'", "*");
    replace_all(Output, Len, "^"", "*");
    replace_all(Output, Len, "`", "*");
    
    remove_quotes(Output);
}

public QueryDefaultHandle(FailState, Handle:Query, Error[], ErrorCode, Data[], DataSize, Float:QueueTime)
{
    switch(FailState)
    {
        case TQUERY_CONNECT_FAILED:
        {
            set_fail_state("SQL: Connection failed.");
        }
        case TQUERY_QUERY_FAILED:
        {
            log_amx("SQL: Query failed. Error: %s (%i)", Error, ErrorCode);
        }
    }
}

LoadData(const Client)
{
    new Query[512], Data[2];
    formatex( Query, charsmax(Query),
    "SELECT * FROM sb_ranking WHERE steamid = '%s'",
    SteamId[Client]
    );
    
    Data[0] = Client;
    SQL_ThreadQuery(SQLTuple, "QueryLoadData", Query, Data, charsmax(Data));
}

public QueryLoadData(FailState, Handle:Query, Error[], ErrorCode, Data[], DataSize, Float:QueueTime)
{
    switch(FailState)
    {
        case TQUERY_CONNECT_FAILED:
        {
            set_fail_state("SQL: Connection failed.");
        }
        case TQUERY_QUERY_FAILED:
        {
            log_amx("SQL: Query failed. Error: %s (%i)", Error, ErrorCode);
        }
        default:
        {
            SQL_GetResults(Query, Data);
        }
    }
}

SQL_GetResults(Handle:Query, const Data[])
{
    new Client = Data[0];
    if( SQL_NumResults(Query))
    {
        ExistsInDB[Client] = 1;
        
        for(new DataIndex = 0; DataIndex < DataTypes; DataIndex++)
        {
            PlayerData[Client][DataIndex] = SQL_ReadResult(Query, DataIndex);
        }
    }
    else
    {
        ExistsInDB[Client] = -1;
    }
}

public client_authorized(Client)
{
    if(!is_user_bot(Client))
    {
        get_user_authid(Client, SteamId[Client], charsmax(SteamId[]));
        
        DefaultVariables(Client);
        
        LoadData(Client);
    }
}

public client_disconnect(Client)
{
    SaveData(Client);
    
    DefaultVariables(Client);
    
    SteamId[Client][0] = 0;
}

DefaultVariables(const Client)
{
    for(new DataIndex = 0; DataIndex < DataTypes; DataIndex++)
    {
        PlayerData[Client][DataIndex] = 0;
    }
}

public Event_DeathMsg()
{
    if(get_cvar_num("amx_live") == 1)
    {
        new Attacker = read_data(1);
        new Victim = read_data(2);
        
        if((1 <= Attacker <= MaxPlayers) 
        && (1 <= Victim <= MaxPlayers)
        && (Victim != Attacker) 
        && is_user_connected(Victim) 
        && is_user_connected(Attacker))
        {
            new Points   = get_pcvar_num(CvarPointsKill);
            new Headshot = read_data(3);
            
            if(Headshot)
            {
                Points += get_pcvar_num(CvarPointsHeadshot);
                
                PlayerData[Attacker][_Data_Headshots]++;
            }
            
            PlayerData[Attacker][_Data_Points] += Points;
            
            PlayerData[Attacker][_Data_Kills]++;
            PlayerData[Victim][_Data_Deaths]++;
            
            SaveData(Attacker);
            SaveData(Victim);
        }
        else if(!Attacker)
        {
            PlayerData[Victim][_Data_Deaths]++;
        }
    }
}

public Event_SendAudio_TWin()
{
    if(get_cvar_num("amx_live") == 1)
    {
        new Points = get_pcvar_num(CvarPointsWins);
        for(new Client = 1; Client <= MaxPlayers; Client++) 
        {
            if(is_user_connected(Client))
            {
                if( cs_get_user_team(Client) == CS_TEAM_T)
                {
                    PlayerData[Client][ _Data_Points] += Points;
                    
                    PlayerData[Client][_Data_Wins]++;
                }
                else if(cs_get_user_team(Client) == CS_TEAM_CT)
                {
                    PlayerData[Client][_Data_Losses]++;
                }
                
                SaveData(Client);
            }
        }
    }
}

public Event_SendAudio_CTWin()
{
    if(get_cvar_num("amx_live") == 1)
    {
        new Points = get_pcvar_num(CvarPointsWins);
        
        for( new Client = 1; Client <= MaxPlayers; Client++) 
        {
            if(is_user_connected(Client))
            {
                if(cs_get_user_team(Client) == CS_TEAM_CT)
                {
                    PlayerData[Client][_Data_Points] += Points;
                    
                    PlayerData[Client][_Data_Wins ]++;
                }
                else if(cs_get_user_team(Client) == CS_TEAM_T)
                {
                    PlayerData[Client][_Data_Losses]++;
                }
                
                SaveData(Client);
            }
        }
    }
}

public bomb_defused(Client)
{
    if(get_cvar_num("amx_live") == 1)
    {
        PlayerData[Client][_Data_Points] += 1;
    }
    
    SaveData(Client);
}

public bomb_planted(Client)
{
    if(get_cvar_num("amx_live") == 1)
    {
        PlayerData[Client][_Data_Points] += 1;
    }
    
    SaveData(Client);
}

Exolent[jNr] · 03-21-2012 , 15:40 Re: Average damage per round.

Here you go.

You'll have to perform this query on your database if you already have the table created:
ALTER TABLE sb_ranking ADD total_damage int(10);

I optimized a few things, but not all the things I saw.
Such as, you should use pcvars for the live status.

PHP Code:


			
#include <amxmodx>
#include <cstrike>
#include <csx>
#include <sqlx>
#include <engine>
#include <hamsandwich>

const MaxSlots = 32;
const MaxSteamIdChars = 35;

const SecondsInHour = 3600;

enum _:DataTypes
{
    _Data_Kills,
    _Data_Deaths,
    _Data_Headshots,
    _Data_Wins,
    _Data_Losses,
    _Data_Points,
    _Data_TotalDamage
};

new PlayerData[MaxSlots + 1][DataTypes];

new SteamId[MaxSlots + 1][MaxSteamIdChars];

new MaxPlayers;

new Handle:SQLTuple;

new CvarPointsKill;
new CvarPointsHeadshot;
new CvarPointsWins;

new szName[32], szSteamID[32];

public plugin_init()
{
    CvarPointsKill = register_cvar("pug_points_kill", "1");
    CvarPointsHeadshot = register_cvar("pug_points_headshot", "2");
    CvarPointsWins = register_cvar("pug_points_win", "1");
    MaxPlayers = get_maxplayers();
    
    register_event("DeathMsg", "Event_DeathMsg", "a");
    
    register_event("SendAudio", "Event_SendAudio_TWin", "a", "2&%!MRAD_terwin");
    register_event("SendAudio", "Event_SendAudio_CTWin", "a", "2&%!MRAD_ctwin");
    
    RegisterHam(Ham_TakeDamage, "player", "FwdPlayerDamagePost", 1);
    
    set_cvar_string("amx_sql_host","");
    set_cvar_string("amx_sql_user","");
    set_cvar_string("amx_sql_pass","");
    set_cvar_string("amx_sql_db","");
    set_cvar_string("amx_sql_table","");
    set_cvar_string("amx_sql_type","mysql");
    
    PrepareDatabase();
}

PrepareDatabase()
{
    SQLTuple = SQL_MakeStdTuple();
    
    new Query[512];
    formatex(Query, 
    charsmax(Query), 
    "CREATE TABLE IF NOT EXISTS sb_ranking (kills int(10), deaths int(10), headshots int(10), wins int(10), losses int(10), points int(10), total_damage int(10), steamid varchar(35), name varchar(32), PRIMARY KEY(steamid))");
    
    SQL_ThreadQuery(SQLTuple, "QueryDefaultHandle", Query);
}

SaveData(const Client)
{
    new Query[512];
    new ClientName[MaxSlots];
    new ClientNameSafe[MaxSlots];
    get_user_name(Client, ClientName, charsmax(ClientName));
    MakeStringSQLSafe(ClientName, ClientNameSafe, charsmax(ClientName));
    
    formatex(Query, charsmax(Query), 
        "REPLACE INTO sb_ranking (kills, deaths, headshots, wins, losses, points, total_damage, steamid, name) VALUES (%i, %i, %i, %i, %i, %i, %i, '%s', '%s')",
        PlayerData[Client][_Data_Kills],
        PlayerData[Client][_Data_Deaths],
        PlayerData[Client][_Data_Headshots],
        PlayerData[Client][_Data_Wins],
        PlayerData[Client][_Data_Losses],
        PlayerData[Client][_Data_Points],
        PlayerData[Client][_Data_TotalDamage],
        SteamId[Client],
        ClientNameSafe
        );
    
    SQL_ThreadQuery(SQLTuple, "QueryDefaultHandle", Query);
}

MakeStringSQLSafe(const Input[], Output[], Len)
{
    copy(Output, Len, Input );
    replace_all(Output, Len, "'", "*");
    replace_all(Output, Len, "^"", "*");
    replace_all(Output, Len, "`", "*");
    
    remove_quotes(Output);
}

public QueryDefaultHandle(FailState, Handle:Query, Error[], ErrorCode, Data[], DataSize, Float:QueueTime)
{
    switch(FailState)
    {
        case TQUERY_CONNECT_FAILED:
        {
            set_fail_state("SQL: Connection failed.");
        }
        case TQUERY_QUERY_FAILED:
        {
            log_amx("SQL: Query failed. Error: %s (%i)", Error, ErrorCode);
        }
    }
}

LoadData(const Client)
{
    new Query[512], Data[2];
    formatex( Query, charsmax(Query),
    "SELECT * FROM sb_ranking WHERE steamid = '%s'",
    SteamId[Client]
    );
    
    Data[0] = Client;
    SQL_ThreadQuery(SQLTuple, "QueryLoadData", Query, Data, charsmax(Data));
}

public QueryLoadData(FailState, Handle:Query, Error[], ErrorCode, Data[], DataSize, Float:QueueTime)
{
    switch(FailState)
    {
        case TQUERY_CONNECT_FAILED:
        {
            set_fail_state("SQL: Connection failed.");
        }
        case TQUERY_QUERY_FAILED:
        {
            log_amx("SQL: Query failed. Error: %s (%i)", Error, ErrorCode);
        }
        default:
        {
            SQL_GetResults(Query, Data);
        }
    }
}

SQL_GetResults(Handle:Query, const Data[])
{
    new Client = Data[0];
    if( SQL_NumResults(Query))
    {
        for(new DataIndex = 0; DataIndex < DataTypes; DataIndex++)
        {
            PlayerData[Client][DataIndex] = SQL_ReadResult(Query, DataIndex);
        }
    }
}

public client_authorized(Client)
{
    if(!is_user_bot(Client))
    {
        get_user_authid(Client, SteamId[Client], charsmax(SteamId[]));
        
        DefaultVariables(Client);
        
        LoadData(Client);
    }
}

public client_disconnect(Client)
{
    SaveData(Client);
    
    DefaultVariables(Client);
    
    SteamId[Client][0] = 0;
}

DefaultVariables(const Client)
{
    for(new DataIndex = 0; DataIndex < DataTypes; DataIndex++)
    {
        PlayerData[Client][DataIndex] = 0;
    }
}

public Event_DeathMsg()
{
    if(get_cvar_num("amx_live") == 1)
    {
        new Attacker = read_data(1);
        new Victim = read_data(2);
        
        if((1 <= Attacker <= MaxPlayers) 
        && (1 <= Victim <= MaxPlayers)
        && (Victim != Attacker) 
        && is_user_connected(Victim) 
        && is_user_connected(Attacker))
        {
            new Points   = get_pcvar_num(CvarPointsKill);
            new Headshot = read_data(3);
            
            if(Headshot)
            {
                Points += get_pcvar_num(CvarPointsHeadshot);
                
                PlayerData[Attacker][_Data_Headshots]++;
            }
            
            PlayerData[Attacker][_Data_Points] += Points;
            
            PlayerData[Attacker][_Data_Kills]++;
            PlayerData[Victim][_Data_Deaths]++;
            
            SaveData(Attacker);
            SaveData(Victim);
        }
        else if(!Attacker)
        {
            PlayerData[Victim][_Data_Deaths]++;
        }
    }
}

public Event_SendAudio_TWin()
{
    TeamWin(CS_TEAM_T);
}

public Event_SendAudio_CTWin()
{
    TeamWin(CS_TEAM_CT);
}

TeamWin(CsTeams:winner) {
    if(get_cvar_num("amx_live") == 1)
    {
        new CsTeams:loser = CS_TEAM_SPECTATOR - winner;
        new Points = get_pcvar_num(CvarPointsWins);
        
        for( new Client = 1, CsTeams:team; Client <= MaxPlayers; Client++) 
        {
            if(is_user_connected(Client))
            {
                team = cs_get_user_team(Client);
                
                if(team == winner) {
                    PlayerData[Client][_Data_Points] += Points;
                    PlayerData[Client][_Data_Wins]++;
                }
                else if(team == loser) {
                    PlayerData[Client][_Data_Losses]++;
                }
                
                SaveData(Client);
            }
        }
    }
}

public FwdPlayerDamagePost(victim, inflictor, attacker, Float:damage, damageBits) {
    if(1 <= attacker <= MaxPlayers && victim != attacker && get_cvar_num("amx_live") == 1) {
        PlayerData[attacker][_Data_TotalDamage] += floatround(entity_get_float(victim, EV_FL_dmg_take));
    }
}

public bomb_defused(Client)
{
    if(get_cvar_num("amx_live") == 1)
    {
        PlayerData[Client][_Data_Points] += 1;
    }
    
    SaveData(Client);
}

public bomb_planted(Client)
{
    if(get_cvar_num("amx_live") == 1)
    {
        PlayerData[Client][_Data_Points] += 1;
    }
    
    SaveData(Client);
}

kramesa · 03-21-2012 , 15:42 Re: Average damage per round.

Quote:

Originally Posted by Exolent[jNr]

Here you go.

You'll have to perform this query on your database if you already have the table created:
ALTER TABLE sb_ranking ADD total_damage int(10);

I optimized a few things, but not all the things I saw.
Such as, you should use pcvars for the live status.

Hooray! Thanks man, I will test.

Exolent[jNr] · 03-21-2012 , 15:45 Re: Average damage per round.

Quote:

Originally Posted by kramesa

Hooray! Thanks man, I will test.

By the way, you get the ADR by doing:

Code:

new ADR = PlayerData[id][_Data_TotalDamage] / (PlayerData[id][_Data_Wins] + PlayerData[id][_Data_Losses]);

Or if you want to test with a query:
SELECT *, (total_damage / (wins + losses)) AS adr FROM sd_ranking;

kramesa · *Last edited by kramesa; 03-21-2012 at 15:58.*

Quote:

Originally Posted by Exolent[jNr]

By the way, you get the ADR by doing:

Code:

new ADR = PlayerData[id][_Data_TotalDamage] / (PlayerData[id][_Data_Wins] + PlayerData[id][_Data_Losses]);

Or if you want to test with a query:
SELECT *, (total_damage / (wins + losses)) AS adr FROM sd_ranking;

But if I put this:

PHP Code:


			
PlayerData[id][_Data_TotalDamage] = PlayerData[id][_Data_TotalDamage] / (PlayerData[id][_Data_Wins] + PlayerData[id][_Data_Losses]);

The total_damage is wrong?

And how I can put a default value of 0.0?

Exolent[jNr] · 03-21-2012 , 16:03 Re: Average damage per round.

Quote:

Originally Posted by kramesa

But if I put this:

PHP Code:


			
PlayerData[id][_Data_TotalDamage] = PlayerData[id][_Data_TotalDamage] / (PlayerData[id][_Data_Wins] + PlayerData[id][_Data_Losses]);

The total_damage is wrong?

And how I can put a default value of 0.0?

That will overwrite your damage, so yes it is wrong.
You shouldn't cache it inside a data value since it should be dynamically calculated whenever you need it.

It will default to 0 already since total damage defaults to 0.

kramesa · 03-21-2012 , 16:05 Re: Average damage per round.

Quote:

Originally Posted by Exolent[jNr]

That will overwrite your damage, so yes it is wrong.
You shouldn't cache it inside a data value since it should be dynamically calculated whenever you need it.

It will default to 0 already since total damage defaults to 0.

Hooray! Ok, lest req.: Can you put the correct ADR on this?

PHP Code:


			
<?php



mysql_connect("", "", "") or die(mysql_error());;



mysql_select_db("");

$query = mysql_query('SELECT * FROM sb_ranking ORDER BY points DESC');



echo '<table><table  width="750"><td><center><b>#</b></center></td><td><center><b>Nome:</b></center></td><td><center><b>SteamID:</b></center></td><td><center><b>Frags:</b></center></td><td><center><b>Deaths:</b></center></td><td><center><b>HS:</b></center></td><td><center><b>Wins:</b></center></td><td><center><b>Losses:</b></center></td><td><center><b>ADR:</b></center><td><center><b>Points:</b></center></td></strong>

';

$pos=1;

$x = 0;

$cor1 = "#ffffff";

$cor2 = "#d4f2e3";

echo "<style type=\"text/css\">.fonteRank { color: #a6a6a6; font-family: \"Verdana, Geneva\"; font-size: 11px; font-weight: bold; }</style>";

while($a = mysql_fetch_array($query)) {

    $cor = ( $x % 2 == 0 ) ? $cor1 : $cor2;

    echo '<tr bgcolor="'.$cor.'" class="fonteRank"><td><center>'.$pos.'</center></td><td><center>'.substr($a['name'], 0 ,15).'</center></td><td><center>'.$a['steamid'].'</center></td><td><center>'.$a['kills'].'</center></td><td><center>'.$a['deaths'].'</center></td><td><center>'.$a['headshots'].'</center></td><td><center>'.$a['wins'].'</center></td><td><center>'.$a['losses'].'</center></td><td><center>'.$a['total_damage'].'</center></td><td><center>'.$a['points'].'</center></td><tr>';

    $pos++;

        $x++;

}

echo '</table>';



?>

Exolent[jNr] · 03-21-2012 , 16:08 Re: Average damage per round.

That is an eyesore, but I'm not going to worry with making it nice.

PHP Code:


			
<?php

mysql_connect("", "", "") or die(mysql_error());;

mysql_select_db("");
$query = mysql_query('SELECT * FROM sb_ranking ORDER BY points DESC');

echo '<table><table  width="750"><td><center><b>#</b></center></td><td><center><b>Nome:</b></center></td><td><center><b>SteamID:</b></center></td><td><center><b>Frags:</b></center></td><td><center><b>Deaths:</b></center></td><td><center><b>HS:</b></center></td><td><center><b>Wins:</b></center></td><td><center><b>Losses:</b></center></td><td><center><b>ADR:</b></center><td><center><b>Points:</b></center></td></strong>
';
$pos=1;
$x = 0;
$cor1 = "#ffffff";
$cor2 = "#d4f2e3";
echo "<style type=\"text/css\">.fonteRank { color: #a6a6a6; font-family: \"Verdana, Geneva\"; font-size: 11px; font-weight: bold; }</style>";
while($a = mysql_fetch_array($query)) {
    $cor = ( $x % 2 == 0 ) ? $cor1 : $cor2;
    echo '<tr bgcolor="'.$cor.'" class="fonteRank"><td><center>'.$pos.'</center></td><td><center>'.substr($a['name'], 0 ,15).'</center></td><td><center>'.$a['steamid'].'</center></td><td><center>'.$a['kills'].'</center></td><td><center>'.$a['deaths'].'</center></td><td><center>'.$a['headshots'].'</center></td><td><center>'.$a['wins'].'</center></td><td><center>'.$a['losses'].'</center></td><td><center>'.round($a['total_damage'] / max($a['wins'] + $a['losses'], 1)).'</center></td><td><center>'.$a['points'].'</center></td><tr>';
    $pos++;
        $x++;
}
echo '</table>';

?>