[doublejz]

So long story short one of our old time members has past away. In tribute we've been trying to come up with a way to always have a bot named after him. Currently we have the bot quota set to 5 followed by the bot_add XYZ which works and keeps 6 bots in the server until players join.

When a player joins, there is that chance that bot XYZ gets kicked leaving the other bots in the server.

What we are trying to do is:
Determine if bot(s) are present and if so, check to see if one of them is named XYZ. If there isn't then we would rename a random bot to XYZ.

I might be going about this all wrong but this was my initial thought process. Any help is appreciated, as I'm trying to get back into scripting here after being absent for ~10+ years.

PHP Code:

public OnPluginStart()
{
    HookEvent("round_start", OnRoundStart, EventHookMode_PostNoCopy);
}

public OnRoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    decl String:t_name[64];
    Format(t_name, sizeof(t_name), "Name");
    new count = 0;
    for (new i = 1; i <= MaxClients; i++)
    {
    if(IsClientInGame(i))
        {
        count++;
        GetClientName(i, t_name, sizeof(t_name));
/*
*        Store somewhere?? array??? how??
*/
        }
    }
/*    Test output to see if [BOT] was found and if any are named XYZ
*    If [BOT] was found but not XYZ, rename a bot with [BOT]-?????? to [BOT]-XYZ
*    sm_rename i "[Bot]-XYZ"
*/
       else
       
       return Plugin_Handled;
} 


[xerox8521]

You could just save the Entity Reference in a variable and then check in OnClientDisconnect if the Entity Reference of the player that disconnected matches the saved variable and assign the name to a new bot.

Keep in mind that OnClientDisconnect is called on each map change.

Also in your for loop you are missing the IsFakeClient check.

[`666]

Tested only in insurgency

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <sdktools>

int        g_iNameSet = 0;
char    g_sOriginalName[32];

public Plugin myinfo = {
    name        = "bot_xyz",
    author        = "",
    description    = "",
    version        = "1.0",
    url            = ""
};

public void OnPluginStart() {
    HookEvent("player_team", Event_PlayerTeam, EventHookMode_Post);

    for (int i = 1 + 1; i <= MaxClients; i++) {
        if (!IsClientInGame(i) || !IsFakeClient(i)) {
            continue;
        }
        SetName(i);
        break;
    }
}

public void OnClientDisconnect(int client) {
    if (client == g_iNameSet && client > 0) {
        int iHumans = 0,
            iBot = 0;
    
        for (int i = 1; i <= MaxClients; i++) {
            if (!IsClientInGame(i) || i == g_iNameSet) {
                continue;
            }
            if (!IsFakeClient(i)) {
                iHumans++;
                continue;
            }

            iBot = i;

            if (iHumans) {
                break;
            }
        }

        if (iHumans && iBot) {
            SetName(iBot);
        } else {
            g_iNameSet = 0;
        }
    }
}

public Action Event_PlayerTeam(Event event, const char[] name, bool dontBroadcast) {
    if (g_iNameSet) {
        return Plugin_Continue;
    }

    int client = GetClientOfUserId(event.GetInt("userid"));
    if (client > 0 && IsClientInGame(client) && IsFakeClient(client)) {
        SetName(client);
    }

    return Plugin_Continue;
}

void SetName(int client) {
    //Remember original name so we can restore on plugin unload
    GetClientName(client, g_sOriginalName, sizeof(g_sOriginalName));
    SetClientName(client, "[Bot]-XYZ");
    g_iNameSet = client;
}

public void OnPluginEnd() {
    if (g_iNameSet && IsClientInGame(g_iNameSet) && IsFakeClient(g_iNameSet)) {
        SetClientName(g_iNameSet, g_sOriginalName);
    }
} 


[doublejz]

Originally Posted by `666 Tested only in insurgency PHP Code: #pragma semicolon 1 #pragma newdecls required #include <sourcemod> #include <sdktools> int        g_iNameSet = 0; char    g_sOriginalName[32]; public Plugin myinfo = {     name        = "bot_xyz",     author        = "",     description    = "",     version        = "1.0",     url            = "" }; public void OnPluginStart() {     HookEvent("player_team", Event_PlayerTeam, EventHookMode_Post);     for (int i = 1 + 1; i <= MaxClients; i++) {         if (!IsClientInGame(i) || !IsFakeClient(i)) {             continue;         }         SetName(i);         break;     } } public void OnClientDisconnect(int client) {     if (client == g_iNameSet && client > 0) {         int iHumans = 0,             iBot = 0;              for (int i = 1; i <= MaxClients; i++) {             if (!IsClientInGame(i) || i == g_iNameSet) {                 continue;             }             if (!IsFakeClient(i)) {                 iHumans++;                 continue;             }             iBot = i;             if (iHumans) {                 break;             }         }         if (iHumans && iBot) {             SetName(iBot);         } else {             g_iNameSet = 0;         }     } } public Action Event_PlayerTeam(Event event, const char[] name, bool dontBroadcast) {     if (g_iNameSet) {         return Plugin_Continue;     }     int client = GetClientOfUserId(event.GetInt("userid"));     if (client > 0 && IsClientInGame(client) && IsFakeClient(client)) {         SetName(client);     }     return Plugin_Continue; } void SetName(int client) {     //Remember original name so we can restore on plugin unload     GetClientName(client, g_sOriginalName, sizeof(g_sOriginalName));     SetClientName(client, "[Bot]-XYZ");     g_iNameSet = client; } public void OnPluginEnd() {     if (g_iNameSet && IsClientInGame(g_iNameSet) && IsFakeClient(g_iNameSet)) {         SetClientName(g_iNameSet, g_sOriginalName);     } }

This appears to work as expected. Thanks a bunch!