[Xc_ace]

I want to make a plugin to detect whether player is in my range when I using Taser. Is there are any ways to make it come true? (Sorry for my bad english, its not my main language)

[databomb]

Yes, something like this is possible with a SourceMod plugin. There are SDKHooks that will allow you to know when a player has the taser equipped; I would try SDKHook_WeaponSwitchPost and you may need to look at the classname of the weapon to see if it's the taser or not.

Once you know the taser is the active weapon then you'll need to script a way to detect whether the enemy player is in range or not. There are several options available there - one would be to loop through all clients and get the distance between the player with the taser and the enemy players and if at least one is within range then provide that indication to the player with the taser. You may also consider using TraceRay to see if you're actively looking at an enemy player and then check if the distance is within a certain amount to that particular enemy player.

[Bacardi]

here is something... wierd content
- When ever you hold taser, 1 sec timer will run repeatly.
- Print in chat player count and names what are in range.
- Some wierd angle check, look players front of you 80 degree wide area wher you aim or something like that.

Spoiler

PHP Code:

#include <sdktools>
#include <sdkhooks>
#include <cstrike>

Handle TimerCheckRange[MAXPLAYERS+1];


public void OnPluginStart()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i)) OnClientPutInServer(i);
    }
}

public void OnClientPutInServer(int client)
{
    if(!IsFakeClient(client) && !IsClientReplay(client) && !IsClientSourceTV(client))
    {
        SDKHook(client, SDKHook_WeaponCanSwitchToPost, WeaponCanSwitchToPost);
    }
}

public void WeaponCanSwitchToPost(int client, int weapon)
{
    //PrintToServer("WeaponCanSwitchToPost");
/*
                "range"        "190"
                "range modifier"        "0.004900"
*/
    if(!HasEntProp(weapon, Prop_Send, "m_iItemDefinitionIndex"))
        return;

    CSWeaponID csweapon = CS_ItemDefIndexToID(GetEntProp(weapon, Prop_Send, "m_iItemDefinitionIndex"));
    
    if(csweapon != CSWeapon_TASER)
        return;


    DataPack pack;
    TimerCheckRange[client] = CreateDataTimer(1.0, checkrange, pack, TIMER_REPEAT);
    pack.WriteCell(client);
    pack.WriteCell(GetClientUserId(client));

    // There are set in taser, items_game.txt
    float m_flRange = 190.0;
    float m_flRangeModifier = 0.004900;

    pack.WriteFloat(m_flRange);
    pack.WriteFloat(m_flRangeModifier);
}

