[rory98]

i have searched the forum for script to change a prop model with a custom one,i found this,what im trying to do is to change the ammo pile model to a custom one
the code compile just fine, but the game wont load and crashes with this error :
588/ - weapon_ammo_spawn: UTIL_SetModel: not precached: models/witch_bowl/bowl.mdl

#include <sourcemod> 
#include <sdktools> 
#include <sdkhooks> 

public OnMapStart() 
{ 
    PrecacheModel("models/witch_bowl/bowl.mdl"); 
} 

public void OnEntityCreated(entity, const String:classname[]) 
{ 

    if ( StrEqual(classname, "weapon_ammo_spawn") ) 
    { 
        SDKHook(entity, SDKHook_SpawnPost, Hook_EntitySpawned); 
    } 
} 

public void Hook_EntitySpawned(entity) 
{ 
    if(IsValidEntity(entity)) 
    { 
        SetEntityModel(entity, "models/witch_bowl/bowl.mdl"); 
    } 
}

[Marttt]

Which game? Is that a custom model?

Try using:

PHP Code:

PrecacheModel("models/witch_bowl/bowl.mdl", true); 


(added true parameter) but may not be related.

[rory98]

Originally Posted by Marttt Which game? Is that a custom model? Try using: PHP Code: PrecacheModel("models/witch_bowl/bowl.mdl", true);  (added true parameter) but may not be related.

game is l4d, and yes its a custom model
i tried to add "true". and still same error

[Bacardi]

witch_bowl/bowl.mdl ? nope

Could you check your model path, one more time ?
You have model, in your server files AND in your own game files ?

[cravenge]

Iirc, OnEntityCreated fires first before OnMapStart so precaching the model there might be already too late. Why not...

PHP Code:

public void OnEntityCreated(int entity, const char[] classname)
{ 
    if (entity < 1 || entity > 2048)
    {
        return;
    }
    
    if (strcmp(classname, "weapon_ammo_spawn") == 0) 
    { 
        SDKHook(entity, SDKHook_SpawnPost, Hook_EntitySpawned);
    }
}

public void Hook_EntitySpawned(int entity) 
{
    // I think IsValidEntity is no longer needed here since all hooks get unhooked
    // automatically when the entity in question is destroyed
    if (!IsModelPrecached("models/witch_bowl/bowl.mdl"))
    {
        PrecacheModel("models/witch_bowl/bowl.mdl");
    }
    SetEntityModel(entity, "models/witch_bowl/bowl.mdl");
} 


?

[Marttt]

You can try looping through all entities aswell as a workaround some seconds after OnMapStart:

PHP Code:

    int entity = -1;
    while ((entity = FindEntityByClassname(entity, "weapon_ammo_spawn")) != -1)
    {
        SetEntityModel(entity, "models/witch_bowl/bowl.mdl");
    } 


[rory98]

Originally Posted by Bacardi witch_bowl/bowl.mdl ? nope Could you check your model path, one more time ? You have model, in your server files AND in your own game files ?

yes i double checked that, everything is on the right place.

[Bacardi]

Zip and upload model in your post

[rory98]

Originally Posted by cravenge Iirc, OnEntityCreated fires first before OnMapStart so precaching the model there might be already too late. Why not... PHP Code: public void OnEntityCreated(int entity, const char[] classname) {      if (entity < 1 || entity > 2048)     {         return;     }          if (strcmp(classname, "weapon_ammo_spawn") == 0)      {          SDKHook(entity, SDKHook_SpawnPost, Hook_EntitySpawned);     } } public void Hook_EntitySpawned(int entity)  {     // I think IsValidEntity is no longer needed here since all hooks get unhooked     // automatically when the entity in question is destroyed     if (!IsModelPrecached("models/witch_bowl/bowl.mdl"))     {         PrecacheModel("models/witch_bowl/bowl.mdl");     }     SetEntityModel(entity, "models/witch_bowl/bowl.mdl"); }  ?

it works as intended , thanks!

[rory98]

Originally Posted by Bacardi Zip and upload model in your post

i managed to solve it, thanks for reply