[Neuro Toxin]

Your best running the extension on your server.

Make sure sourcemod is upto date (latest stable snapshot) and you have updated the gamedata for the extension (in first post)

edit: The update below should fix it for you.

[Neuro Toxin]

Version 1.7 Released
- Added cvar 'aws_enable' to disable/enable plugin
- Added cvar 'aws_delay' which delays the weapon respawn
- Added support for sm_hosties - Players in last request wont have their weapons replaced

If you run other plugins that process weapon equipping, this plugin may causes unexpected crashes. If you turn aws_delay to 0.1 or higher, this should stop any conflictions.

[Root_]

I really think code is too complicated. Also #include <lastrequest> is optional I guess,but without that you cant recompile plugin. You may use static instead of some global variables (like ProcessingClientWeapons). There's alot of things I would change, so I better just leave it here as example.

Spoiler

#include <sdkhooks>
#include <sdktools>

enum
{
    CS_TEAM_NONE,
    CS_TEAM_SPECTATOR,
    CS_TEAM_T,
    CS_TEAM_CT
}

new Handle:WeaponsTrie

public OnPluginStart()
{
    WeaponsTrie = CreateTrie()

    SetTrieValue(WeaponsTrie, "glock", CS_TEAM_T)
    SetTrieValue(WeaponsTrie, "p250", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "cz75", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "fiveseven", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "deagle", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "elite", CS_TEAM_T)
    SetTrieValue(WeaponsTrie, "hkp2000", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "tec9", CS_TEAM_T)
    SetTrieValue(WeaponsTrie, "usp_silencer", CS_TEAM_CT)

    SetTrieValue(WeaponsTrie, "nova", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "xm1014", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "mag7", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "sawedoff", CS_TEAM_T)
    SetTrieValue(WeaponsTrie, "m249", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "negev", CS_TEAM_NONE)

    SetTrieValue(WeaponsTrie, "mp9", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "mac10", CS_TEAM_T)
    SetTrieValue(WeaponsTrie, "mp7", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "ump45", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "p90", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "bizon", CS_TEAM_NONE)

    SetTrieValue(WeaponsTrie, "famas", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "m4a1", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "m4a1_silencer", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "galilar", CS_TEAM_T)
    SetTrieValue(WeaponsTrie, "ak47", CS_TEAM_T)
    SetTrieValue(WeaponsTrie, "ssg08", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "aug", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "sg556", CS_TEAM_T)
    SetTrieValue(WeaponsTrie, "awp", CS_TEAM_NONE)
    SetTrieValue(WeaponsTrie, "scar20", CS_TEAM_CT)
    SetTrieValue(WeaponsTrie, "g3sg1", CS_TEAM_T)
}

public OnEntityCreated(entity, const String:classname[])
{
    decl dummy
    if (GetTrieValue(WeaponsTrie, classname[7], dummy))
    {
        CreateTimer(0.1, Timer_OnClientReceive, EntIndexToEntRef(entity), TIMER_FLAG_NO_MAPCHANGE)
    }
}

public Action:Timer_OnClientReceive(Handle:event, any:data)
{
    new weapon  = EntRefToEntIndex(data)
    if (weapon != INVALID_ENT_REFERENCE)
    {
        decl String:classname[32], client, dummy, m_iTeamNum
        client = GetEntPropEnt(weapon, Prop_Data, "m_hOwnerEntity")
        if (1 <= client <= MaxClients && IsClientInGame(client)
        && GetEdictClassname(weapon, classname, sizeof(classname)))
        {
            if (GetTrieValue(WeaponsTrie, classname[7], dummy))
            {
                switch (GetEntProp(weapon, Prop_Send, "m_iItemDefinitionIndex"))
                {
                    case 60: classname = "weapon_m4a1_silencer"
                    case 61: classname = "weapon_usp_silencer"
                    case 63: classname = "weapon_cz75a"
                }

                static String:LastPlayerWeapon[MAXPLAYERS + 1][32]
                if (StrEqual(LastPlayerWeapon[client], classname, false))
                {
                    LastPlayerWeapon[client][0] = '\0'
                    return Plugin_Stop
                }

                m_iTeamNum = GetEntProp(client, Prop_Data, "m_iTeamNum")
                if (CS_TEAM_T <= dummy <= CS_TEAM_CT && m_iTeamNum != dummy)
                {
                    SetEntProp(client, Prop_Data, "m_iTeamNum", dummy)
                    AcceptEntityInput(weapon, "Kill")
                    GivePlayerItem(client, classname)
                    LastPlayerWeapon[client] = classname
                    SetEntProp(client, Prop_Data, "m_iTeamNum", m_iTeamNum)
                }
            }
        }
    }
    return Plugin_Stop
}

[Neuro Toxin]

Thanks for your feedback.

Your example is almost identical to the first version of this plugin minus the trie.

This is what I got from your feedback.

* static the client processing list
* use a trie to hold the weapon teams
* remove optional mark for lastrequest as its required

I would also like to point out that how your timer and process list is setup in your example. Only one gun can process at a time. This means if one had a shop with auto buy, only one weapon would replace if multiple weapons are purchased in the same frame. This makes your example look simple when comparing to this plugin.

