[HARd_]

Hello there!

I need some help with the plugin usually called "No flash team" for the CS 1.6 servers.
I have two versions of this plugin which should work. Well, this won't happen all the time.

These plugins are:
Simple No Team Flash (1.0) - P.Of.Pw
No Team Flash (0.2) - KRoTaL

These plugins have bugs and won't work all the time.
Sometimes you won't get flashed by your team mates, but in some cases you will.
I attached the plugins to this post.

[aEEk]

Check this topic: https://forums.alliedmods.net/showthread.php?t=233355

[wickedd]

Use this one

[Godofwar]

For me that here works fine. U can try it .

/**
 * Team Flash Blocker
 * Written by GwynBleidD
 * based on Connor's Team Flash Punish v1.1.1
 */

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "1.0"

const MAX_PLAYERS = 32

new g_iMaxPlayers
#define IsPlayer(%1)	( 1 <= %1 <= g_iMaxPlayers )

new g_bitGonnaExplode[64]
#define SetGrenadeExplode(%1)		g_bitGonnaExplode[%1>>5] |=  1<<(%1 & 31)
#define ClearGrenadeExplode(%1)	g_bitGonnaExplode[%1>>5] &= ~( 1 << (%1 & 31) )
#define WillGrenadeExplode(%1)		g_bitGonnaExplode[%1>>5] &   1<<(%1 & 31)

new Float:g_flCurrentGameTime, g_iCurrentFlasher

new g_msgScreenFade;

public plugin_init()
{
	register_plugin("Team Flash Blocker", VERSION, "GwynBleidD")
	register_event("ScreenFade", "Event_ScreenFade", "be", "4=255", "5=255", "6=255", "7>199")
	RegisterHam(Ham_Think, "grenade", "CGrenade_Think")

	g_iMaxPlayers = get_maxplayers()
	g_msgScreenFade = get_user_msgid("ScreenFade")
}

public CGrenade_Think( iEnt )
{
	static Float:flGameTime, Float:flDmgTime, iOwner
	flGameTime = get_gametime()
	pev(iEnt, pev_dmgtime, flDmgTime)
	const XO_GRENADE = 5
	if(	flDmgTime <= flGameTime
	// VEN's way on how to detect grenade type
	// http://forums.alliedmods.net/showthread.php?p=401189#post401189
	&&	get_pdata_int(iEnt, 114, XO_GRENADE) == 0 // has a bit when is HE or SMOKE
	&&	!(get_pdata_int(iEnt, 96, XO_GRENADE) & (1<<8)) // has this bit when is c4
	&&	IsPlayer( (iOwner = pev(iEnt, pev_owner)) )	) // if no owner (3rd 'after dmgtime' frame), grenade gonna be removed from world
	{
		if( ~WillGrenadeExplode(iEnt) ) // grenade gonna explode on next think
		{
			SetGrenadeExplode( iEnt )
		}
		else
		{
			ClearGrenadeExplode( iEnt )
			g_flCurrentGameTime = flGameTime
			g_iCurrentFlasher = iOwner
		}
	}
}

public Event_ScreenFade(id)
{
	new Float:flGameTime = get_gametime()
	if(	id != g_iCurrentFlasher
		&&	g_flCurrentGameTime == flGameTime
		&&	cs_get_user_team(id) == cs_get_user_team(g_iCurrentFlasher)	)
	{		
		message_begin(MSG_ONE, g_msgScreenFade, {0,0,0}, id)
		write_short(1)
		write_short(1)
		write_short(1)
		write_byte(0)
		write_byte(0)
		write_byte(0)
		write_byte(255)
		message_end()
	}
}

[Alber9091]

If your server is ReHLDS than try this ..!!
You may require reapi inc and reapi module to use it.
To install module, upload reapi_1336.iso module in root/cstrike/addons/amxmodx/modules
and add a line with text reapi in root/cstrike/addons/amxmodx/configs/modules.ini

Search on google reapi module and include.

PHP Code:

#include <amxmodx>
#include <reapi>

// const BLINDED_PARTLY = 200
// const BLINDED_FULLY = 255

public plugin_init()
{
    register_plugin("[ReAPI] No Team Flash", "0.0.2", "unknown")

    RegisterHookChain(RG_PlayerBlind, "PlayerBlind", .post = false)
}

public PlayerBlind(const index, const inflictor, const attacker, const Float:fadeTime, const Float:fadeHold, const alpha, Float:color[3])
{
    return (index != attacker && get_member(index, m_iTeam) == get_member(attacker, m_iTeam)) ? HC_SUPERCEDE : HC_CONTINUE
}