[Nutu_]

how to find the last alive CT? does it seems good?

PHP Code:

public DeathMsgEvent(){
    
    for(new i = 1; i <= g_maxplayers; i++)
    {
        if(is_user_connected(i) && is_user_alive(i) && cs_get_user_team(i) == CS_TEAM_CT)
        {
            g_lastman = i;
            new szName[32]
            get_user_name(i, szName, 31)
            set_hudmessage(0, 150, 255, -1.0, 0.15, 0, 1.0, 5.0, 0.1, 0.1, -1)
            show_hudmessage(i, "%s is the last ct alive.", szName)
            extra_weapon_menu(i) 
            return;
        } 
    }  
    
}

public extra_weapon_menu(i)
{
bla bla
} 


[OciXCrom]

Not really.

new iPlayers[32], iPnum
get_players(iPlayers, iPnum, "ae", "CT")

if(iPnum == 1)
{
    new iLastCT = iPlayers[0]
}

[Bugsy]

Here's OciXCrom's code in a function. This will return the player id of the last alive CT. If there are more than 1 alive CT's, or no alive CT's, it will return 0.

PHP Code:

LastAliveCT()
{
    new iPlayers[ 32 ] , iPnum;
    get_players( iPlayers , iPnum , "ae" , "CT" );
    
    return ( iPnum == 1 ) ? iPlayers[ 0 ] : 0;
} 


[Nutu_]

i also find it before

PHP Code:

public Event_DeathMsg() 
{ 
    set_task(0.1,"check_alive", 0) 
}

public check_alive() 
{ 
    if(fnGetAliveCt() == 1) 
    { 
        for( new i = 1; i <= g_Players; i++ )  
        {  
            if (is_user_alive(i) && cs_get_user_team(i) == CS_TEAM_CT)  
            { 
                new szName[32]
                get_user_name(i, szName, 31)
                extra_weapon_menu(i)
                client_print(0, print_center, "%s is the last survivor", i)
            } 
        }  
    } 
} 
fnGetAliveCt() 
{ 
    static iAlive, id 
    iAlive = 0 
    
    for (id = 1; id <= g_Players; id++) 
    { 
        if (is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) 
            iAlive++ 
    } 
    return iAlive; 
} 


how am i supposed to make this to work only once, it gives the extra_weapon_menu to every player that have killed someone, I want this to gives only once, to the last CT alive, if there respawns a new CT and there would be 2 CT's, and someone got killed, not to show anymore.. thanks

[Bugsy]

Try this

PHP Code:

public Event_DeathMsg() 
{ 
    //set_task( 0.1 , "check_alive" ) 
    check_alive();
}

public check_alive() 
{ 
    new iLastCT = LastAliveCT();
    
    if ( iLastCT ) 
    { 
        new szName[32]
        get_user_name(iLastCT, szName, charsmax(szName) );
        extra_weapon_menu(iLastCT)
        client_print(0, print_center, "%s is the last survivor", szName)
    } 
} 

LastAliveCT()
{
    new iPlayers[ 32 ] , iPnum;
    get_players( iPlayers , iPnum , "ae" , "CT" );
    
    return ( iPnum == 1 ) ? iPlayers[ 0 ] : 0;
} 


[Nutu_]

Bugsy, it works, it only shows the menu when you're last CT but the problem is, it shows every time you make a kill, you kill someone, not only once, i would like to appear that only once.

[Napoleon_be]

declare a new bool, set it to true when menu has opened, set to false when new round begins.

[Nutu_]

alright, i was just look through some plugins about that bool

PHP Code:

new bool:hasOpened[33] = false

public newround()
{
    hasOpened[id] = false
}

public check_alive() 
{ 
    new iLastCT = LastAliveCT();
    
    if ( iLastCT ) 
    { 
        new szName[32]
        get_user_name(iLastCT, szName, charsmax(szName) );
        extra_weapon_menu(iLastCT)
        client_print(0, print_center, "%s is the last survivor", szName)
        hasOpened[id] = true
    } 
} 


but how would i declare that the menu has been opened? or will work this way? (i cant test right now)

[Bugsy]

You don't need to use this bool at a player level, since there will ever only be 1 last CT per round.

PHP Code:

new bool:hasOpened

public newround()
{
    hasOpened = false
}

public check_alive() 
{ 
    if ( !hasOpened )
    {
        new iLastCT = LastAliveCT();
        
        if ( iLastCT ) 
        { 
            new szName[32]
            get_user_name(iLastCT, szName, charsmax(szName) );
            extra_weapon_menu(iLastCT)
            client_print(0, print_center, "%s is the last survivor", szName)
            hasOpened = true
        } 
    }
} 


[Nutu_]

Originally Posted by Bugsy You don't need to use this bool at a player level, since there will ever only be 1 last CT per round. PHP Code: new bool:hasOpened public newround() {     hasOpened = false } public check_alive()  {      if ( !hasOpened )     {         new iLastCT = LastAliveCT();                  if ( iLastCT )          {              new szName[32]             get_user_name(iLastCT, szName, charsmax(szName) );             extra_weapon_menu(iLastCT)             client_print(0, print_center, "%s is the last survivor", szName)             hasOpened = true         }      } }

thank you, works! +karma