[eyal282]

When you have 100 perma HP and 0 temp HP and hang onto a ledge and get revived on 1 hanging HP, you will not have 100 perma HP, you will get up injured. What calculates this? What's the formula?

I need to know because the method to ignore the 200 max temporary HP is extremely fragile and is wiped with a single ledge hang.

[alasfourom]

AFAIK, u suppose to lose 1 health per sec when u r ledge hanging

I don't know if there is a native to adjust the post hanged health

but you could store client pre health before ledge hanging and then restore it after being revived

something like this

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <left4dhooks>

int g_iPermHealth_Pre[MAXPLAYERS+1];
int g_iTempHealth_Pre[MAXPLAYERS+1];

int g_iPermHealth_Post[MAXPLAYERS+1];
int g_iTempHealth_Post[MAXPLAYERS+1];

public void OnPluginStart()
{
    HookEvent("revive_success", Event_ReviveSuccess, EventHookMode_Post);
}

public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float vel[3], float angles[3], int &weapon)
{
    if (!client || !IsClientInGame(client) || GetClientTeam(client) != 2 || !IsPlayerAlive(client) || GetEntProp(client, Prop_Send, "m_isHangingFromLedge") == 0) return Plugin_Handled;
    
    g_iPermHealth_Pre[client] = GetClientHealth(client);
    g_iTempHealth_Pre[client] = RoundToFloor(L4D_GetTempHealth(client));
    return Plugin_Continue;
}

void Event_ReviveSuccess(Event event, const char[] name, bool dontBroadcast)
{
    if (!event.GetBool("ledge_hang")) return;
    
    int client = GetClientOfUserId (event.GetInt("subject"));
    if (!client || !IsClientInGame(client)) return;
    
    g_iPermHealth_Post[client] = g_iPermHealth_Pre[client];
    g_iTempHealth_Post[client] = g_iTempHealth_Pre[client];
    
    CreateTimer(0.1, Timer_RestoreClientHealth, GetClientUserId(client), TIMER_FLAG_NO_MAPCHANGE);
}

Action Timer_RestoreClientHealth(Handle timer, int userid)
{
    int client = GetClientOfUserId(userid);
    if(client == 0 || !IsClientInGame(client)) return Plugin_Stop;
    
    SetEntProp(client, Prop_Send, "m_iHealth", g_iPermHealth_Post[client], 1);
    L4D_SetTempHealth(client, float(g_iTempHealth_Post[client]));
    return Plugin_Handled;
} 


[Silvers]

Originally Posted by alasfourom something like this

PHP Code:

// Gets the health of the survivor from before they were incapacitated
native int L4D2Direct_GetPreIncapHealth(int client);

// Gets the temporary health of the survivor from before they were incapacitated
native int L4D2Direct_GetPreIncapHealthBuffer(int client); 


[alasfourom]

Originally Posted by Silvers PHP Code: // Gets the health of the survivor from before they were incapacitated native int L4D2Direct_GetPreIncapHealth(int client); // Gets the temporary health of the survivor from before they were incapacitated native int L4D2Direct_GetPreIncapHealthBuffer(int client);

Ahh, you are right, didn't check that, this should make it a lot easier now

[sorallll]

PHP Code:

int health, tempHealth, bufferTime;
if (GetEntProp(client, Prop_Send, "m_isIncapacitated")) {
    if (!GetEntProp(client, Prop_Send, "m_isHangingFromLedge")) {
        static ConVar cSurvivorReviveH;
        if (!cSurvivorReviveH)
            cSurvivorReviveH = FindConVar("survivor_revive_health");

        health = 1;
        tempHealth = cSurvivorReviveH.IntValue;
    }
    else {
        static ConVar cSurvivorIncapH;
        if (!cSurvivorIncapH)
            cSurvivorIncapH = FindConVar("survivor_incap_health");

        int m_preHangingHealth = L4D2Direct_GetPreIncapHealth(client);                                                                        // 玩家挂边前的实血
        int m_preHangingHealthBuffer = L4D2Direct_GetPreIncapHealthBuffer(client);                                                            // 玩家挂边前的虚血
        int preTotalHealth = m_preHangingHealth + m_preHangingHealthBuffer;                                                                    // 玩家挂边前的总血量
        int revivedTotalHealth = RoundToFloor(GetEntProp(client, Prop_Data, "m_iHealth") / cSurvivorIncapH.FloatValue * preTotalHealth);    // 玩家挂边起身后的总血量

        int deltaHealth = preTotalHealth - revivedTotalHealth;
        if (m_preHangingHealthBuffer > deltaHealth) {
            health = m_preHangingHealth;
            tempHealth = m_preHangingHealthBuffer - deltaHealth;
        }
        else {
            health = m_preHangingHealth - (deltaHealth - m_preHangingHealthBuffer);
            tempHealth = 0;
        }
    }
    bufferTime = 0;
}
else {
    health = GetEntProp(client, Prop_Data, "m_iHealth");
    tempHealth = RoundToNearest(GetEntPropFloat(client, Prop_Send, "m_healthBuffer"));
    bufferTime = RoundToNearest(GetGameTime() - GetEntPropFloat(client, Prop_Send, "m_healthBufferTime"));
} 


what you need is this

PHP Code:

int health, tempHealth;
static ConVar cSurvivorIncapH;
if (!cSurvivorIncapH)
    cSurvivorIncapH = FindConVar("survivor_incap_health");

int m_preHangingHealth = L4D2Direct_GetPreIncapHealth(client);                                                                        // 玩家挂边前的实血
int m_preHangingHealthBuffer = L4D2Direct_GetPreIncapHealthBuffer(client);                                                            // 玩家挂边前的虚血
int preTotalHealth = m_preHangingHealth + m_preHangingHealthBuffer;                                                                    // 玩家挂边前的总血量
int revivedTotalHealth = RoundToFloor(GetEntProp(client, Prop_Data, "m_iHealth") / cSurvivorIncapH.FloatValue * preTotalHealth);    // 玩家挂边起身后的总血量

int deltaHealth = preTotalHealth - revivedTotalHealth;
if (m_preHangingHealthBuffer > deltaHealth) {
    health = m_preHangingHealth;
    tempHealth = m_preHangingHealthBuffer - deltaHealth;
}
else {
    health = m_preHangingHealth - (deltaHealth - m_preHangingHealthBuffer);
    tempHealth = 0;
}