[[Black_Jack]]

Hi. I try to write plugin, but have a question. How can I chec for idividual steamid. Try to explain: If Steam_0:1:123456 is connectig, then exec function.


Tried to do this, but this didnt work =(

PHP Code:

public client_authorized(id)
{
    get_user_authid(id, SID)
    if(contain("STEAM:0:1:123456", SID) set_task(0.1, function, id)
} 


And i forgot the function which exec your public function, instead of set_task. Lol
I'm new to scripting

[xPaw]

public client_authorized( id ) {
    new szAuthId[ 40 ];
    get_user_authid( id, szAuthId, 39 );
    
    if( equal( szAuthId, "blah" ) )
        YourFunction( id );
}

[Dr.G]

yeah well id recommand to trim strings, atleast if you are using a WIN server.

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "New Plug-In"
#define VERSION "1.0 by Dr.G"
#define AUTHOR "AMXX DoD Team"

new const STEAM_ID[] = "STEAM:0:1:123456"

new p_on

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    p_on = register_cvar("amx_something", "1")
}
public client_authorized(id)
{
    if(is_user_bot(id) || is_user_hltv(id) || !get_pcvar_num(p_on))
        return PLUGIN_CONTINUE
    
    new iSteamStr[32]
    
    get_user_authid(id, iSteamStr, sizeof(iSteamStr) - 1)
    trim(iSteamStr)
    
    if(equal(STEAM_ID, iSteamStr))
    {
        server_print("User with %s has connected", iSteamStr)
        doStuff(id)
    }
    
    return PLUGIN_CONTINUE
}
doStuff(id) {
    
    /* Warning: Symbol is never used: "id"... yea yea...*/
    server_print("..doStuff")
    return PLUGIN_CONTINUE
} 


[[Black_Jack]]

Thanks very much ^^

[[Black_Jack]]

Hm, And another question. How to add few steamids in 1 const?
MB Like this?

PHP Code:

new const SIDs = {
"111",
"1111",
..
..
..
"22222"} 


Will this works with my code?

[Bugsy]

Originally Posted by [Black_Jack] Hm, And another question. How to add few steamids in 1 const? MB Like this? ... Will this works with my code?

PHP Code:

//Add as many as you want
new const CheckSteamID[][] = 
{ 
    "STEAM_12345" ,
    "STEAM_67890" ,
    "STEAM_10101" ,
    "STEAM_01010" 
};

public client_authorized( id )
{
    new szSteamID[ 35 ];
    get_user_authid( id , szSteamID , charsmax( szSteamID ) );
    
    for ( new i = 0 ; i < sizeof( CheckSteamID ) ; i++ )
    {
        if ( equal( szSteamID , CheckSteamID[ i ] ) )
        {
            // Player has connected, take action on player.
            // Some functions that you call here may need
            // a delay depending on what it does. If this is 
            // the case, use set_task( 3.0 , "DelayFunc" , id )
            // and place your code in DelayFunc (see below).
        
            //set_user_money( id );
        }
    }
}

public DelayFunc( id )
{
    // This will be called 3 seconds (or whatever delay is specific in set_task) 
    // after client_authorized()

    //set_user_money( id );
} 


[Dr.G]

I would use a Trie

->

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
////////////////////////////////////////////////////////////////////////////////////////////////////
#define PLUGIN "New Plug-In"
#define VERSION "1.0 by Dr.G"
#define AUTHOR "AMXX DoD Team"
////////////////////////////////////////////////////////////////////////////////////////////////////
new const STEAM_IDs[][] = { 
    
    "STEAM:0:1:123456", 
    "STEAM:0:1:1234567", 
    "STEAM:0:1:12345678", 
    "STEAM:0:1:123456789"
}

new p_on
new Trie:SteamList
////////////////////////////////////////////////////////////////////////////////////////////////////
public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    p_on = register_cvar("amx_something", "1")
    
    SteamList = TrieCreate()
    
    for(new i ; i < sizeof STEAM_IDs ; i++)
        TrieSetCell(SteamList, STEAM_IDs[i], 1)
    
}
////////////////////////////////////////////////////////////////////////////////////////////////////
public client_authorized(id)
{
    if(is_user_bot(id) || is_user_hltv(id) || !get_pcvar_num(p_on))
        return PLUGIN_CONTINUE
    
    new iSteamStr[32]
    
    get_user_authid(id, iSteamStr, sizeof(iSteamStr) - 1)
    trim(iSteamStr)
    
    if(TrieKeyExists(SteamList, iSteamStr))
    {
        server_print("User with %s has connected", iSteamStr)
        doStuff(id)
    }
    
    return PLUGIN_CONTINUE
}
////////////////////////////////////////////////////////////////////////////////////////////////////
doStuff(id) {
    
    /* Warning: Symbol is never used: "id"... */
    server_print("..doStuff")
    return PLUGIN_CONTINUE
}
////////////////////////////////////////////////////////////////////////////////////////////////////
public plugin_end()
{
    TrieDestroy(SteamList)
}
//////////////////////////////////////////////////////////////////////////////////////////////////// 


[Bugsy]

Perhaps if data was being read from a file where the list could grow large. I dont see a point in using trie for such a short list. If he decides to read from file, there is an example I recently wrote that reads entries from file and stores in trie

http://forums.alliedmods.net/showpos...7&postcount=13

http://forums.alliedmods.net/showpos...0&postcount=27

[[Black_Jack]]

Hmmm... Not compiling with Bugsy's code .

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "Black_Jack"


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    new const SteamIDs[][] = 
    {
        "STEAM_0:1:234567",
        "STEAM_0:2:234255",
        "STEAM_0:1:342356"
    }
}

public client_authorized(id)
{
    new temp[35]
    get_user_authid(id, temp, sizeof(temp))
    for(new i; i < sizeof(SteamIDs); i++)
    {
        if(equal(temp, SteamIDs[i]))
        {
            server_print("123123123")
        }
    }
} 


PHP Code:

Welcome to the AMX Mod X 1.8.1-300 Compiler.
Copyright (c) 1997-2006 ITB CompuPhase, AMX Mod X Team

Warning: Symbol is assigned a value that is never used: "SteamIDs" on line 19
Error: Undefined symbol "SteamIDs" on line 25
Error: Empty statement on line 25
Error: Undefined symbol "i" on line 25
Error: Too many error messages on one line on line 25

Compilation aborted.
4 Errors.
Could not locate output file C:\Server\Clear\cstrike\addons\amxmodx\plugins\Untitled.amx (compile failed). 


[Exolent[jNr]]

You have to make SteamIDs a global variable.