[Weasel]

Anybody have or care to throw-together an plug-in such as this?
It is a pretty simple idea, for monitoring/diagnostic purposes.

• Start a new log file every map load.
• Once a minute, log every players latency to a log file.
• Each log entry/line should be time-stamped of course.

Maybe a tab-separated format somewhat like this in the log file:

yyyy-mm-dd-hh:mm:ss <tab> Player-SteamID <tab> Latency <tab> Player-Name

[Bacardi]

This log files into

...logs/YYYY-MM-DD-MMSS_mapname.log

2024-01-12-20:35:39	[U:1:28327177]	30	'Bacardi

This now create new empty line, after checking all human players in game.
You can remove that line if you don't like it.

Latency is ms, and this ping follows like "status" or "ping" command.
- Scoreboard ping again work differently

PHP Code:






File logfile;

public void OnMapStart()
{
    if(logfile != null)
    {
        logfile.Flush();
        delete logfile;
    }

    if(!DirExists("logs") && !CreateDirectory("logs", 0x1ED))    //0x1C0 = 700, 0x1E8 = 750, 0x1ED = 755
    {
        SetFailState("Plugin failed to create directory /logs");
    }



    char map[PLATFORM_MAX_PATH];
    char path[PLATFORM_MAX_PATH];

    GetCurrentMap(map, sizeof(map));
    FormatTime(path, sizeof(path), "%F-%H%M_");
    Format(path, sizeof(path), "logs/%s%s.log", path, map);

    logfile = OpenFile(path, "a");
    
    if(logfile == null)
        SetFailState("Plugin failed to create or open file %s", path);

    CreateTimer(60.0, checkPing, logfile, TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT);
}

public Action checkPing(Handle timer, File log)
{
    if(log == null)
        return Plugin_Stop;

    if(log != logfile)
    {
        log.Flush();
        delete log;
        return Plugin_Stop;
    }



    char buffer[MAX_NAME_LENGTH];
    //FormatTime(buffer, sizeof(buffer), "%FT%T%z"); // ISO 8601
    FormatTime(buffer, sizeof(buffer), "%F-%T");

    char auth[PLATFORM_MAX_PATH];
    bool DoFlush = false;

    for(int i = 1; i <= MaxClients; i++)
    {
        if(!IsClientInGame(i) || IsFakeClient(i)) continue;

        auth[0] = '\0';

        GetClientAuthId(i, AuthId_Engine, auth, sizeof(auth));
        //PrintToServer("%s    %s    %0.0f    %N",buffer, auth, GetClientAvgLatency(i, NetFlow_Outgoing) * 1000.0, i);
        Format(auth, sizeof(auth), "%s    %s    %0.0f    %N",buffer, auth, GetClientAvgLatency(i, NetFlow_Outgoing) * 1000.0, i);
        
        if(!log.WriteLine(auth))
            LogError("Plugin WriteLine failed");

        DoFlush = true;
    }

    if(DoFlush)
    {
        log.WriteLine("\n"); // extra new line
        log.Flush();
    }

    return Plugin_Continue;
} 


[Weasel]

Thanks! Will check it out!

[Weasel]

Thanks. Made a plugin based on that. Compiled it. Tested it. Working as expected. Exactly what I needed for troubleshooting / monitoring.

I have a compiled version available for anyone who wants ...

Compiled Plugin:
logpings.smx

Source Code:
logpings.sp

Spoiler

//
//	Periodic Ping-Loggger
//	---------------------
//
//	Purpose:
//		Logs player latency/ping to a file periodically for
//		diagnostic / troubleshooting purposes.
//
//	Based on this code:
//		https://forums.alliedmods.net/showthread.php?t=345369
//
//	Created by "Bicardi"
//		https://forums.alliedmods.net/member.php?u=67162
//
//	Created for "Weasel"
//		https://forums.alliedmods.net/member.php?u=511
//		http://steamcommunity.com/profiles/76561197960266039
//
//	Version History:
//	---------------
//
//	20240121a	v1.0.0	Initial version.
//	20240121b	v1.0.1	Disabled extra line after each dump to file.
//	20240121c	v1.0.2	Cleanded-up source-code formatting (tabs instead of multiple spaces).
//	20240121c	v1.0.3	Switched to logfile delimiter being TAB character (ASCI 9) insted of multiple spaces.
//

public Plugin:myinfo = {
	name = "Periodic Ping-Loggger",
	author = "Bicardi",
	description = "Logs player latency/ping to a file periodically",
	version = "1.0.3",
	url = "https://forums.alliedmods.net/showthread.php?t=345369"
};

File logfile;

public void OnMapStart()
{
	if(logfile != null)
	{
		logfile.Flush();
		delete logfile;
	}

	if(!DirExists("logs") && !CreateDirectory("logs", 0x1ED))	//0x1C0 = 700, 0x1E8 = 750, 0x1ED = 755
	{
		SetFailState("Plugin failed to create directory /logs");
	}

	char map[PLATFORM_MAX_PATH];
	char path[PLATFORM_MAX_PATH];

	GetCurrentMap(map, sizeof(map));
	FormatTime(path, sizeof(path), "%F-%H%M_");
	Format(path, sizeof(path), "logs/%s%s.log", path, map);

	logfile = OpenFile(path, "a");
	
	if(logfile == null)
		SetFailState("Plugin failed to create or open file %s", path);

	CreateTimer(60.0, checkPing, logfile, TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT);
}

public Action checkPing(Handle timer, File log)
{
	if(log == null)
		return Plugin_Stop;

	if(log != logfile)
	{
		log.Flush();
		delete log;
		return Plugin_Stop;
	}

	char buffer[MAX_NAME_LENGTH];
	//FormatTime(buffer, sizeof(buffer), "%FT%T%z"); // ISO 8601
	FormatTime(buffer, sizeof(buffer), "%F-%T");

	char auth[PLATFORM_MAX_PATH];
	bool DoFlush = false;

	for(int i = 1; i <= MaxClients; i++)
	{
		if(!IsClientInGame(i) || IsFakeClient(i)) continue;

		auth[0] = '\0';

		GetClientAuthId(i, AuthId_Engine, auth, sizeof(auth));
		//PrintToServer("%s	%s	%0.0f	%N",buffer, auth, GetClientAvgLatency(i, NetFlow_Outgoing) * 1000.0, i);

		//	Original log format with multiple spaces between columns ...
		//
		//	Format(auth, sizeof(auth), "%s	%s	%0.0f	%N",buffer, auth, GetClientAvgLatency(i, NetFlow_Outgoing) * 1000.0, i);

		//	Replaced log format, with TAB delimiter between columns ...
		//
		Format(auth, sizeof(auth), "%s\t%s\t%0.0f\t%N",buffer, auth, GetClientAvgLatency(i, NetFlow_Outgoing) * 1000.0, i);

		if(!log.WriteLine(auth))
			LogError("Plugin WriteLine failed");

		DoFlush = true;
	}

	if(DoFlush)
	{
		//	log.WriteLine("\n"); // extra new line - commented out by Weasel as a preference (to not log extra line).
		log.Flush();
	}

	return Plugin_Continue;
}

.