[NiHiLaNTh]

VIP cannot receive any weapons apart from knife and handguns and [maybe] grenades. That's the limitation of the game.

[Spirit_12]

Originally Posted by NiHiLaNTh VIP cannot receive any weapons apart from knife and handguns and [maybe] grenades. That's the limitation of the game.

Not entirely true. I was able to find a way around it.

[HamletEagle]

You can't simply set some private data and change weapon, you need to create an entity and touch that entity with a player.
give_item does that, but it not work on vip because in CBasePlayerItem:: DefaultTouch game checks for vip and what weapon you want to give. In order to enable give_item on a vip player you can use the following code:

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>
#include <engine>
#include <orpheu>
#include <orpheu_advanced>
#include <fun>

#if AMXX_VERSION_NUM < 183

#define INT_BYTES        4 
#define BYTE_BITS        8 

stock bool:get_pdata_bool(ent, charbased_offset, intbase_linuxdiff = 5) 
{ 
    return !!( get_pdata_int(ent, charbased_offset / INT_BYTES, intbase_linuxdiff) & (0xFF<<((charbased_offset % INT_BYTES) * BYTE_BITS)) ) 
} 
#endif

const m_pfnTouch  = 5
const XoPfnTouch  = 1
const m_bIsVIP    = 837
 
public plugin_init()
{
    /*
        | HACK
        | Instead of making a signature we simply create a weapon entity(can be any weapon)
        | Then we retrieve the touch function address from m_pfnTouch and hook DefaultTouch from that address
    */
    new WeaponEntity = create_entity("weapon_ak47")
    ExecuteHamB(Ham_Spawn, WeaponEntity)
    
    new DefaultTouchAddress = get_pdata_int(WeaponEntity, m_pfnTouch, XoPfnTouch)

    if(DefaultTouchAddress)
    {
        new OrpheuFunction:DefaultTouchFunction = OrpheuCreateFunction(DefaultTouchAddress, "DefaultTouch", "CBasePlayerItem")
        OrpheuRegisterHook(DefaultTouchFunction, "CBasePlayerItem_DefaultTouch", OrpheuHookPre)
        remove_entity(WeaponEntity)
    }
    
    register_clcmd("test", "ClientCommand_Test")
    
}

public ClientCommand_Test(id)
{
    give_item(id, "weapon_m4a1")
}

public OrpheuHookReturn:CBasePlayerItem_DefaultTouch(const Item, const id)
{
    if(pev_valid(Item))
    {
        if(is_user_alive(id))
        {
            if(get_pdata_bool(id, m_bIsVIP))
            { 
                if(ExecuteHamB(Ham_AddPlayerItem, id, Item))
                {
                    ExecuteHamB(Ham_Item_AttachToPlayer, Item, id)
                    emit_sound(id, CHAN_ITEM, "items/gunpickup2.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
                }

                return OrpheuSupercede
            }
        }
    }
    
    return OrpheuIgnored
} 


Create a file called DefaultTouch in addons/amxmodx/configs/orpheu/functions/CBasePlayerItem

{
    "name"      : "DefaultTouch",
    "class"     : "CBasePlayerItem",
    "library"   : "mod",
    "arguments" :
    [
        {
            "type"  : "CBaseEntity *"
        }
    ]
}

To test, simply write "test" in console as a vip player and you'll see you get an m4a1.

Or you can try another way: set m_bIsVIP to false before give_item and to true after.

[CrazY.]

Cstrike have a native to check if a player is VIP. Check if is_user_alive instead of is_user_connected.

P.S: I didn't see the second page

[Spirit_12]

I was looking at increase vip bullets plugin. Connor has used pdata in that method. Was it only because it is a modification to clients inventory as opposed to adding an item?

[HamletEagle]

Most likely yes. Ammo are stored in offsets.