[Guppy488]

hi,can anyone tell me how to set hud message Bottom Left Of Screen that last a Whole Round,and won't be Covered by Anything Else.

and has a command attached to it,example: amx_hudmessage <your message> and Default Color can be set in .sma or using cvars?

[Bugsy]

Please use descriptive topic titles. I recommend you change it to something related to your problem so future users can benefit from your same problem and solution.

I can't promise it won't conflict with HUDs from other plugins.

Usage: amx_hudmessage "Your message here"

Always use quotes to be safe.

PHP Code:

#include <amxmodx>
#include <amxmisc>

const TaskHUD = 13579;

new const RGBColor[] = 
{
    0,
    212, 
    255
}

new const Float:HUDPos[] = 
{
    0.05,
    0.85
}

new g_szHUDMsg[ 128 ];
new g_SyncHUD;

public plugin_init() 
{
    register_concmd( "amx_hudmessage" , "cmd_SetHUD" , ADMIN_KICK , "Set Round HUD Msg" ); 

    register_logevent( "fw_RoundEnd" , 2 , "1=Round_End" );
    
    g_SyncHUD = CreateHudSyncObj();
}

public fw_RoundEnd()
{
    remove_task( TaskHUD );
}

public cmd_SetHUD( id , level , cid )
{
    if ( cmd_access( id , level , cid , 1 ) )
    {
        read_argv( 1 , g_szHUDMsg , charsmax( g_szHUDMsg ) );
        set_task( 5.0 , "ShowHUD" , TaskHUD , _, _, "b" );
        ShowHUD();
    }

    return PLUGIN_HANDLED;
}

public ShowHUD()
{
    set_hudmessage( RGBColor[ 0 ] , RGBColor[ 1 ] , RGBColor[ 2 ] , HUDPos[ 0 ] , HUDPos[ 1 ] , _, _, 6.0 , _, _, -1 );
    ShowSyncHudMsg( 0 , g_SyncHUD , g_szHUDMsg );
} 


[SpeeDeeR]

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Hud Message"
#define VERSION "1.0"
#define AUTHOR "SpeeD"
#define TASK_ID 13337

new cvarHudColor,cvarHudCoords,arg[128],id
public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_concmd("amx_hudmessage","hudmsg",ADMIN_CVAR)
    cvarHudColor = register_cvar("amx_hudmessage_color","255 0 0")
    cvarHudCoords = register_cvar("amx_hudmessage_coords","0.01 0.91")
    register_logevent("round_start",2,"1=Round_Start")
    register_logevent("round_end",2,"1=Round_End")
}

public GetHudColor( cvar, &r, &g, &b )
{
    static color[16], piece[5];
    get_pcvar_string( cvar, color, 15 );
    
    strbreak( color, piece, 4, color, 15 );
    r = str_to_num( piece );
    
    strbreak( color, piece, 4, color, 15 );
    g = str_to_num( piece );
    b = str_to_num( color );
}

public GetHudCoords( cvar, &Float:x, &Float:y )
{
    static coords[16], piece[10];
    get_pcvar_string( cvar, coords, 15 );
    
    strbreak( coords, piece, 9, coords, 15 );
    x = str_to_float( piece );
    y = str_to_float( coords );
}

public hudmsg(id,level,cid)
{
    if (!cmd_access(id,level,cid,1))
        return PLUGIN_HANDLED
    
    read_argv(1,arg,charsmax(arg))
    return PLUGIN_HANDLED
}

public round_start()
{
    
    set_task(0.1,"showhudmsg",TASK_ID,_,_,"b")
}

public round_end()
{
    remove_task(TASK_ID)
}
public showhudmsg()
{
    static r, g, b
    GetHudColor( cvarHudColor, r, g, b )
    static Float:x, Float:y
    GetHudCoords( cvarHudCoords, x, y )
    set_hudmessage(r, g, b, x ,y, 0, 0, 1.0, 0.0,0.0,-1)
    show_hudmessage(0, "%s",arg)
} 


Cvars:
amx_hudmessage_color
amx_hudmessage_coords

Commands:
amx_hudmessage

[Guppy488]

@SpeeDeeR
so if i type in console amx_hudmessage "hello everyone"
it will stay on bottom of the screen for 1 whole round?
@Bugsy
how to set the color?

[Bugsy]

You can use this calculator to get the RGB color values (top right-hand section with 3 # text boxes). If you want red, green, or blue just set the appropriate value to 255 and both others to 0. 255 255 255 = white, 0 0 0 = black.

Place values here:

PHP Code:

new const RGBColor[] = 
{
    0, //red
    212,  //green
    255 //blue
} 


Same idea for HUD position

PHP Code:

new const Float:HUDPos[] = 
{
    0.05, //x position
    0.85  //y position
} 


[SpeeDeeR]

YEs it will(comma) the whole round (full stop)

[Guppy488]

thanks all,i may use both of yours ... now i could add on with your ideas to my own first complicated plugin...tho i'm making for private use >_>

[Guppy488]

@bugsy
how do i set Hud On Middle Right of the screen?

Will My name will be shown in the hud message? i don't want my name to be shown :S

[Bugsy]

Originally Posted by Guppy488 @bugsy how do i set Hud On Middle Right of the screen? Will My name will be shown in the hud message? i don't want my name to be shown :S

Play with the HUDPos values. Your name will not be in the HUD msg. If you have AMXX-Studio there is a generator that can easily provide coordinates (Generators->Hudmessage Generator. Try using 0.60 , -1.0

PHP Code:

new const Float:HUDPos[] = 
{
    0.6,
    -1.0
} 


[Guppy488]

Thanks Bugsy,you've helped me alot ^^