[Root_]

Player receives weapon only once at its spawn. Since multiple weapons can be created/spawned/purchased at same frame (like multipurchase) a multiple callbacks will be called as well. So its fine when you buy/pick/whatever multiple weapons at a time. As of the LastPlayerWeapon string, if callback is fired twice and weapon is same as previous, it means weapon was already changed, so it clears the LPW string and stops weapon replacing process... again for every weapon, independent on its time receiving. Also GetTeamName(2/3) returns T/CT names appropriately, so you can not change weapon configs and use some optimizations further. I can add comments to my example so it will be more clear if you want.

[Neuro Toxin]

Thanks for feedback.

Ill do some testing and changes based on this.

[h3bus]

Also for optimizations and code clarity you could always use m_iItemDefinitionIndex to identify a weapon (instead of using string comparison which are slower).
The optimization is really tiny though compared to the cost of spawning a new weapon.

[Neuro Toxin]

Originally Posted by Root_ Also #include <lastrequest> is optional I guess,but without that you cant recompile plugin.

It's optional because if it's not marked this way, the plugin wont start without sm_hosties. It's got nothing to do with compilation without the lastrequest include file. For this reason, the lastrequest include file is part of the download.

Originally Posted by Root_ You may use static instead of some global variables (like ProcessingClientWeapons).

ProcessingClientWeapons needs to be cleaned if a client disconnects while the timer is awaiting callback. For this reason, it CANT be static as in my code, PutClientInServer wont have access to clean the process list.

Originally Posted by Root_ it means weapon was already changed, so it clears the LPW string and stops weapon replacing process... again for every weapon, independent on its time receiving.

I added debug messages to your example. This is what came back with multiple purchases at once.

[AWS] Timer_OnClientReceive(): client=3, classname=weapon_ak47
[AWS] Switching for class 'weapon_ak47'
[AWS] Timer_OnClientReceive(): client=3, classname=weapon_glock
[AWS] Switching for class 'weapon_glock'
[AWS] Timer_OnClientReceive(): client=3, classname=weapon_glock
[AWS] Completed switch for class 'weapon_glock'
[AWS] Timer_OnClientReceive(): client=3, classname=weapon_ak47
[AWS] Switching for class 'weapon_ak47'
[AWS] Timer_OnClientReceive(): client=3, classname=weapon_ak47
[AWS] Completed switch for class 'weapon_ak47'

You can see this doesn't work as you intend. The AK is added first and then the Glock. You can see the Glock completes first and wipes the current processing weapon for the AK. So when the AK comes back it starts the replacement again.

My Comments

With all this said, I'm still taking your advise on using Trie's, however, the complexity you talk about is all required. I started off with something similar to your example and I've had to make it more complex then your example for it to work as intended.

I will be releasing a new version soon with some updates based on your feedback, however, It's still going to be complex.

Also note that using OnEntityCreated followed by a timer was causing issues (server crashes in rare instances) over the round restarting. This is why we opt'd for OnPostWeaponEquip as you are guaranteed to have the correct client, and the weapon hasn't magically disappeared.

I do notice in your example the use of EntRefToEntIndex which could have been the causes of our previous crashes. Either way, if the cvar for the delay is enabled, I now use EntRefToEntIndex when passing the weapon through the timer.

[Neuro Toxin]

Originally Posted by h3bus Also for optimizations and code clarity you could always use m_iItemDefinitionIndex to identify a weapon (instead of using string comparison which are slower). The optimization is really tiny though compared to the cost of spawning a new weapon.

I attempted to use m_iItemDefinitionIndex instead of a classname. However: Map weapons on some maps do not have a definition index and I would to need to complete a classname lookup for the plugin to work properly.

For this reason, I have decided to keep everything class based otherwise I break the cvar functionality for aws_alwaysreplace.

[Root_]

Originally Posted by Neuro Toxin It's optional because if it's not marked this way, the plugin wont start without sm_hosties. It's got nothing to do with compilation without the lastrequest include file. For this reason, the lastrequest include file is part of the download.

Use #tryinclude <hosties>, and check #ifdef hosties_included_ with #endif on hosties code, so everyone can compile plugin without hosties stuff.

Originally Posted by Neuro Toxin ProcessingClientWeapons needs to be cleaned if a client disconnects while the timer is awaiting callback. For this reason, it CANT be static as in my code, PutClientInServer wont have access to clean the process list.

Originally Posted by Neuro Toxin I added debug messages to your example. This is what came back with multiple purchases at once. You can see this doesn't work as you intend. The AK is added first and then the Glock. You can see the Glock completes first and wipes the current processing weapon for the AK. So when the AK comes back it starts the replacement again.

Have you really tested that plugin ingame? It works perfectly for me, otherwise I would not give false suggestions.

Originally Posted by Neuro Toxin Also note that using OnEntityCreated followed by a timer was causing issues (server crashes in rare instances) over the round restarting. This is why we opt'd for OnPostWeaponEquip as you are guaranteed to have the correct client, and the weapon hasn't magically disappeared.

I havent met any crashes for like 1 year with this code, and OEC is way clearer than OnPostEquip IMO.