public Action checkrange(Handle timer, DataPack pack)
{
    pack.Reset();

    int index = pack.ReadCell();
    int userid = pack.ReadCell();

    if(TimerCheckRange[index] != timer)
    {
        return Plugin_Stop;
    }

    int client = GetClientOfUserId(userid);

    if(!client || !IsClientInGame(client))
    {
        TimerCheckRange[index] = null;
        return Plugin_Stop;
    }

    if(!HasEntProp(client, Prop_Send, "m_hActiveWeapon"))
    {
        TimerCheckRange[index] = null;
        return Plugin_Stop;
    }

    int weapon = GetEntPropEnt(client, Prop_Send, "m_hActiveWeapon");

    if(weapon < MaxClients)
    {
        TimerCheckRange[index] = null;
        return Plugin_Stop;
    }

    CSWeaponID csweapon = CS_ItemDefIndexToID(GetEntProp(weapon, Prop_Send, "m_iItemDefinitionIndex"));

    if(csweapon != CSWeapon_TASER)
    {
        TimerCheckRange[index] = null;
        return Plugin_Stop;
    }

    float m_flRange = pack.ReadFloat();
    float m_flRangeModifier = pack.ReadFloat();

    float eyepos[3], eyeangl[3];
    GetClientEyePosition(client, eyepos);
    GetClientEyeAngles(client, eyeangl);

    int[] targets = new int[MaxClients+1];
    int count;

    float enemypos[3], angle[3], distance, vector[3], fwd[3];

    float maxangle = 40.0;
    float angledistance;


    for(int i = 1; i <= MaxClients; i++)
    {
        if(client == i || !IsClientInGame(i) || GetClientTeam(i) <= CS_TEAM_SPECTATOR || !IsPlayerAlive(i))
            continue;

        GetClientEyePosition(i, enemypos);
        
        MakeVectorFromPoints(eyepos, enemypos, vector);

        distance = GetVectorLength(vector);

        if(distance >= m_flRange)
            continue;

        GetVectorAngles(vector, angle);

        // re-format player eye angle
        GetAngleVectors(eyeangl, fwd, NULL_VECTOR, NULL_VECTOR);
        GetVectorAngles(fwd, fwd);


        // Angle rotate distance is 0 ... 360
        // - problem began on close 0 point when calculate
        // - rotate angle 90 degrees when we are close 0 point.

        if(0.0 <= angle[1] <= 90.0 &&
            270.0 <= fwd[1] <= 360.0 ||
            0.0 <= fwd[1] <= 90.0 &&
            270.0 <= angle[1] <= 360.0)
        {
            angle[1] -= 90.0;
            fwd[1] -= 90.0;
            
            if(angle[1] < 0.0)
                angle[1] += 360.0;
            
            if(fwd[1] < 0.0)
                fwd[1] += 360.0;
        }

        //PrintToServer("\nangle %f", angle[1]);
        //PrintToServer("fwd %f", fwd[1]);
        //PrintToServer("angle[1] - fwd[1] %f", angle[1] > fwd[1] ? angle[1] - fwd[1]:fwd[1] - angle[1]);

        
        angledistance = angle[1] > fwd[1] ? angle[1] - fwd[1]:fwd[1] - angle[1];
        
        if(angledistance > maxangle)
            continue;
        
        
        targets[count++] = i;
        
    }

    char msg[244];
    Format(msg, sizeof(msg), "Taser! - You have %i enemies in close-range\n", count);
    
    for(int x = 0; x < count; x++)
    {
        Format(msg, sizeof(msg), "%s, %N", msg, targets[x]);
    }
    PrintToChat(client, msg);



    return Plugin_Continue;
} 


[Xc_ace]

Originally Posted by databomb Yes, something like this is possible with a SourceMod plugin. There are SDKHooks that will allow you to know when a player has the taser equipped; I would try SDKHook_WeaponSwitchPost and you may need to look at the classname of the weapon to see if it's the taser or not. Once you know the taser is the active weapon then you'll need to script a way to detect whether the enemy player is in range or not. There are several options available there - one would be to loop through all clients and get the distance between the player with the taser and the enemy players and if at least one is within range then provide that indication to the player with the taser. You may also consider using TraceRay to see if you're actively looking at an enemy player and then check if the distance is within a certain amount to that particular enemy player.

Thanks to answer, but I have another question, can I detect the taser's damage to player? as far as I know, the Taser has damage attenuation when player is out-of-range and I don't know how many damage attenuation per hammer units

[Xc_ace]

