[DWIGHTpN]

It's posible to receive played hours(for another name) from gametracker with socket?

I follow OT_207 tutorial (https://forums.alliedmods.net/showthread.php?t=151401) and i make this plugin:

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <colorchat>
#include <sockets>

new g_PlayerQuest;
#define SetBit(%0) (g_PlayerQuest |= (1 << (1 & 31)))
#define ClearBit(%0) (g_PlayerQuest &= ~(1 << (1 & 31)))
#define CheckBit(%0) (g_PlayerQuest & (1 << (1 & 31)))
#define FAIL 123


new g_szHost[ ] = "gametracker.com";
new g_socket[ 32 ]; // Every player handle
new g_serverip[ 22 ];
new g_enable, g_request;

public plugin_init() {
    register_plugin( "GT Hour", "0.0.5", "Dwight" );
    
    g_enable = register_cvar( "GTh_enable", "1" );
    g_request = register_cvar( "GTh_request", "5.0" );
    get_user_ip(0, g_serverip, charsmax( g_serverip ), 0);
    
    register_concmd( "amx_gt", "ConCMD_GT", ADMIN_KICK, "< name / # userid >" );
    // Can get hour without connected player.
    register_clcmd( "say /hour", "ClCMD_GT" );
}

public ConCMD_GT(id, level, cid) {
    if( !cmd_access(id, level, cid, 2) || !get_pcvar_num( g_enable ) )
        return PLUGIN_HANDLED;
    
    if( CheckBit( id ) ) {
        console_print( id, "Another quest is sending now. Please wait for get information and end process !" );
        return PLUGIN_HANDLED;
    }
    else
        SetBit( id );
    
    new arg[ 32 ];
    read_argv( 1, arg, charsmax( arg ) );
    new player = cmd_target( id, arg, CMDTARGET_NO_BOTS | CMDTARGET_ALLOW_SELF );
    
    if( !( 1 <= player <= get_maxplayers() ) ) {
        console_print(id, "This player is invalid !");
        return PLUGIN_HANDLED;
    }
    
    new name[ 32 ], error, sendbuffer[ 512 ];
    get_user_name( player, name, charsmax(name) );
    new topic[ 100 ];
    format( topic, charsmax( topic ), "/player/%s/%s/", name,g_serverip );
    
    // Connect, quest for amx_gt own command...not for player target...
    g_socket[ id ] = socket_open( g_szHost, 80, SOCKET_TCP, error );
    
    // If found error.
    switch( error ) {
        case 1: {
            console_print( id, "Unable to create socket, close quest !" );
            return PLUGIN_HANDLED;
        }
        case 2: {
            console_print( id, "Unable to connect Gametracker Server, close quest !" );
            return PLUGIN_HANDLED;
        }
        case 3: {
            console_print( id, "Unable to connect to the HTTP port, close quest !" );
            return PLUGIN_HANDLED;
        }
    }
    
    
    console_print( id, "Please wait (%d seconds) to receive hour !", 1+floatround(get_pcvar_float( g_request )) );
    format( sendbuffer, charsmax( sendbuffer ), "GET %s HTTP/1.1^nHost:%s^r^n^r^n", topic, g_szHost);
    socket_send( g_socket[ id ], sendbuffer, charsmax( sendbuffer ) );
    
    
    set_task( 1.0, "CheckReceive", id, name, charsmax( name ), "a", floatround(get_pcvar_float( g_request )) );
    set_task( 1.0 + get_pcvar_float( g_request ), "CloseQSocket", id+FAIL );
    
    return PLUGIN_HANDLED;
}

public ClCMD_GT( id ) {
    if( !get_pcvar_num( g_enable ) || is_user_bot( id ) || is_user_hltv( id ) )
        return PLUGIN_HANDLED;
    
    if( CheckBit( id ) ) {
        client_print_color( id, GREY, "Another quest is sending now. Please wait for get information and end process !" );
        return PLUGIN_HANDLED;
    }
    else
        SetBit( id );
    
    new name[ 32 ], error, sendbuffer[ 512 ];
    get_user_name( id, name, charsmax(name) );
    new topic[ 100 ];
    format( topic, charsmax( topic ), "/server_info/%s/top_players/?query=%s&Search=Search", g_serverip, name );
    
    // Connect, quest for amx_gt own command...not for player target...
    g_socket[ id ] = socket_open( g_szHost, 80, SOCKET_TCP, error );
    
    // If found error.
    switch( error ) {
        case 1: {
            client_print_color( id, GREY, "Unable to create socket, close quest !" );
            return PLUGIN_HANDLED;
        }
        case 2: {
            client_print_color( id, GREY, "Unable to connect Gametracker Server, close quest !" );
            return PLUGIN_HANDLED;
        }
        case 3: {
            client_print_color( id, GREY, "Unable to connect to the HTTP port, close quest !" );
            return PLUGIN_HANDLED;
        }
    }
    
    
    client_print_color( id, GREY, "Please wait (%d seconds) to receive hour !", 1+floatround(get_pcvar_float( g_request )) );
    format( sendbuffer, charsmax( sendbuffer ), "GET %s HTTP/1.1^nHost:%s^r^n^r^n", topic, g_szHost);
    socket_send( g_socket[ id ], sendbuffer, charsmax( sendbuffer ) );
    
    
    set_task( 1.0, "CheckReceive", id, name, charsmax( name ), "a", floatround(get_pcvar_float( g_request )) );
    set_task( 1.0 + get_pcvar_float( g_request ), "CloseQSocket", id+FAIL );
    
    return PLUGIN_HANDLED;
}
    
public CheckReceive( name[], id ) {
    if( socket_change( g_socket[ id ] ) ) {
        new g_data[ 1000 ];
        socket_recv( g_socket[ id ], g_data, charsmax( g_data ) );
        
        new Position = containi( g_data, "Minutes Played: " );
        if( Position < 1 )
            return;
        Position += strlen( "Minutes Played: " );
        new sz_hour[ 11 ], lenght = 0;
        for( new i = 0;i <= 10;i++ ) {
            if ('0' <= g_data[Position + i] <= '9' || g_data[Position + i] == '.') {
                sz_hour[ lenght ] = g_data[ Position + i];
                lenght++;
            }
        }
        
        console_print( id, "GameTracker:^nName:%s^nHours:%s^n",name, str_to_num(sz_hour)/60 );
        client_print_color( id, GREY, "Name:%s | Hours:%s",name, str_to_num(sz_hour)/60 );
        
        socket_close( g_socket[ id ] );
        remove_task( id );
        remove_task( id+FAIL );
        ClearBit( id );
    }
}

public CloseQSocket( task ) {
    new id = task - FAIL;
    console_print( id, "Server not responding!" );
    client_print_color( id, GREY, "Server not responding!" );
    socket_close( g_socket[ id ] );
}

public client_disconnect( id ) {
    if( CheckBit( id ) ) {
        socket_close( g_socket[ id ] );
        remove_task( id );
        remove_task( id+FAIL );
        ClearBit( id );
    }
    return PLUGIN_CONTINUE;
}

    
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/ 


It's not posible or my plugin is wrong coded.. ?

[DWIGHTpN]

BUMP

[Black Rose]

There are some examples in this thread that can easily be modified to do what you want.
https://forums.alliedmods.net/showthread.php?t=223244

If you're having delay problems I could rewrite it using HTTP2 instead.

[Black Rose]

Originally Posted by devilicioux If we can get the hours played ..we can get the ranks as well ..That would be awesome

If I understand you correctly that function already exists in one of the examples in that thread.

[DWIGHTpN]

I try with http library, but is to slow. I got information after 20 sec .

[Black Rose]

Sorry for the delay. I rewrote it using HTTP2 and on-the-fly parsing.
You obviously have to edit the way this information is printed to your liking. I made it fit my purpose of testing.

#include <amxmodx>
#include <http2>
#include <regex>

#define SERVER_IP "PUT YOUR IP HERE"

#define TOTAL   0
#define CURRENT 1

new g_patterns[][] = {
    "(?:First Seen:[\r\n\s]*<.+>[\r\n\s]*)(\w{3} [0-3][0-9], [12][019][0-9][0-9])",
    "(?:Last Seen:[\r\n\s]*<.+>[\r\n\s]*)(Online Now|(?:(?:(?:Yester|To)day)|(?:\w{3} [0-3][0-9], [12][019][0-9][0-9])) (?:1[0-2]|[0-9]):[0-5]\d [A|P]M)",
    "(?:Score:[\r\n\s]*<.+>[\r\n\s]*)(\d+)",
    "(?:Minutes Played:[\r\n\s]*<.+>[\r\n\s]*)(\d+)",
    "(?:Score per Minute:[\r\n\s]*<.+>[\r\n\s]*)(\d+\.?\d?)",
    "(?:Rank on Server:[\r\n\s]*<.+>[\r\n\s]*(?:<a.*>[\r\n\s]*)?)(#\d+(?: out of \d+)?)"
}

enum playerinfo_enum {
    FirstSeen[16],
    LastSeen[16],
    Score[2],
    MinutesPlayed[2],
    Float:ScorePerMinute[2],
    RankOnServer[2],
    bool:CurrentStats
};

new g_playerinfo[33][playerinfo_enum];
new g_downloadinfo[HTTP2_MAX_DOWNLOAD_SLOTS];
new g_totalranks;
new bool:g_cmd_blocked[33];

new buffer[HTTP2_BUFFER_SIZE];

public plugin_init() {
    register_plugin("Gametracker Test", "1.1", "[ --{-@ ]");
    
    register_clcmd("say /myinfo", "clcmd_myinfo");
}

public clcmd_myinfo(id, level, cid) {
    
    if ( g_cmd_blocked[id] )
        return;
    
    g_cmd_blocked[id] = true;
    
    clear_pinfo_array(id);
    
    new name[32];
    get_user_name(id, name, charsmax(name));
    
    new URL[128];
    formatex(URL, charsmax(URL), "http://www.gametracker.com/player/%s/%s/", name, SERVER_IP);
    
    new download_index = HTTP2_Download(URL, _, _, "DownloadProcess");
    if ( download_index >= 0 )
        g_downloadinfo[download_index] = id;
}

public DownloadProcess(index) {
    
    new id = g_downloadinfo[index];
    new num, startpos, result[32];
    
    HTTP2_getDataSafe(index, buffer, charsmax(buffer));
    
    if ( contain(buffer, "PLAYER SUMMARY") == -1 )
        return PLUGIN_CONTINUE;
    
    if ( contain(buffer, "CURRENT STATS") != -1 )
        g_playerinfo[id][CurrentStats] = true;
    
    for ( new i = 0 ; i < sizeof g_patterns ; i++ ) {
        new Regex:hRegex = regex_match(buffer[startpos], g_patterns[i], num, result, charsmax(result));
        
        if ( hRegex >= REGEX_OK ) {
            regex_substr(hRegex, 1, result, charsmax(result));
            
            new slot = g_playerinfo[id][CurrentStats] && ! startpos ? CURRENT : TOTAL;
            
            switch ( i ) {
                case 0: copy(g_playerinfo[id][FirstSeen], charsmax(g_playerinfo[][FirstSeen]), result);
                case 1: copy(g_playerinfo[id][LastSeen], charsmax(g_playerinfo[][LastSeen]), result);
                case 2: g_playerinfo[id][Score][slot] = str_to_num(result);
                case 3: g_playerinfo[id][MinutesPlayed][slot] = str_to_num(result);
                case 4: g_playerinfo[id][ScorePerMinute][slot] = any:str_to_float(result);
                case 5: {
                    g_playerinfo[id][RankOnServer][slot] = str_to_num(result[1]);
                    if ( slot == TOTAL ) {
                        g_totalranks = str_to_num(result[contain(result, "out of") + 7]);
                    }
                }
            }
            
            regex_free(hRegex);
        }
        if ( i == sizeof g_patterns - 1 && g_playerinfo[id][CurrentStats] && ! startpos ) {
            i -= 4;
            startpos = contain(buffer, "ALL TIME STATS");
        }
        else if ( i == sizeof g_patterns - 1 ) {
            server_print("");
            server_print("First Seen: %s", g_playerinfo[id][FirstSeen]);
            server_print("Last Seen: %s", g_playerinfo[id][LastSeen]);
            server_print("");
            server_print("Total Score: %d", g_playerinfo[id][Score][TOTAL]);
            server_print("Total Minutes Played: %d", g_playerinfo[id][MinutesPlayed][TOTAL]);
            server_print("Total Score Per Minute: %0.1f", g_playerinfo[id][ScorePerMinute][TOTAL]);
            server_print("Total Rank: #%d/#%d", g_playerinfo[id][RankOnServer][TOTAL], g_totalranks);
            server_print("");
            server_print("Current Score: %d", g_playerinfo[id][Score][CURRENT]);
            server_print("Current Minutes Played: %d", g_playerinfo[id][MinutesPlayed][CURRENT]);
            server_print("Current Score Per Minute: %0.1f", g_playerinfo[id][ScorePerMinute][CURRENT]);
            server_print("Current Rank: #%d", g_playerinfo[id][RankOnServer][CURRENT]);
            g_cmd_blocked[id] = false;
            return PLUGIN_HANDLED;
        }
    }
    return PLUGIN_CONTINUE;
}

clear_pinfo_array(id) {
    arrayset(g_playerinfo[id][FirstSeen], 0, sizeof g_playerinfo[][FirstSeen]);
    arrayset(g_playerinfo[id][LastSeen], 0, sizeof g_playerinfo[][LastSeen]);
    g_playerinfo[id][Score][TOTAL] = 0;
    g_playerinfo[id][Score][CURRENT] = 0;
    g_playerinfo[id][MinutesPlayed][TOTAL] = 0;
    g_playerinfo[id][MinutesPlayed][CURRENT] = 0;
    g_playerinfo[id][ScorePerMinute][TOTAL] = any:0.0;
    g_playerinfo[id][ScorePerMinute][CURRENT] = any:0.0;
    g_playerinfo[id][RankOnServer][TOTAL] = 0;
    g_playerinfo[id][RankOnServer][CURRENT] = 0;
    g_playerinfo[id][CurrentStats] = false;
}

[devilicioux]

Hey Blackrose .. First of all thank you for helping with the codes everytime ..
I tried the code you made in that thread using HTTP.inc .. There seems to be a little problem .. whenever i type /myinfo in chat .. The server gets stuck for 2-3 seconds and few of the players get Overflowed,I got lagged for atleast a minute .. and suddenly i woke up back in next round .. Checked up the server console it showed almost 10-12 ppl got overflowed and kicked.
This was the bad thing that happened.Now Gud thing was this happened second time.
When i tried first time .. 2-3 Seconds stucking and game continuous and then out of no where after 15-20 seconds the Info was shown on HUD Such a delay is not gud.
So i had to remove the plugin as a result.May be the socket connections are happening too slow in that plugin.

Now i ll go and try the code you made with Http2.inc and Give you the accurate feedback

[DWIGHTpN]

@Black Rose : Thank you , this method is fast.

Here is http2 library: https://forums.alliedmods.net/showpo...62&postcount=1

[ss1234]

Hi,
Could someone rewrite the plugin of #6 made by black rose?
I tried compiling it but it gave errors as below :
Welcome to the AMX Mod X 1.8.1-300 Compiler.
Copyright (c) 1997-2013 ITB CompuPhase, AMX Mod X Team

Rank.sma(67) : error 017: undefined symbol "HTTP2_getDataSafe"
Rank.sma(67) : error 088: number of arguments does not match definition

2 Errors.
Could not locate output file rank.amx (compile failed).

thanks!