[alasfourom]

Hello everyone,

I want to know 2 things,

Lets take this script as an example which show you how many kills players got "Frags".

PHP Code:

int KillCount [MAXPLAYERS+1];


public void OnPluginStart() 
{
    HookEvent("round_start", Event_RoundStart);
    HookEvent("player_death", EVENT_PlayerDeath);
}

public void Event_RoundStart(Event event, const char[] name, bool dontBroadcast)
{
    for (int i = 1; i <= MaxClients; i++)
        if (IsClientInGame(i)) KillCount[i] = 0;
}

public void EVENT_PlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int victim = GetClientOfUserId(event.GetInt("userid"));
    if (!victim || !IsClientInGame(victim)) return;
    
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    if (!attacker || !IsClientInGame(attacker)) return;
    
    if(attacker != victim)
    {
        KillCount[attacker]++;
        
        if (KillCount[attacker] > 0) PrintHintText(attacker, "Kills: %d", KillCount[attacker]);
    }
} 


- The first thing I would like to know, is how print in the end of the round everyone's kill like:
mario kills: 15, sonic kills: 10, dragon kills: 8, noob kills: 5


- The second thing is how to show in the end of the round only the highest killer, like:
mario kills: 15 > thats all


Thank you

[Marttt]

You have to sort.

Example (not same scenario)

Spoiler

may have some errors since was copy paste from a snippet

PHP Code:

public void GetQueue()
{
    int specs[MAXPLAYERS+1][2];

    for (int client = 1; client <= MaxClients; client++)
    {
        specs[client][0] = client;

        if (!IsClientInGame(client))
            continue;

        if (IsFakeClient(client))
            continue;

        if (GetClientTeam(client) != 1)
            continue;

        specs[client][1] = RoundFloat(GetClientTime(client));
    }

    SortCustom2D(specs, sizeof(specs), CustomCompare);

    char buffer[250];

    for (int i = 0; i < MaxClients; i++)
    {
        if (specs[i][1] == 0)
            continue;

        if (!IsClientInGame(specs[i][0]))
            continue;

        if (buffer[0] == 0)
            FormatEx(buffer, sizeof(buffer), "%N", specs[i][0]);
        else
            Format(buffer, sizeof(buffer), "%s, %N", buffer, specs[i][0]);
    }

    PrintToChatAll(buffer);
}

public int CustomCompare(int[] elem1, int[] elem2, const int[][] array, Handle hndl)
{
    if (elem2[1] == 0)
        return -1;

    if (elem1[1] > elem2[1])
        return -1;

    if (elem1[1] < elem2[1])
        return 1;

    return 0;
} 


Probably has other ways to do it, is an old code I did a long time ago to sort specs

[HarryPotter]

https://github.com/fbef0102/L4D1_2-P...e/master/kills

[alasfourom]

Both are not easy to do,

I will try it in the weekend thanks Marttt and Harry

[moschinovac]

Originally Posted by alasfourom I was able to make it to work but I wanna know one more thing, how to print only the highest player with kills for example instead of printing everyone with his kills

I assume u use Harry Potter’s plugins. In line 141, just only Print the first value satisfy condition of j then break the Loop, no need to print full the Loop

[Marttt]

Sort Descending -> First

[alasfourom]

Thanks, seems working fine now

[alasfourom]

Its working fine, but I'm not sure is this the right method, and if there is for example 0 kills, how to make it display "None"

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

#define PLUGIN_VERSION "1.0"

bool  g_bRoundEnd;

int SI_KillCount     [MAXPLAYERS+1];
int Boss_KillCount [MAXPLAYERS+1];

public void OnPluginStart() 
{
    HookEvent("round_start", Event_RoundStart);
    HookEvent("round_end", Event_RoundEnd);
    HookEvent("player_death", EVENT_OnSpecialDeath);
    HookEvent("tank_killed", EVENT_OnTankDeath);
    HookEvent("witch_killed", EVENT_OnWitchDeath);
}

/* =============================================================================================================== *
 *                                                   Round Start                                                   *
 *================================================================================================================ */

public void Event_RoundStart(Event event, const char[] name, bool dontBroadcast)
{
    g_bRoundEnd = false;
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            SI_KillCount     [i] = 0;
            Boss_KillCount    [i] = 0;
        }
    }
}

/* =============================================================================================================== *
 *                                                   MVP: SI Kills                                                 *
 *================================================================================================================ */

public void EVENT_OnSpecialDeath(Event event, const char[] name, bool dontBroadcast)
{
    int victim = GetClientOfUserId(event.GetInt("userid"));
    if (!victim || !IsClientInGame(victim) || IsTank(victim)) return;
    
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    if (!attacker || !IsClientInGame(attacker)) return;
    
    if(attacker != victim && GetClientTeam(attacker) == 2)
    {
        SI_KillCount[attacker]++;
        
        if (SI_KillCount[attacker] > 0) PrintHintText(attacker, "Special Kills: %d", SI_KillCount[attacker]);
    }
}

/* =============================================================================================================== *
 *                                                   MVP: Boss Kills                                               *
 *================================================================================================================ */

