[Cader]

hi.

I have a surf server. I want to give pistols to players on spawn, if they don't have a primary/secondary weapon carried from previous round. or in other words, players only have died are going to get pistols (usp or glock)

here's what I have from my code snippet;

RegisterHam(Ham_Spawn, "player", "giveweap", 1)


public giveweap(id) {

if(is_user_alive(id) && !is_user_bot(id)) {
fm_strip_user_weapons(id)
fm_give_item(id, "weapon_knife")
if(cs_get_user_team(id) == CS_TEAM_CT) {
give_item(id, "weapon_usp")
give_item(id,"ammo_45acp")
give_item(id,"ammo_45acp")
give_item(id,"ammo_45acp")
give_item(id,"ammo_45acp")
give_item(id,"ammo_45acp")
give_item(id,"ammo_45acp")
give_item(id,"ammo_45acp")
give_item(id,"ammo_45acp")
give_item(id,"ammo_45acp")
}else{
give_item(id,"weapon_glock18")
give_item(id,"ammo_9mm")
give_item(id,"ammo_9mm")
give_item(id,"ammo_9mm")
give_item(id,"ammo_9mm")
give_item(id,"ammo_9mm")
give_item(id,"ammo_9mm")
give_item(id,"ammo_9mm")
}
}
}

[Shadows In Rain]

new bool:u_died[33]

...

public plugin_init()
{
    ...
    RegisterHam(Ham_Spawn, "player", "giveweap", 1)
    ...
    RegisterHam(Ham_Killed, "player", "fn_PlayerKilled_post", 1)
    ...
}
...
public fn_PlayerKilled_post(victim, attacker, shouldgib)
{
    u_died[victim] = true
}
...
public giveweap(id)
{
    if(is_user_alive(id) && !is_user_bot(id) && u_died[id])
    {
        u_died[id] = false
        
        fm_strip_user_weapons(id)
        fm_give_item(id, "weapon_knife")
        
        if(cs_get_user_team(id) == CS_TEAM_CT)
        {
            give_item(id, "weapon_usp")
            
            give_item(id,"ammo_45acp")
            give_item(id,"ammo_45acp")
            give_item(id,"ammo_45acp")
            give_item(id,"ammo_45acp")
            give_item(id,"ammo_45acp")
            give_item(id,"ammo_45acp")
            give_item(id,"ammo_45acp")
            give_item(id,"ammo_45acp")
            give_item(id,"ammo_45acp")
        }
        else
        if(cs_get_user_team(id) == CS_TEAM_T) // what if spawned as spectator / unassigned?
        {
            give_item(id,"weapon_glock18")
            
            give_item(id,"ammo_9mm")
            give_item(id,"ammo_9mm")
            give_item(id,"ammo_9mm")
            give_item(id,"ammo_9mm")
            give_item(id,"ammo_9mm")
            give_item(id,"ammo_9mm")
            give_item(id,"ammo_9mm")
        }
    }
}

[ConnorMcLeod]

Try this :

PHP Code:

/*    Formatright © 2010, ConnorMcLeod

    This plugin is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this plugin; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

#define VERSION "0.0.1"
#define PLUGIN ""

#define XO_PLAYER 5
#define m_bNotKilled 113
#define HasUserSurvivedLastRound(%0)    get_pdata_int(%0, m_bNotKilled, XO_PLAYER)

new g_bitConnecting
#define MarkUserConnecting(%0)    g_bitConnecting |= 1<<(%0&31)
#define ClearUserConnecting(%0)    g_bitConnecting &= ~(1<<(%0&31))
#define IsUserConnecting(%0)    ( g_bitConnecting & 1<<(%0&31) )

new HamHook:g_iHhPlayerSpawnPost, HamHook:g_iHhAddPlayerItemPre

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    RegisterHam(Ham_Spawn, "player", "CBasePlayer_Spawn_Pre")

    DisableHamForward( g_iHhPlayerSpawnPost = RegisterHam(Ham_Spawn, "player", "CBasePlayer_Spawn_Post", 1) )
    DisableHamForward( g_iHhAddPlayerItemPre = RegisterHam(Ham_AddPlayerItem, "player", "CBasePlayer_AddPlayerItem_Pre") )
}

public client_connect( id )
{
    MarkUserConnecting( id )
}

public client_putinserver( id )
{
    ClearUserConnecting( id )
}

public CBasePlayer_Spawn_Pre( id )
{
    if( !IsUserConnecting(id) && !HasUserSurvivedLastRound(id) )
    {
        EnableHamForward( g_iHhPlayerSpawnPost )
        EnableHamForward( g_iHhAddPlayerItemPre )
    }
}

public CBasePlayer_AddPlayerItem_Pre( id , iWeapon )
{
    return HAM_SUPERCEDE
}

public CBasePlayer_Spawn_Post( id )
{
    DisableHamForward( g_iHhPlayerSpawnPost )
    DisableHamForward( g_iHhAddPlayerItemPre )
    strip_user_weapons(id)
    give_item(id, "weapon_knife")
    switch( cs_get_user_team(id) )
    {
        case CS_TEAM_T:
        {
            give_item(id, "weapon_glock18")
            cs_set_user_bpammo(id, CSW_GLOCK18, 120)
        }
        case CS_TEAM_CT:
        {
            give_item(id, "weapon_usp")
            cs_set_user_bpammo(id, CSW_USP, 100)
        }
    }
}