[Michael Shoe Maker]

Greetings M'Lords,

I've happened to befall a problem. I have seen a plugin for TTT to make it so that a client who may be alive or dead is always 'alive'. Meaning they are not blacked out on the scoreboard or the alive count is less.

This leads me to believe the alive status of someone can be changed, how would this be done?

Many Thanks.

[Marcus101RR]

Originally Posted by Michael Shoe Maker Greetings M'Lords, I've happened to befall a problem. I have seen a plugin for TTT to make it so that a client who may be alive or dead is always 'alive'. Meaning they are not blacked out on the scoreboard or the alive count is less. This leads me to believe the alive status of someone can be changed, how would this be done? Many Thanks.

When it comes to Left 4 Dead, you can change the number of incap/death status on their netprops. Try to find a netprop that changes during alive/dead status? I am not sure which one it is.

[Michael Shoe Maker]

Originally Posted by Marcus101RR When it comes to Left 4 Dead, you can change the number of incap/death status on their netprops. Try to find a netprop that changes during alive/dead status? I am not sure which one it is.

Tried:

PHP Code:

SetEntProp(param1, Prop_Send, "m_bAlive", 0); 


Apparently this isn't a property that's valid even though it's in my netprops dump.

[Bacardi]

Have you try change that property on OnThinkPost or other OnThink* forwards ?

[Michael Shoe Maker]

Originally Posted by Bacardi Have you try change that property on OnThinkPost or other OnThink* forwards ?

Nope. It says in console something like "Invalid property", so my guess the same would happen in a think hook.

[good_live]

Why you don't take the relevant part from the TTT plugin?
It is open source.

[Franc1sco]

Originally Posted by Michael Shoe Maker Tried: PHP Code: SetEntProp(param1, Prop_Send, "m_bAlive", 0);  Apparently this isn't a property that's valid even though it's in my netprops dump.

Try with

PHP Code:

SetEntProp(client, Prop_Send, "m_lifeState", 1); 


[Michael Shoe Maker]

Originally Posted by Franc1sco Try with PHP Code: SetEntProp(client, Prop_Send, "m_lifeState", 1);

That does work in a sense, it makes it so I don't count as an alive player on the hud and scoreboard but it makes me invisible. The reason I need this is because I made a little menu that allows players to choose a model to become (like a teapot), but because this is used on a Jailbreak server it interferes with the game since T's would be looking for that remaining player.

EDIT: I saw this before in the plugin but I have no idea what it does and if it's what im looking for:

PHP Code:

public void OnMapStart()
{
    g_iAlive = FindSendPropInfo("CCSPlayerResource", "m_bAlive");
    if (g_iAlive == -1)
        SetFailState("CCSPlayerResource \"m_bAlive\" offset is invalid");
    
    g_iKills = FindSendPropInfo("CCSPlayerResource", "m_iKills");
    if (g_iKills == -1)
        SetFailState("CCSPlayerResource \"m_iKills\" offset is invalid");
    
    g_iDeaths = FindSendPropInfo("CCSPlayerResource", "m_iDeaths");
    if (g_iDeaths == -1)
        SetFailState("CCSPlayerResource \"m_iDeaths\"  offset is invalid");
    
    g_iAssists = FindSendPropInfo("CCSPlayerResource", "m_iAssists");
    if (g_iAssists == -1)
        SetFailState("CCSPlayerResource \"m_iAssists\"  offset is invalid");
    
    g_iMVPs = FindSendPropInfo("CCSPlayerResource", "m_iMVPs");
    if (g_iMVPs == -1)
        SetFailState("CCSPlayerResource \"m_iMVPs\"  offset is invalid");
    
    
    int iPlayerManagerPost = FindEntityByClassname(0, "cs_player_manager");
    SDKHook(iPlayerManagerPost, SDKHook_ThinkPost, ThinkPost);
}

public void ThinkPost(int entity)
{
    int isAlive[65];
    
    GetEntDataArray(entity, g_iAlive, isAlive, 65);
    LoopValidClients(i)
        isAlive[i] = (!g_bFound[i]);
    
    if (g_iConfig[b_kadRemover])
    {
        int iZero[MAXPLAYERS + 1] =  { 0, ... };
        
        SetEntDataArray(entity, g_iKills, iZero, MaxClients + 1);
        SetEntDataArray(entity, g_iDeaths, iZero, MaxClients + 1);
        SetEntDataArray(entity, g_iAssists, iZero, MaxClients + 1);
        SetEntDataArray(entity, g_iMVPs, iZero, MaxClients + 1);
    }
    
    SetEntDataArray(entity, g_iAlive, isAlive, 65);
} 


[Michael Shoe Maker]

Solved:

PHP Code:

public void Hook_ThinkPost(int entity)
{
    int IsAlive[MAXPLAYERS + 1];
    
    GetEntDataArray(entity, g_iAlive, IsAlive, sizeof(IsAlive));
    
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsValidClient(i))
        {
            IsAlive[i] = view_as<int>(!g_bProp[i]);
        }
    }
    
    SetEntDataArray(entity, g_iAlive, IsAlive, sizeof(IsAlive));
} 


[shavit]

Originally Posted by Michael Shoe Maker That does work in a sense, it makes it so I don't count as an alive player on the hud and scoreboard but it makes me invisible. The reason I need this is because I made a little menu that allows players to choose a model to become (like a teapot), but because this is used on a Jailbreak server it interferes with the game since T's would be looking for that remaining player. EDIT: I saw this before in the plugin but I have no idea what it does and if it's what im looking for: PHP Code: public void OnMapStart() {     g_iAlive = FindSendPropInfo("CCSPlayerResource", "m_bAlive");     if (g_iAlive == -1)         SetFailState("CCSPlayerResource \"m_bAlive\" offset is invalid");          g_iKills = FindSendPropInfo("CCSPlayerResource", "m_iKills");     if (g_iKills == -1)         SetFailState("CCSPlayerResource \"m_iKills\" offset is invalid");          g_iDeaths = FindSendPropInfo("CCSPlayerResource", "m_iDeaths");     if (g_iDeaths == -1)         SetFailState("CCSPlayerResource \"m_iDeaths\"  offset is invalid");          g_iAssists = FindSendPropInfo("CCSPlayerResource", "m_iAssists");     if (g_iAssists == -1)         SetFailState("CCSPlayerResource \"m_iAssists\"  offset is invalid");          g_iMVPs = FindSendPropInfo("CCSPlayerResource", "m_iMVPs");     if (g_iMVPs == -1)         SetFailState("CCSPlayerResource \"m_iMVPs\"  offset is invalid");               int iPlayerManagerPost = FindEntityByClassname(0, "cs_player_manager");     SDKHook(iPlayerManagerPost, SDKHook_ThinkPost, ThinkPost); } public void ThinkPost(int entity) {     int isAlive[65];          GetEntDataArray(entity, g_iAlive, isAlive, 65);     LoopValidClients(i)         isAlive[i] = (!g_bFound[i]);          if (g_iConfig[b_kadRemover])     {         int iZero[MAXPLAYERS + 1] =  { 0, ... };                  SetEntDataArray(entity, g_iKills, iZero, MaxClients + 1);         SetEntDataArray(entity, g_iDeaths, iZero, MaxClients + 1);         SetEntDataArray(entity, g_iAssists, iZero, MaxClients + 1);         SetEntDataArray(entity, g_iMVPs, iZero, MaxClients + 1);     }          SetEntDataArray(entity, g_iAlive, isAlive, 65); }

it makes zero sense to set entity data to all player at ThinkPost instead of just to the one that ThinkPost is hooked to