[SnoW]

Originally Posted by Lee I don't know why you guys are using set_task() and recursion when a simple while loop would be more efficient.

There's no need even for a while.

[Lee]

Indeed (depending on what approach to collecting valid players is taken). Here's an efficient and simple solution to a simple problem.

#include <amxmodx>

new bool:isConnected[33];

public client_putinserver(id)
    isConnected[id] = true;
    
public client_disconnect(id)
    isConnected[id] = false;

getRandomPlayer()
{
    //returns player index or 0 if no players are found
    
    static playerList[32];
    new playerCount;
    
    for(new i = 1; i < 33; i++)
    {
        if(!isConnected[i])
            continue;
            
        if(1 < get_user_team(i) < 4)
            playerList[playerCount++] = i;
    }
        
    return playerCount ? playerList[random_num(0, playerCount - 1)] : 0;
}

Edit: this doesn't meet the request because I was following what the the other three did. :/

[Dores]

Lee is right, a loop is enough.
this is for 1 random player:

PHP Code:

#include <amxmodx>


public plugin_init()
    register_event("HLTV", "NewRound", "a", "1=0", "2=0");

public NewRound()
{
    new playersnum = get_playersnum();
    new randPlayer;
    
    do
        randPlayer = random_num(1, playersnum);
    
    while (/* randPlayer is a invalid player */);
} 


[padilha007]

Originally Posted by Exolent[jNr] padilha's way is only good if you want 1 player. If you want random players, see the tutorial that arkshine gave.

@SnoW

try use my code before say anything

[Exolent[jNr]]

GetRandomPlayer()
{
    new players[32], pnum;
    get_players(players, pnum);
    
    if( !pnum ) return 0;
    
    return players[random(pnum)];
}

It's been shown that get_players() is faster than looping through players.

[SnoW]

Originally Posted by padilha007 @SnoW try use my code before say anything

And why I should do that? I already said the problems that it had and attached a code which is five times better than yours. I don't need to test it since I see from the code that it isn't efficient at all.

[micke1101]

Thank you all .
I guess ill use padilha's function.
But isnt it possible that it takes same person twice? (since i wanna make 4 players ct (with different equipments) and the rest terrorist (1 with special maybe that could be done with checking who has the bomb.))

[Lee]

Hah, this forum never changes, discussing minor details about code that doesn't even meet the requirements.

padilha007: you've been told what's wrong with your code. You're using set_task() as a control structure and that's simply not what it's for. Your code also includes a redundant test.

Exolent: whether or not to use get_players() once in a single round is a matter of style. The speed difference, if measurable, is negligible. Not only that, but you need to determine if the players are alive (or on the correct team), which is "unsupported" using get_players() flags for whatever reason.

Dores: that code will result in a infinite loop if there's no valid players connected. You also include a similar bug as hleV (by assuming player indexes are consecutive and begin at 1) and so could be stuck in an infinite loop even if there are valid players connected.

micke1101: you need to follow Exolent's tutorial. As has been stated multiple times, none of the code here meets your request. Post again if you need help with it.

[Bugsy]

Here's a way you could do it. This will only return a player that has not yet been selected. You could modify the code to make it automatically reset selected players when all players have been selected. If you are unsure how to do this just ask.

PHP Code:

new g_Selected;
new g_MaxPlayers;

g_MaxPlayers = get_maxplayers();

ResetSelected()
{
    g_Selected = 0;
}

GetRandomPlayer()
{
    new iPlayerBits;
    new i;
    
    //Make a bitsum of connected player indexes. 
    //You can add additional checks here (bot,team,admin, etc).
    for ( i = 1 ; i <= g_MaxPlayers ; i++ )
        if ( is_user_connected( i ) )
            iPlayerBits |= ( 1 << ( i - 1 ) );
    
    //No players are connected.
    if ( !iPlayerBits )
        return 0;

    //Keep looping until there is no players that haven't been selected.
    while( iPlayerBits != g_Selected )
    {
        //Get random player id
        i = ( random_num( 1 , g_MaxPlayers ) - 1 );
        
        //If player is connected and has not yet been selected
        if ( ( iPlayerBits & ( 1 << i ) ) && !( g_Selected & ( 1 << i ) ) )
        {
            //Set bit in g_Selected bit-field so they will be ignored on the next call
            g_Selected |= ( 1 << i );
            return ( i + 1 );
        }
    }
    
    //All players have already been selected.
    return 0;
} 


[Dores]

I've posted that code knowing that it might result in a infinite loop. the only thing needs to be changed is using max players instead of players amount, and to make sure that the players amount is not 0.