[Drak]

Example:

new MyString[] = "My very long sentence"

If i wanted was was above, to be randomized, and to look like this:

new MyString[] = "My very long sentence"
// do something

// my string would look like this
MyString[] = "Mv sery logn uentecne"

How would I go about doing that?
Basically just messing up the text abit. I tried usng "replace()" but that just started duplicating stuff.

[fysiks]

copy/move single characters from the source string to random positions in destination string without getting the same 'random' position twice.

[Drak]

Originally Posted by fysiks copy/move single characters from the source string to random positions in destination string without getting the same 'random' position twice.

That's what I tried, I can't even get to the "copying" part.

	new Arg[64]
	read_args(Arg,63);
	
	server_print("Arg: %s",Arg);
	
	new NewArg[64]
	copy(Arg,63,Arg[6]);
	
	server_print("Arg: %s",NewArg);

I'm not sure how to 'select' a single char.

[Exolent[jNr]]

	new NewArg[64]
	copy(Arg,63,Arg[6]);

NewArg is never used.

[fysiks]

Originally Posted by Drak That's what I tried, I can't even get to the "copying" part. I'm not sure how to 'select' a single char.

Just do direct character assignment (integer).

after[random_position_here] = before[i]

[Exolent[jNr]]

stock RandomizeString(const string[], output[], const output_len)
{
    new string_len = strlen(string);
    
    new Array:is_char = ArrayCreate(1);
    new Array:chars = ArrayCreate(1);
    new char_size;
    
    for(new i = 0; i < string_len; i++)
    {
        if(isalpha(string[i] || isdigit(string[i]))
        {
            ArrayPushCell(chars, i);
            ArrayPushCell(is_char, 1);
            char_size++;
        }
        else
        {
            ArrayPushCell(is_char, 0);
        }
    }
    
    new string_pos, output_pos, c, rand;
    while(string_pos < string_len && output_pos < output_len)
    {
        if(ArrayGetCell(is_char, string_pos))
        {
            rand = random(char_size--);
            c = ArrayGetCell(chars, rand);
            ArrayDeleteItem(chars, rand);
        }
        else
        {
            c = string[string_pos];
        }
        
        output[output_pos++] = c;
        string_pos++;
    }
    
    ArrayDestroy(is_char);
    ArrayDestroy(chars);
    
    output[output_pos] = EOS;
    
    return output_pos;
}

[fysiks]

Wow, that looks complicated. I modified one of your non-repeating random functions:

PHP Code:

#include <amxmodx>

public plugin_init()
{
    register_concmd("str", "cmdScramble")
}

public cmdScramble()
{
    new szString[32]
    read_argv(1, szString, charsmax(szString))
    
    new szOutput[32]
    StringScramble(szString, szOutput, charsmax(szOutput))
    
    server_print("Before: %s", szString)
    server_print("After : %s", szOutput)
}

stock StringScramble( input[], output[], output_len ) 
{ 
    new Array:aNumbers = ArrayCreate( 1 ); 
    new input_len = strlen(input); 
     
    for( new i = 0; i < input_len; i++ ) 
    { 
       ArrayPushCell( aNumbers, i ); 
    } 
     
    new iLastIndex = min( input_len, output_len ); 
    new iRand; 
    for( new i = 0; i < iLastIndex; i++ ) 
    { 
        iRand = random( input_len ); 
         
        output[i] = input[ArrayGetCell( aNumbers, iRand )]; 
        ArrayDeleteItem( aNumbers, iRand ); 
         
        input_len--; 
    } 
     
    ArrayDestroy( aNumbers ); 
     
    return iLastIndex; 
} 


[Exolent[jNr]]

Mine keeps the structure of the string by only replacing letters and numbers.
Yours will randomize all characters.

[Drak]

Awesome. Thanks guy's.

[fysiks]

Originally Posted by Exolent[jNr] Mine keeps the structure of the string by only replacing letters and numbers. Yours will randomize all characters.

Oh I see. I didn't think of that since he didn't explicitly say that he wanted that .