[nicolaus1111]

hy guys i have been on a server and they had a plugin really nice,
at the beginning of the round the players were in spawn mode u could practically walk through them, for 10 sec, i think is a pease of code borrowed from war3.
Does anyone have and idee what is the name of that plugin ?, i really like it.

[Jelle]

It may not be the most efficient way of doing it, but it is the only way I know how without doing a lot of searching:

PHP Code:

#include <amxmodx>
#include <engine>
#include <hamsandwich>
#include <fun>

new gIsInvis[33]

public plugin_init() 
{
    register_plugin("Player invis on spawn", "1.0", "Jelle")
    
    RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1)
    
    register_event("DeathMsg", "player_death", "a", "1>0")
}

public fwHamPlayerSpawnPost(id)
{
    if ( is_user_alive(id) )
    {
        set_user_rendering(id, kRenderFxGlowShell, 0, 0, 0, kRenderTransAlpha, 255)
        
        entity_set_int(id, EV_INT_solid, SOLID_TRIGGER)
        
        set_task(10.0, "stop_invis", id)
        
        gIsInvis[id] = true
    }
}

public stop_invis(id)
{
    set_user_rendering(id)
    
    entity_set_int(id, EV_INT_solid, SOLID_BBOX)
    
    gIsInvis[id] = false
}

public player_death(id)
{
    if ( gIsInvis[id] )
    {
        set_user_rendering(id)
        
        entity_set_int(id, EV_INT_solid, SOLID_BBOX)
    }
} 


Not tested.

[Exolent[jNr]]

Fixed.

PHP Code:

#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >

new g_bInvis;

#define SetInvis(%1) g_bInvis |= (1<<(%1&31))
#define GetInvis(%1) (g_bInvis & (1<<(%1&31)))
#define RemoveInvis(%1) g_bInvis &= ~(1<<(%1&31))

public plugin_init( )
{
    register_plugin( "Invisible on Spawn", "0.0.1", "Exolent" );
    
    register_forward( FM_AddToFullPack, "FwdAddToFullPackPost", 1 );
    
    RegisterHam( Ham_Spawn, "player", "FwdPlayerSpawnPost", 1 );
    RegisterHam( Ham_Killed, "player", "FwdPlayerKilledPost", 1 );
}

public client_disconnect( iPlayer )
{
    remove_task( iPlayer );
    
    RemoveInvis( iPlayer );
}

public FwdAddToFullPackPost( esHandle, e, iEntity, iHost, iHostFlags, iPlayer, pSet )
{
    if( iPlayer )
    {
        if( iHost != iEntity
        &&  get_orig_retval( )
        &&  is_user_alive( iHost )
        &&  is_user_alive( iEntity )
        &&  GetInvis( iEntity ) )
        {
            set_es( esHandle, ES_Origin, Float:{ 9999999.0, 999999.0, 999999.0 } );
            
            set_es( esHandle, ES_Effects, ( get_es( esHandle, ES_Effects ) | EF_NODRAW ) );
        }
    }
}

public FwdPlayerSpawnPost( iPlayer )
{
    if( is_user_alive( iPlayer ) )
    {
        SetInvis( iPlayer );
        
        remove_task( iPlayer );
        set_task( 10.0, "TaskRemoveInvis", iPlayer );
    }
}

public FwdPlayerKilledPost( iPlayer )
{
    remove_task( iPlayer );
    
    RemoveInvis( iPlayer );
}

public TaskRemoveInvis( iPlayer )
{
    RemoveInvis( iPlayer );
} 


[nicolaus1111]

Thank you very much 4 taking the time to help me, i'm going to test it right now,
im wondering if is gonna have problems on Linux bakhos it has different libraries.
Thanks again.


Ok it has a bag, i have a plugin 4 auto restart after 60 seconds
seens the begginging of the round, when the seconds past and is
time 4 restart the server crashes.

[Jelle]

Why do you want to remove a task when it is only running once Exolent? It should remove itself, right?

Originally Posted by nicolaus1111 Thank you very much 4 taking the time to help me, i'm going to test it right now, im wondering if is gonna have problems on Linux bakhos it has different libraries. Thanks again. Ok it has a bag, i have a plugin 4 auto restart after 60 seconds seens the begginging of the round, when the seconds past and is time 4 restart the server crashes.

What happens if you disable that plugin, and use "sv_restartround 60"? Does it still crash?

[nicolaus1111]

Hello again , so if i disable "Player invis on spawn" the server does not crash anymore
the RR plugin say's " 60 seconds until biological hazard " after dose seconds past a way
and it has to restart it does not restart, is just crushing.

[Jelle]

Originally Posted by Jelle What happens if you disable that plugin, and use "sv_restartround 60"? Does it still crash?

[nicolaus1111]

i have tested the new, disabled the auto RR plugin and is still crushing
it has emptied my server, they were 32 players playing...

[Exolent[jNr]]

Originally Posted by Jelle Why do you want to remove a task when it is only running once Exolent? It should remove itself, right?

Because if a player dies, then the task will be executed on a dead player, which is unnecessary.
If a player leaves, the task will be executed on an invalid player, throwing an error.
If a player spawns again, then the task will be executed too early from the first before, then the proper one will be too late since the one from last spawn removed invis too early.

set_task() does not override existing tasks with the same id.

[Jelle]

Originally Posted by Exolent[jNr] Because if a player dies, then the task will be executed on a dead player, which is unnecessary. If a player leaves, the task will be executed on an invalid player, throwing an error. If a player spawns again, then the task will be executed too early from the first before, then the proper one will be too late since the one from last spawn removed invis too early. set_task() does not override existing tasks with the same id.

Oh. I didn't even think of that. Thanks.