Quote:
|
but my opinion is still that the logic of the enumeration in this situation is strangely limited.
|
Quote:
|
to mimic some functionality
|
Anyway, the logic is simple ; if you use the enum as a structure you have to follow the usage of a structure. There is no bug, it's the way of the Pawn.
Simple tagged enum :
Code:
enum Weather
{
SNOW,
RAIN,
};
new Weather:CurrentWeather = SNOW;
Simple no tagged enum ( same as defines )
Code:
enum
{
SNOW,
RAIN,
};
new CurrentWeather = SNOW;
Simple tagged structure
Code:
enum Rectangle
{
Left,
Top,
Right,
Bottom
};
new MyRec[ Rectangle ];
new Value = MyRec[ Left ] = 10;
new Rectangle:Side = Bottom;
Code:
enum Coordinate
{
Float:X, Float:Y, Float:Z
}
new Float:coordinates[ Coordinate ];
new Float:value = coordinates[X] = 1.0;
new Coordinate:Value2 = Z;
Simple no tagged structure ( bad idea )
Code:
enum
{
Left,
Top,
Right,
Bottom
};
new MyRec[ 4 ];
new Value = MyRec[ Left ] = 10;
new Side = Bottom;
Code:
enum
{
Float:X, Float:Y, Float:Z
}
new Float:coordinates[ 3 ];
new Float:value = coordinates[X] = 1.0;
new Value2 = Z;
Complex tagged structures ( without tag, no change. )
Code:
enum Color
{
Red,
Green,
Blue
}
enum Mood
{
HAPPY,
ANNOYED,
}
enum PlayerData
{
Float:RunTime,
bool:IsConnected,
KillCount,
GlowColor[ Color ],
Mood:CurrentMood,
PlayerName[ 32 ],
}
new Data[ PlayerData ];
new Float:Value1 = Data[ RunTime ] = _:150.854;
new bool:Value2 = Data[ IsConnected ] = true;
new Value3 = Data[ KillCount ] = 666;
new Value4 = Data[ GlowColor ][ Red ] = 255;
new Mood:Value5 = Data[ CurrentMood ] = _:ANNOYED;
copy( Data[ PlayerName ], 31, "Arkshine" );
Even me I understand and I don't see bug, nor difficulty. Such "incredible hacked enum" ( (c) BAILOPAN ) works fine as it is.
Quote:
|
Arkshine, this code works graet, I wanna use the structure property of the enum in my plugin but I'm not sure on the "_:" thingy, like when should I use it & exactly what does it do.
|
_: means you set a "no tag" ; basically you untag the variable.
If you have a structure which have strong tags ( A strong tag starts with an uppercase letter ) and you need to set a value in such constants, you would need to untag them before. A weak tag is dropped automatically in such case, that's why like bool you don't need to untag before.
See my example above :
new Mood:Value5 = Data[ CurrentMood ] = _:ANNOYED; If I was written "mood" instead of "Mood", it would be a weak tag and I would write :
new mood:Value5 = Data[ CurrentMood ] = ANNOYED;
You understand ?
__________________
It's clear now, but there's one more case:
Linear Mode
