[Ark_Procession]

Hello! Is there any way to change c4 explosion damage? any plugin out there?

[Bacardi]

For csgo, remove cheat flags from commands:
map_setbombradius
map_showbombradius


This will change (or create) entity info_map_parameters bombradius value.
Default radius is 500
Maximum radius is 2048
- Output message: Bomb Damage is 2048, Radius is 7168

PHP Code:


public void OnPluginStart()
{
    if(CommandExists("map_setbombradius"))
    {
        SetCommandFlags("map_setbombradius", FCVAR_NONE);
    }
    if(CommandExists("map_showbombradius"))
    {
        SetCommandFlags("map_showbombradius", FCVAR_NONE);
    }
} 


However in CS:S, above code works but it would spam lot of errors in server console x 104 times:
UTIL_GetListenServerHost() called from a dedicated server or single-player game.

So here is some kind "replica"

PHP Code:

#include <sdktools>

public void OnPluginStart()
{
    RegAdminCmd("sm_map_setbombradius", map_setbombradius, ADMFLAG_CHEATS);
    RegAdminCmd("sm_map_showbombradius", map_showbombradius, ADMFLAG_CHEATS);
}

int info_map_parameters = -1;
float radius = 500.0;

public void OnMapStart()
{
    info_map_parameters = FindEntityByClassname(-1, "info_map_parameters");
    radius = 500.0; // I can't get real value m_flBombRadius from entity info_map_parameters. I set default 500.0
}


public Action map_setbombradius(int client, int args)
{
    if(args < 1)
    {
        map_showbombradius(client, 0);

        return Plugin_Handled;
    }

    char arg[10];
    GetCmdArg(1, arg, sizeof(arg));
    radius = StringToFloat(arg);

    // Find entity "info_map_parameters"
    info_map_parameters = FindEntityByClassname(-1, "info_map_parameters");


    if(info_map_parameters == -1)
    {
        // Try create entity "info_map_parameters"
        info_map_parameters = CreateEntityByName("info_map_parameters");

        if(info_map_parameters == -1)
        {
            LogError("Couldn't create entity \"info_map_parameters\"");
            return Plugin_Handled;
        }
    }

    DispatchKeyValueFloat(info_map_parameters, "bombradius", radius);

    map_showbombradius(client, 0);

    return Plugin_Handled;
}

public Action map_showbombradius(int client, int args)
{
    float bombdamage = 500.0;

    if(info_map_parameters != -1)
    {
        bombdamage = radius;
    }

    float bombradius = bombdamage * 3.5;

    PrintToConsole(client, "Bomb Damage is %.0f, Radius is %.0f\n", bombdamage, bombradius );
    

    return Plugin_Handled;
} 


[Ark_Procession]

Thanks Bacardi!, i have sv_cheats 1 in my server, so , should this cvars simply work without that code?
or should i compile that tiny amount of code and put the smx in plugins?

[Bacardi]

try it

[Ark_Procession]

Originally Posted by Bacardi try it

i did! and it worked.

its a shame that the radius cant be kept low. but damage high.

[Bacardi]

Ok, that was in-game explosion radius.

Here is for C4 explosion damage scale.
bombdamagescale 1.0 = 100%
bombdamagescale 0.5 = 50%
bombdamagescale 5.0 = 500%

PHP Code:

#include <sdkhooks>

ConVar bombdamagescale;
ConVar bombexplosiondistance;

public void OnPluginStart()
{

    bombdamagescale = CreateConVar("bombdamagescale", "1.0", "C4 explosion damage multiplier, 1.2 = 120\% 0.5 = 50\%", _, true, 0.0);
    bombexplosiondistance = CreateConVar("bombexplosiondistance", "200.0", "C4 explosion distance", _, true, 1.0);

    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i)) OnClientPutInServer(i);
    }
}

public void OnClientPutInServer(int client)
{
    if(IsClientSourceTV(client) || IsClientReplay(client))
        return;

    SDKHook(client, SDKHook_OnTakeDamageAlive, OnTakeDamageAlive);
}

public Action OnTakeDamageAlive(int victim, int &attacker, int &inflictor, float &damage, int &damagetype)
{

    if(damagetype & DMG_BLAST && attacker > MaxClients && HasEntProp(attacker, Prop_Send, "m_flC4Blow"))
    {
        float pos1[3], pos2[3];

        GetEntPropVector(attacker, Prop_Data, "m_vecOrigin", pos1);
        GetEntPropVector(victim, Prop_Data, "m_vecOrigin", pos2);
        
        //PrintToServer("GetVectorDistance %f", GetVectorDistance(pos1, pos2));

        if(GetVectorDistance(pos1, pos2) <= bombexplosiondistance.FloatValue)
        {
            damage *= bombdamagescale.FloatValue;
            return Plugin_Changed;
        }
        
        // No damage outside of bombexplosiondistance
        return Plugin_Handled;
    }


    return Plugin_Continue;
} 


[Ark_Procession]

Originally Posted by Bacardi Ok, that was in-game explosion radius. Here is for C4 explosion damage scale. bombdamagescale 1.0 = 100% bombdamagescale 0.5 = 50% bombdamagescale 5.0 = 500% PHP Code: #include <sdkhooks> ConVar bombdamagescale; public void OnPluginStart() {     bombdamagescale = CreateConVar("bombdamagescale", "1.0", "C4 explosion damage multiplier, 1.2 = 120\% 5.0 = 50\%", _, true, 0.0, true, 5.0);     for(int i = 1; i <= MaxClients; i++)     {         if(IsClientInGame(i)) OnClientPutInServer(i);     } } public void OnClientPutInServer(int client) {     if(IsClientSourceTV(client) || IsClientReplay(client))         return;     SDKHook(client, SDKHook_OnTakeDamageAlive, OnTakeDamageAlive); } public Action OnTakeDamageAlive(int victim, int &attacker, int &inflictor, float &damage, int &damagetype) {     if(damagetype & DMG_BLAST && attacker > MaxClients && HasEntProp(attacker, Prop_Send, "m_flC4Blow"))     {         damage *= bombdamagescale.FloatValue;         return Plugin_Changed;     }     return Plugin_Continue; }

It works perfectly. Any chance to add a distance cvar too?

Thanks so much Bacardi, i am glad you took the time to make this for me. it is deeply appreciated.

You rock

[Bacardi]

Originally Posted by Ark_Procession It works perfectly. Any chance to add a distance cvar too? Thanks so much Bacardi, i am glad you took the time to make this for me. it is deeply appreciated. You rock

Could you tell what you mean by distance ?

[Ark_Procession]

Originally Posted by Bacardi Could you tell what you mean by distance ?

i meant Change the radius of explosion but have it be independt from the damage set.
(otherwkse game default cvar should be enough) but its not the case.


eg: bombexplosiondistance 200. and the radius of the c4 explosion would be shorter.

i think the real reason why i ask for thia is because c4 damage go through walls and it feels a little bit
unrealistic.

[Bacardi]

Updated post #6