[93SHADoW]

Is there a way to check if an active CP is currently being captured and it's capture percentage?

I run a fork of Freak Fortress 2 and i've been wanting to check if an active CP is being capped on when FF2's countdown timer reaches 0, and instead of ending the round, it would enter an "overtime" mode to give players/bosses a chance to finish capping or until they manage to defeat the boss/kill the last players while capping the point, or until the point is capped. If the CP has no capture percentage, it would then proceed with how FF2 ends the round like it normally would when the timer reaches 0.

Just like how on normal CP/KOTH maps, it would enter "overtime" if a CP is still being capped by the time the round timer reaches 0 until neither team is no longer capping it, or until it is capped.

[Akuba]

You could use the "teamplay_point_startcapture" event to track the control point.

Use the "teamplay_point_startcapture" and cache the cp entity.

Use the entity output "OnCapReset" to track if the point has no percentage anymore.

https://wiki.alliedmods.net/Team_For...t_startcapture
https://developer.valvesoftware.com/..._control_point

I am not sure if there is a better way to do it.

[Benoist3012]

I'm sure there is a netprop for the percentage, I will try to found it.
But actually Akuba is right but not for OnCapReset that is never called(I don't know why), I use almost the same way in MvT for run a overtime to the robot team.

PHP Code:

//Define
bool:bControlPointInCapture=false;
//In OnPluginStart
HookEvent("teamplay_point_startcapture", StartCapture);
HookEntityOutput("trigger_capture_area", "OnBreakTeam2", CaptureReset);
HookEntityOutput("trigger_capture_area", "OnBreakTeam1", CaptureReset);

public Action:StartCapture(Handle event, char name[], bool dontBroadcast)
{
    bControlPointInCapture = true;
    return Plugin_Continue;
}
public CaptureReset(char output[], int caller, int activator,float delay)
{
    bControlPointInCapture = false;
    return Plugin_Continue;
} 


[Akuba]

Originally Posted by Benoist3012 but not for OnCapReset that is never called(I don't know why)

I think you have to define it with "AddOutput" before its called.
https://forums.alliedmods.net/showpo...70&postcount=2

[Michalplyoutube]

Theres cp output called on cap start...

OnCapTeam1 Sent when RED capture this point.

OnCapTeam2 Sent when BLUE capture this point.

OnCapReset Sent when owner is changed to neutral.

https://developer.valvesoftware.com/..._control_point

[Pelipoika]

How to get capture point percentage:

gamedata

"Games"
{
	"tf"
	{
		"Signatures"
		{
			"CTeamControlPoint::GetTeamCapPercentage"	//CTeamControlPoint::GetTeamCapPercentage(CTeamControlPoint *this, int) team_control_point entindex, player team
			{
				"library"		"server"
				"windows"		"\x55\x8B\xEC\x56\x8B\xF1\x8B\x0D\x2A\x2A\x2A\x2A\x57\x8B\x86\x6C\x05\x00\x00"
				"linux"		"@_ZN17CTeamControlPoint20GetTeamCapPercentageEi"
				"mac"		"@_ZN17CTeamControlPoint20GetTeamCapPercentageEi"
			}
		}
	}
}

PHP Code:

#include <sdktools>

Handle g_hSDKGetTeamCapPercentage;

public void OnPluginStart()
{
    Handle hConfig = LoadGameConfigFile("serverstuff"); 
    if (hConfig == INVALID_HANDLE) SetFailState("Couldn't find plugin serverstuff.txt!"); 

    StartPrepSDKCall(SDKCall_Entity); 
    PrepSDKCall_SetFromConf(hConfig, SDKConf_Signature, "CTeamControlPoint::GetTeamCapPercentage"); 
    PrepSDKCall_AddParameter(SDKType_PlainOldData, SDKPass_Plain);
    PrepSDKCall_SetReturnInfo(SDKType_Float, SDKPass_Plain);
    if ((g_hSDKGetTeamCapPercentage = EndPrepSDKCall()) == INVALID_HANDLE) SetFailState("Failed to create SDKCall for CTeamControlPoint::GetTeamCapPercentage signature!"); 
    
    CloseHandle(hConfig); 
    
    RegConsoleCmd("sm_percentages", Command_CapPercentages);
}

public Action Command_CapPercentages(int client, int args)
{
    int cp = -1;
    while ((cp = FindEntityByClassname(cp, "team_control_point")) != -1)
    {
        PrintToChatAll("%i, %f%%", cp, SDKCall(g_hSDKGetTeamCapPercentage, cp, TF2_GetClientTeam(client)));
    }
        
    return Plugin_Handled;
}
/*
68, 0.000000%
300, 0.317620%
304, 0.000000%
*/ 


[Benoist3012]

Originally Posted by Michalplyoutube OnCapTeam1 Sent when RED capture this point. OnCapTeam2 Sent when BLUE capture this point.

Actually those outputs are already handled by the event "teamplay_point_startcapture"

[Michalplyoutube]

Originally Posted by Pelipoika How to get capture point percentage: gamedata "Games" { "tf" { "Signatures" { "CTeamControlPoint::GetTeamCapPercentage" //CTeamControlPoint::GetTeamCapPercentage(CTeamControlPoint *this, int) team_control_point entindex, player team { "library" "server" "windows" "\x55\x8B\xEC\x56\x8B\xF1\x8B\x0D\x2A\x2A\x2A\x2A\x57\x8B\x86\x6C\x05\x00\x00" "linux" "@_ZN17CTeamControlPoint20GetTeamCapPercentageEi" "mac" "@_ZN17CTeamControlPoint20GetTeamCapPercentageEi" } } } } PHP Code: #include <sdktools> Handle g_hSDKGetTeamCapPercentage; public void OnPluginStart() {     Handle hConfig = LoadGameConfigFile("serverstuff");      if (hConfig == INVALID_HANDLE) SetFailState("Couldn't find plugin serverstuff.txt!");      StartPrepSDKCall(SDKCall_Entity);      PrepSDKCall_SetFromConf(hConfig, SDKConf_Signature, "CTeamControlPoint::GetTeamCapPercentage");      PrepSDKCall_AddParameter(SDKType_PlainOldData, SDKPass_Plain);     PrepSDKCall_SetReturnInfo(SDKType_Float, SDKPass_Plain);     if ((g_hSDKGetTeamCapPercentage = EndPrepSDKCall()) == INVALID_HANDLE) SetFailState("Failed to create SDKCall for CTeamControlPoint::GetTeamCapPercentage signature!");           CloseHandle(hConfig);           RegConsoleCmd("sm_percentages", Command_CapPercentages); } public Action Command_CapPercentages(int client, int args) {     int cp = -1;     while ((cp = FindEntityByClassname(cp, "team_control_point")) != -1)     {         PrintToChatAll("%i, %f%%", cp, SDKCall(g_hSDKGetTeamCapPercentage, cp, TF2_GetClientTeam(client)));     }              return Plugin_Handled; } /* 68, 0.000000% 300, 0.317620% 304, 0.000000% */

I bet this works too m_flCapPercentages in tf_objective_resource

[93SHADoW]

#6 solved my question.