[crazyeffect]

Hey,

I disabled 'kill' command in my server, so now the people use a grenade when they are a zombie!

So i need a plugin that disables the grenade kill

[Dores]

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define DMG_GRENADE      (1 << 24)

new NoDamage;
new NoKill;


public plugin_init()
{
    register_plugin("No Grenade Self-Kill/Damage", "1.0", "Dores");
    
    NoDamage = register_cvar("amx_no_self_nade_damage", "1");
    NoKill = register_cvar("amx_no_self_nade_kill", "1");
    
    RegisterHam(Ham_TakeDamage, "player", "PrePlayerDamaged");
}

public PrePlayerDamaged(id, inflictor, attacker, Float:damage, damagebit)
{
    static noDamage;
    static noKill;
    if (     !inflictor
    ||      id != attacker
    ||      !(damagebit & DMG_GRENADE)
    ||      ( !(noDamage = get_pcvar_num(NoDamage)) && !(noKill = get_pcvar_num(NoKill)) )      )
        return;
    
    if (noDamage)
        SetHamParamFloat(4, 0.0);
    
    else if (noKill)
    {
        static Float:health;
        pev(id, pev_health, health);
        
        // the damage passed through this forward isn't accurate, but o well...
        if (health <= damage)
        {
            SetHamParamFloat(4, 0.0);
            set_pev(id, pev_health, 1.0);
        }
    }
} 


[ConnorMcLeod]

You don't have to check classname, just check if damagebit & (1<<24)

[Bugsy]

This will block players from suicide via grenade. There is a cvar that, if enabled, will allow players to still receive damage from grenades but will not allow them to die from them. If the cvar is disabled then all grenade damage is blocked. Grenades thrown by other players will still issue damage as normal.

Example, with cvar ngs_allowdamage = 1
Player starts round with 100 health and attempts to kill self with 4 nades.
Grenade 1 issues 50 dmg, health = 50
Grenade 2 issues 25 dmg, health = 25
Grenade 3 issues 30 dmg, dmg blocked, health = 25  ( since 30 dmg > 25 health )
Grenade 4 issues 10 dmg, health = 15

If cvar ngs_allowdamage = 0 then all grenade damage is blocked

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN "No Grenade Suicide"
#define VERSION "1.0"
#define AUTHOR "bugsy"

#define DMG_GRENADE    ( 1 << 24 )

new g_pAllowDamage;

public plugin_init() 
{
    register_plugin( PLUGIN , VERSION , AUTHOR );
    
    RegisterHam( Ham_TakeDamage , "player" , "fw_HamTakeDamage" );
    
    g_pAllowDamage = register_cvar( "ngs_allowdamage" , "1" );
}

public fw_HamTakeDamage( iVictim , iInflictor , iAttacker , Float: fDamage , iBitDamage )
{
    if ( ( iVictim != iAttacker ) || !iInflictor || !( iBitDamage & DMG_GRENADE ) )
        return HAM_IGNORED;

    new iCVar = get_pcvar_num( g_pAllowDamage );    
    new Float: fHealth;
    pev( iVictim , pev_health , fHealth );

    return ( !iCVar || ( iCVar && ( fDamage >= fHealth ) ) ) ? HAM_SUPERCEDE : HAM_IGNORED;
} 


[Dores]

Originally Posted by ConnorMcLeod You don't have to check classname, just check if damagebit & (1<<24)

i've never heard of that bit. O_o
updated.

[Arkshine]

When you see the damagebits from a grenade you see it's always 16777216 so 1 << 24. Maybe in cs code a new DMG_* has been added.

[Cuttlas]

nice job bro