[botz]

I want a plugin that gives us 10 sec delay for changing name, so if change ur name every sec it wont work, it will keep saying u on message area "[AMXX] Name can be only changed every 20 second." There are exploits which u can change your name every sec. Thats why i need this delay.

I did check other plugins similiar to this some that were approved dont even work, some that had this function has more and alot more stuff that i dont need. Please someone make me this

Thanks for the help

[Hartmann]

Try...

PHP Code:

#include <amxmodx>
#include <fakemeta>

new cName[33];

public plugin_init() {
    register_forward(FM_ClientUserInfoChanged, "ClientUserInfoChanged")     
}
public ClientUserInfoChanged(usr) 
{
    static const name[] = "name" 
    static szOldName[32], szNewName[32] 
    pev(usr, pev_netname, szOldName, charsmax(szOldName)) 
    if( szOldName[0] ) 
    { 
        get_user_info(usr, name, szNewName, charsmax(szNewName)) 
        if(cName[usr]){
            if( !equal(szOldName, szNewName)) { 
                set_user_info(usr, name, szOldName); 
                client_print(usr,print_chat, "Wait to pass 20 seconds of last change.");
                return FMRES_HANDLED; 
            } 
        } 
        else 
        {
            cName[usr] = true;
            set_task(20.0, "change", usr);
            client_print(usr,print_chat, "Name change allowed for 20 seconds."); 
        } 
    }
    return FMRES_IGNORED 
}  
public change(usr){ 
    cName[usr] = false;
}
public client_putinserver(usr){ 
    cName[usr] = false;
} 


[botz]

Hey i need a bit more edit

When he changes name in less then 20 secs it should tell him "[AMXX] Name Change Delay, You can only change name manually every 20 secs." IN Console and in Chat area, whenever he tries when the time hasnt passed

It shouldnt change his next name automatic in next 20 secs but tell him to try again changing in 20 secs, he should try again manually

Thanks for the great work sir

[fysiks]

Here's a simpler, more compact and more efficient version:

PHP Code:

#include <amxmodx>
#include <fakemeta>

new g_szNameChangeMessage[] = "Name change denied.  You can only change name manually every 20 seconds."

public plugin_init()
{
    register_forward(FM_ClientUserInfoChanged, "ClientUserInfoChanged")
}

public ClientUserInfoChanged(id, buffer)
{
    static szOldName[32], szNewName[32]
    static iTime[33]

    if( !is_user_connected(id) || is_user_bot(id) || !is_user_alive(id) )
        return FMRES_IGNORED
    
    get_user_name(id, szOldName, charsmax(szOldName))
    engfunc(EngFunc_InfoKeyValue, buffer, "name", szNewName, charsmax(szNewName))
    if( !equal(szOldName, szNewName))
    {
        if( get_systime() < iTime[id] )
        {  // Name change not allowed, override the name change request to request the same name
            engfunc(EngFunc_SetClientKeyValue, id, buffer, "name", szOldName)
            console_print(id, g_szNameChangeMessage)
            client_print(id, print_chat, g_szNameChangeMessage)
            return FMRES_SUPERCEDE
        }
        else
        {  // Name change allowed, update the time for the next name change
            iTime[id] = get_systime() + 20
        }
    }
    return FMRES_IGNORED
} 


You can change the string for g_szNameChangeMessage to whatever message you want.

P.S. This is based on other name change plugins that I have but I didn't explicitly test this on. Let me know if it doesn't work.

[botz]

Buggy

People have changed to other peoples name, or when u join u have a diff name to same as others, and the other guys switch auto matic, sometimes new people have same name as old people that were in server and had left, so new one joins has hiss name

Also when you fix can you update the message and time

Time: 5 secs , manually
Message:
[AMXX] Name change request refused. You can only change name manually every 5 seconds.

Thanks for the work

[fysiks]

Originally Posted by botz Buggy

How so?

Originally Posted by botz People have changed to other peoples name, or when u join u have a diff name to same as others, and the other guys switch auto matic, sometimes new people have same name as old people that were in server and had left, so new one joins has hiss name

This plugin has nothing to do with multiple players having the same name.

Originally Posted by botz Also when you fix can you update the message and time Time: 5 secs , manually Message: [AMXX] Name change request refused. You can only change name manually every 5 seconds.

I made it EXTREMELY easy for you to do that on your own.

[botz]

Originally Posted by fysiks How so? This plugin has nothing to do with multiple players having the same name. I made it EXTREMELY easy for you to do that on your own.

I mean that the bug is, when player enters his name is changed to anothers players name who had "LEFT" the server. Automatically thats bug.

I know u made it so easy but what i meant is that for the new plugin you make after knowing this bugs, please add those new settings i listed above.

Thanks for helping, love your work

[fysiks]

Originally Posted by botz I mean that the bug is, when player enters his name is changed to anothers players name who had "LEFT" the server. Automatically thats bug.

I'm not sure how that is possible but I added an extra check which I think might help. I posted the new code in the post above.