Originally Posted by Bacardi here is something... wierd content - When ever you hold taser, 1 sec timer will run repeatly. - Print in chat player count and names what are in range. - Some wierd angle check, look players front of you 80 degree wide area wher you aim or something like that. Spoiler PHP Code: #include <sdktools> #include <sdkhooks> #include <cstrike> Handle TimerCheckRange[MAXPLAYERS+1]; public void OnPluginStart() {     for(int i = 1; i <= MaxClients; i++)     {         if(IsClientInGame(i)) OnClientPutInServer(i);     } } public void OnClientPutInServer(int client) {     if(!IsFakeClient(client) && !IsClientReplay(client) && !IsClientSourceTV(client))     {         SDKHook(client, SDKHook_WeaponCanSwitchToPost, WeaponCanSwitchToPost);     } } public void WeaponCanSwitchToPost(int client, int weapon) {     //PrintToServer("WeaponCanSwitchToPost"); /*                 "range"        "190"                 "range modifier"        "0.004900" */     if(!HasEntProp(weapon, Prop_Send, "m_iItemDefinitionIndex"))         return;     CSWeaponID csweapon = CS_ItemDefIndexToID(GetEntProp(weapon, Prop_Send, "m_iItemDefinitionIndex"));          if(csweapon != CSWeapon_TASER)         return;     DataPack pack;     TimerCheckRange[client] = CreateDataTimer(1.0, checkrange, pack, TIMER_REPEAT);     pack.WriteCell(client);     pack.WriteCell(GetClientUserId(client));     // There are set in taser, items_game.txt     float m_flRange = 190.0;     float m_flRangeModifier = 0.004900;     pack.WriteFloat(m_flRange);     pack.WriteFloat(m_flRangeModifier); } public Action checkrange(Handle timer, DataPack pack) {     pack.Reset();     int index = pack.ReadCell();     int userid = pack.ReadCell();     if(TimerCheckRange[index] != timer)     {         return Plugin_Stop;     }     int client = GetClientOfUserId(userid);     if(!client || !IsClientInGame(client))     {         TimerCheckRange[index] = null;         return Plugin_Stop;     }     if(!HasEntProp(client, Prop_Send, "m_hActiveWeapon"))     {         TimerCheckRange[index] = null;         return Plugin_Stop;     }     int weapon = GetEntPropEnt(client, Prop_Send, "m_hActiveWeapon");     if(weapon < MaxClients)     {         TimerCheckRange[index] = null;         return Plugin_Stop;     }     CSWeaponID csweapon = CS_ItemDefIndexToID(GetEntProp(weapon, Prop_Send, "m_iItemDefinitionIndex"));     if(csweapon != CSWeapon_TASER)     {         TimerCheckRange[index] = null;         return Plugin_Stop;     }     float m_flRange = pack.ReadFloat();     float m_flRangeModifier = pack.ReadFloat();     float eyepos[3], eyeangl[3];     GetClientEyePosition(client, eyepos);     GetClientEyeAngles(client, eyeangl);     int[] targets = new int[MaxClients+1];     int count;     float enemypos[3], angle[3], distance, vector[3], fwd[3];     float maxangle = 40.0;     float angledistance;     for(int i = 1; i <= MaxClients; i++)     {         if(client == i || !IsClientInGame(i) || GetClientTeam(i) <= CS_TEAM_SPECTATOR || !IsPlayerAlive(i))             continue;         GetClientEyePosition(i, enemypos);                  MakeVectorFromPoints(eyepos, enemypos, vector);         distance = GetVectorLength(vector);         if(distance >= m_flRange)             continue;         GetVectorAngles(vector, angle);         // re-format player eye angle         GetAngleVectors(eyeangl, fwd, NULL_VECTOR, NULL_VECTOR);         GetVectorAngles(fwd, fwd);         // Angle rotate distance is 0 ... 360         // - problem began on close 0 point when calculate         // - rotate angle 90 degrees when we are close 0 point.         if(0.0 <= angle[1] <= 90.0 &&             270.0 <= fwd[1] <= 360.0 ||             0.0 <= fwd[1] <= 90.0 &&             270.0 <= angle[1] <= 360.0)         {             angle[1] -= 90.0;             fwd[1] -= 90.0;                          if(angle[1] < 0.0)                 angle[1] += 360.0;                          if(fwd[1] < 0.0)                 fwd[1] += 360.0;         }         //PrintToServer("\nangle %f", angle[1]);         //PrintToServer("fwd %f", fwd[1]);         //PrintToServer("angle[1] - fwd[1] %f", angle[1] > fwd[1] ? angle[1] - fwd[1]:fwd[1] - angle[1]);                  angledistance = angle[1] > fwd[1] ? angle[1] - fwd[1]:fwd[1] - angle[1];                  if(angledistance > maxangle)             continue;                           targets[count++] = i;              }     char msg[244];     Format(msg, sizeof(msg), "Taser! - You have %i enemies in close-range\n", count);          for(int x = 0; x < count; x++)     {         Format(msg, sizeof(msg), "%s, %N", msg, targets[x]);     }     PrintToChat(client, msg);     return Plugin_Continue; }

Thanks your code, it save my lots of time and realized the angles-detect feature, which I didn't think about.

[databomb]

Originally Posted by Xc_ace Thanks to answer, but I have another question, can I detect the taser's damage to player? as far as I know, the Taser has damage attenuation when player is out-of-range and I don't know how many damage attenuation per hammer units

Damage can be detected using the player_hurt event. See the details for CS:GO here:
https://wiki.alliedmods.net/Counter-...ts#player_hurt

If you need to modify the taser damage then use SDKHook_OnTakeDamage; for example, use that SDKHook if you want to remove the damage attentuation for the taser and cause it to kill anyone within range.