public void EVENT_OnWitchDeath(Event event, const char[] name, bool dontBroadcast)
{
    int attacker = GetClientOfUserId(event.GetInt("userid"));
    if (!attacker || !IsClientInGame(attacker)) return;
    
    if(GetClientTeam(attacker) == 2)
    {
        Boss_KillCount[attacker]++;
        if (Boss_KillCount[attacker] > 0) PrintHintText(attacker, "Boss Kills: %d", Boss_KillCount[attacker]);
    }
}

public void EVENT_OnTankDeath(Event event, const char[] name, bool dontBroadcast)
{
    int tank = GetClientOfUserId(event.GetInt("userid"));
    if (!tank || !IsClientInGame(tank)) return;
    
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    if (!attacker || !IsClientInGame(attacker)) return;
    
    if(attacker != tank && GetClientTeam(attacker) == 2)
    {
        Boss_KillCount[attacker]++;
        if (Boss_KillCount[attacker] > 0) PrintHintText(attacker, "Boss Kills: %d", Boss_KillCount[attacker]);
    }
}

/* =============================================================================================================== *
 *                                                       Round End                                                 *
 *================================================================================================================ */

public Action Event_RoundEnd(Event event, const char[] name, bool dontBroadcast)
{
    if(!g_bRoundEnd) 
    {
        MVP_Display(); //Display Players With MVP
        g_bRoundEnd = true;
    }
    return Plugin_Handled;
}

/* =============================================================================================================== *
 *                                                       MVP Display                                               *
 *================================================================================================================ */

void MVP_Display()
{
    int client;
    int players = 0;
    
    int[] players_clients = new int[MaxClients+1];
    
    int SI_KillCount_MVP, Boss_KillCount_MVP;
    
    for (client = 1; client <= MaxClients; client++)
    {
        if (!IsClientInGame(client) || GetClientTeam(client) == 3) continue;
        players_clients[players] = client;
        players++;
    }
    
    SortCustom1D(players_clients, players, SortDescending);
    {
        client = players_clients [0];
        SI_KillCount_MVP = SI_KillCount [client];
        PrintToChatAll("MVP SI Kills: %N (%d)", client, SI_KillCount_MVP);
    }
    
    SortCustom1D(players_clients, players, SortDescending);
    {
        client = players_clients    [0];
        Boss_KillCount_MVP = Boss_KillCount [client];
        PrintToChatAll("MVP Boss Kills: %N (%d)", client, Boss_KillCount_MVP);
    }
}

public int SortDescending(int elem1, int elem2, const int[] array, Handle hndl)
{
    if (SI_KillCount[elem1] > SI_KillCount[elem2]) return -1;
    else if (Boss_KillCount[elem1] > Boss_KillCount[elem2]) return -1;
    else if (SI_KillCount[elem2] > SI_KillCount[elem1]) return 1;
    else if (Boss_KillCount[elem2] > Boss_KillCount[elem1]) return 1;
    else if (elem1 > elem2) return -1;
    else if (elem2 > elem1) return 1;
    return 0;
}

/* =============================================================================================================== *
 *                                                       Check Tank                                                 *
 *================================================================================================================ */

stock bool IsTank(int client)
{
    return (client > 0 
        && client <= MaxClients 
        && IsClientInGame(client) 
        && GetClientTeam(client) == 3 
        && GetEntProp(client, Prop_Send, "m_zombieClass") == 8);
} 


[Grey83]

Originally Posted by alasfourom if there is for example 0 kills, how to make it display "None"

PHP Code:

PrintToChatAll("MVP SI Kills: %N (%d)", client, SI_KillCount_MVP); 


==>

PHP Code:

if(SI_KillCount_MVP > 0) PrintToChatAll("MVP SI Kills: %N (%d)", client, SI_KillCount_MVP);
else PrintToChatAll("MVP SI Kills: %N (None)", client); 


[Bacardi]

...tips

public void Event_RoundStart(Event event, const char[] name, bool dontBroadcast)
{
    g_bRoundEnd = false;
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            SI_KillCount     [i] = 0;
            Boss_KillCount    [i] = 0;
        }
    }
}

Why not reset whole array, either client is in game or not.

    for (client = 1; client <= MaxClients; client++)
    {
        if (!IsClientInGame(client) || GetClientTeam(client) == 3) continue;
        players_clients[players] = client;
        players++;
    }

... I don't remember L4D teams, but now you exlude clients from that team only. What about spectators ?
Should it be GetClientTeam(client) != 2, if any another team than index 2



This look nonsense, what happened here ?

    
    SortCustom1D(players_clients, players, SortDescending);
    {
        client = players_clients [0];
        SI_KillCount_MVP = SI_KillCount [client];
        PrintToChatAll("MVP SI Kills: %N (%d)", client, SI_KillCount_MVP);
    }
    
    SortCustom1D(players_clients, players, SortDescending);
    {
        client = players_clients    [0];
        Boss_KillCount_MVP = Boss_KillCount [client];
        PrintToChatAll("MVP Boss Kills: %N (%d)", client, Boss_KillCount_MVP);
    }
}